dev-libs/gobject-introspection: bump to 1.56.1

Depend on cairo for tests, as regress.h in testsuite includes
cairo-gobject.h header. We could hack to disable cairo ifdef
for test runs without cairo really present, but I don't think
we mind the circular deps with USE=test involved.

Closes: https://bugs.gentoo.org/639016
Closes: https://bugs.gentoo.org/635922
Package-Manager: Portage-2.3.49, Repoman-2.3.10

dev-libs/gobject-introspection/Manifest

@@ -1,2 +1,3 @@
 DIST gobject-introspection-1.50.0.tar.xz 1415700 BLAKE2B 7707d0affc35e60d272312debd429a96a578cc6ea4e889244a0a1dc34f23e3b686cea06076427575fa620f570141e173990ed12649cb669808141dab1fdffb19 SHA512 cb108cf3d49743e1686fe4ae99f2360799bc8825ad97bf0b97e097b3f89e2771079593de0f497a9e5b9cff892f6fbf870834a6c4d13f11bcde99162e9388ecfa
 DIST gobject-introspection-1.52.1.tar.xz 1384292 BLAKE2B e1176bff177d7b6deee3e93159425a176d8056fbac2af5038950b7bc4486785ca988fc4c8c4d6a069b2bf623092e57f096aea37bbb9a767adaa695ec8f0db4e6 SHA512 878653ffa80c064c73453ea2878a977e52f0d6a0b2123bee8c3429379366f9da3e9fd991fad0dda170d74e4241314ea6c5120f5988e68fad4bfe9c333d11389f
+DIST gobject-introspection-1.56.1.tar.xz 1397812 BLAKE2B 070597f3bd6e4e58d1ae1964cf6e8d7881daa68aeeddc5e9b64bc410fad6d435f2041171f4dfc2a6b477d39f2d7e9181b9917d1244fcb45b3a37491726381649 SHA512 2bfcd45b8c5ad68a3f6550c2f80a6804db0e1a72ffaf4fdd3cec3d8acc23e79ad14bb5bf612fe26fc896691839ab19ca8dd1c9994db14d730e56fa79df9d973d

dev-libs/gobject-introspection/gobject-introspection-1.56.1.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="cairo doctool test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	test? ( cairo )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+# We force glib and g-i to be in sync by this way as explained in bug #518424
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.56.1:2
+	doctool? ( dev-python/mako[${PYTHON_USEDEP}] )
+	virtual/libffi:=
+	virtual/pkgconfig
+	!<dev-lang/vala-0.20.0
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.19
+	sys-devel/bison
+	sys-devel/flex
+	test? ( x11-libs/cairo[glib] )
+"
+# PDEPEND to avoid circular dependencies, bug #391213; but needed for tests, thus test DEPEND as well
+PDEPEND="cairo? ( x11-libs/cairo[glib] )"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if ! has_version "x11-libs/cairo[glib]"; then
+		# Bug #391213: enable cairo-gobject support even if it's not installed
+		# We only PDEPEND on cairo to avoid circular dependencies
+		export CAIRO_LIBS="-lcairo -lcairo-gobject"
+		export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
+	fi
+
+	# To prevent crosscompiling problems, bug #414105
+	gnome2_src_configure \
+		--disable-static \
+		CC="$(tc-getCC)" \
+		YACC="$(type -p yacc)" \
+		$(use_with cairo) \
+		$(use_enable doctool)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"usr/share/aclocal/introspection.m4 \
+		"${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"usr/share/aclocal || die
+}