sys-cluster/charliecloud: add 0.29

Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>
Signed-off-by: Nicolas Bock <nicolasbock@gentoo.org>
This commit is contained in:
Oliver Freyermuth
2022-08-05 07:23:14 +02:00
committed by Nicolas Bock
parent 012c626fda
commit ee9ddd25af
2 changed files with 84 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST charliecloud-0.27.tar.gz 471754 BLAKE2B b683847a79dd55a4bb79458e94e03988acdff0a1e6a24e7f67d56758bdbc3754cc3609e97bfc778f5cb6ce35d6f4df773235314c2ed642ac796b28b824ecadf6 SHA512 cfa5b1ac923008b9a38fc0228562b31551ea941bf222c9b9e12d8dce4c83ca896893e3509773a5ebc02d6b374d08dc049797226cf1432099aae7174c2bc5ee2b
DIST charliecloud-0.28.tar.gz 504793 BLAKE2B 97b9249be59700506b7b7032da7111b0099b88bea6cb73e348238ef2aacfb55ee9d868f81036728b1e67a41911ca3e754d009ba74375847747f3303a7dc2304c SHA512 62a00f16c118e3dd8d9f011290666961216d24d07825590c9a3ec9dd527948be75c66df8d5ef50f4796567aa358ca4e466148ca78bad9d0715bb4caa26004eb6
DIST charliecloud-0.29.tar.gz 506974 BLAKE2B 2f5ce5f6addf1abbb3274f8e8a9d33cc7ec73ba275efc4d750806b5fc2358ad9491da453ae4dcad712567b5719a4b179644e630b64fe9c29cfc2525a06e533a0 SHA512 a8f334cf1ac9fa1117b69f1282b74a3bce313b8fd892373dd7cfa642f664fcd623a8e8d2b81aa9757e43f972cd31fca9185e00d2280b40def2c63c725cea7256
@@ -0,0 +1,83 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
inherit autotools optfeature python-single-r1
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/hpc/${PN}.git"
S="${WORKDIR}/${P}"
else
SRC_URI="https://github.com/hpc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86 ~x86-linux"
fi
DESCRIPTION="Lightweight user-defined software stacks for high-performance computing"
HOMEPAGE="https://hpc.github.io/charliecloud/"
SLOT="0"
LICENSE="Apache-2.0"
IUSE="ch-image doc"
# Extensive test suite exists, but downloads container images
# directly and via Docker and installs packages inside using apt/yum.
# Additionally, clashes with portage namespacing and sandbox.
RESTRICT="test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
elibc_musl? ( sys-libs/argp-standalone )
"
DEPEND="
ch-image? (
$(python_gen_cond_dep '
dev-python/lark[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
')
)
doc? (
$(python_gen_cond_dep '
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
')
net-misc/rsync
)"
src_prepare() {
default
eautoreconf
}
src_configure() {
local econf_args=()
econf_args+=(
$(use_enable doc html)
$(use_enable ch-image)
# Libdir is used as a libexec-style destination.
--libdir="${EPREFIX}"/usr/lib
# Attempts to call python-exec directly otherwise.
--with-sphinx-python="${EPYTHON}"
# This disables -Werror, see also: https://github.com/hpc/charliecloud/pull/808
--enable-buggy-build
# Do not use bundled version of dev-python/lark.
--disable-bundled-lark
# Use correct shebang.
--with-python="${PYTHON}"
)
econf "${econf_args[@]}"
}
pkg_postinst() {
elog "Various builders are supported, as alternative to the internal ch-image."
optfeature "Building with Buildah" app-containers/buildah
optfeature "Building with Docker" app-containers/docker
optfeature "Progress bars during long operations" sys-apps/pv
optfeature "Pack and unpack squashfs images" sys-fs/squashfs-tools
optfeature "Mount and umount squashfs images" sys-fs/squashfuse
optfeature "Build versioning with ch-image" dev-vcs/git
}