mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-util/spirv-llvm-translator: Bump to 23.1.0
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -21,3 +21,4 @@ DIST spirv-llvm-translator-21.1.7.tar.gz 1855026 BLAKE2B 7b23acfba68cbe9b2cf3094
|
||||
DIST spirv-llvm-translator-21.1.9.tar.gz 1862146 BLAKE2B c54db44033a8e8c658b5ff8c84cbd9ddc659d7677f1920f07983c4e03feb6bbf38d0cd392284de23022bf324d81db88ca21be4bf88ea2048a7deda650681ed51 SHA512 4dc8e6257f3b1c98ac6289b442b870bf6115fa6f1d5ae4b8c906948706a08ee959f8a409a8d0a20c0895330b50d541f761f5ed953902e8c17586356c1c03bdd3
|
||||
DIST spirv-llvm-translator-22.1.2.tar.gz 1870249 BLAKE2B 56dd66732727e2d002422392b41e0d7d745f9c3866953178759f862d0155539f6be2b54519fc6be1a694036d198d50c5f778cb709bef3c83d1dbb5416c7020ac SHA512 d224b29029dae66dac430834b927a0683e3e15fb555c2ba83764403b8cdc28bfcccbe8e9ec2e3d1854c9d32b02d0b8282a3d883441c7ce33c1fc5339c0a373f0
|
||||
DIST spirv-llvm-translator-22.1.4.tar.gz 1875796 BLAKE2B af731f5ebb3b4082c11e388b038b91933a20650f6dc5f871d9a2fffbee37c15099a20a25fae7eebb77613a0c5eeaf24fbab30394cd5f2eabab150d6fb5a31775 SHA512 7a1275088a2e58040efdd64f00ded27e7f4099e3c8add9528e4bccaae827578534b31c16bd4ab590f6f9f37c5ac4899e8651dc9d66d5c1ec0bc72c3246399f90
|
||||
DIST spirv-llvm-translator-23.1.0.tar.gz 1928907 BLAKE2B 98a749adc36d38b54a28ef26db0321244a9c68e70e367092e2c5dbcb1199825233ce3e6a36c89d898dae24fb77f62da034fcbb8d5e9267731ad0b230d19b562e SHA512 86f76906d62baadce8050d46dcf0ccd8ff74e916edcdf62dcf4e5fa3245d23cff39ec1a1f21e9e853efc4090085040eb95cc86d266978d68a62d5fb9dc2b8766
|
||||
|
||||
@@ -0,0 +1,70 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
MY_PN="SPIRV-LLVM-Translator"
|
||||
MY_P="${MY_PN}-${PV}"
|
||||
|
||||
inherit cmake-multilib flag-o-matic multiprocessing
|
||||
|
||||
DESCRIPTION="Bi-directional translator between SPIR-V and LLVM IR"
|
||||
HOMEPAGE="https://github.com/KhronosGroup/SPIRV-LLVM-Translator"
|
||||
SRC_URI="
|
||||
https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz
|
||||
-> ${P}.tar.gz
|
||||
"
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
LICENSE="UoI-NCSA"
|
||||
SLOT="$(ver_cut 1)"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
|
||||
IUSE="test"
|
||||
RESTRICT="
|
||||
!test? ( test )
|
||||
arm? ( test )
|
||||
arm64? ( test )
|
||||
loong? ( test )
|
||||
riscv? ( test )
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
dev-util/spirv-tools[${MULTILIB_USEDEP}]
|
||||
llvm-core/llvm:${SLOT}=[${MULTILIB_USEDEP}]
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
>=dev-util/spirv-headers-1.4.357.0
|
||||
"
|
||||
BDEPEND="
|
||||
virtual/pkgconfig
|
||||
test? (
|
||||
dev-python/lit
|
||||
llvm-core/clang:${SLOT}
|
||||
)
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
append-flags -fPIC
|
||||
cmake_src_prepare
|
||||
|
||||
# do not force a specific LLVM version to find_package(), this only
|
||||
# causes issues and we force a specific path anyway
|
||||
sed -i -e '/find_package/s:${BASE_LLVM_VERSION}::' CMakeLists.txt || die
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DLLVM_ROOT="${ESYSROOT}/usr/lib/llvm/${SLOT}"
|
||||
-DCCACHE_ALLOWED="OFF"
|
||||
-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/${SLOT}"
|
||||
-DLLVM_EXTERNAL_SPIRV_HEADERS_SOURCE_DIR="${ESYSROOT}/usr/include/spirv"
|
||||
-DLLVM_SPIRV_INCLUDE_TESTS=$(usex test "ON" "OFF")
|
||||
-Wno-dev
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
lit -vv "-j${LIT_JOBS:-$(makeopts_jobs)}" "${BUILD_DIR}/test" || die
|
||||
}
|
||||
Reference in New Issue
Block a user