dev-python/paramiko: Bump to 3.5.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/paramiko/Manifest

@@ -1 +1,2 @@
 DIST paramiko-3.5.0.gh.tar.gz 376242 BLAKE2B 3080669e8b0d60e5b2e5aea390dc4f5f8d19ff32441d13b4e319892d1566f3fc76df714c0a063932e5077de08cd66ccf1140ac96bcb6e1c8e801c1377923aece SHA512 933a63c511fcd0a5a159faf2a9dfddbb44368ba923ea892aa1bf8dbe296777f3caedff27560113cfb15576812b994a59007caac8f297b24e70c79505f88c7d9f
+DIST paramiko-3.5.1.gh.tar.gz 376472 BLAKE2B e00c0e1ab62eb443b3dfb5b1ebfacb9ac2f0f7e4946dcb986f8a211c22e645acd6d96ceaf709a954bf1f1554e8ce57ea1c6269984184025de39d9d9c4ff909d9 SHA512 a1198f7f21cfbdbb843acb59cc431f9af0a47d687a7e9702244f36b555bb37b75149c0e22302040400f20df50dee1d83154e5acd582982ca44f6cf68ff592675

dev-python/paramiko/paramiko-3.5.1.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="
+	https://www.paramiko.org/
+	https://github.com/paramiko/paramiko/
+	https://pypi.org/project/paramiko/
+"
+SRC_URI="
+	https://github.com/paramiko/paramiko/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples server"
+
+RDEPEND="
+	>=dev-python/bcrypt-3.1.3[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.5[${PYTHON_USEDEP}]
+	>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# upstream doesn't really maintain the gssapi support
+	tests/test_gssapi.py
+	tests/test_kex_gss.py
+	tests/test_ssh_gss.py
+)
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-3.2.0-nih-test-deps.patch"
+	)
+
+	if ! use server; then
+		PATCHES+=( "${FILESDIR}/${PN}-3.2.0-disable-server.patch" )
+	fi
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p rerunfailures --reruns=5
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r demos/*
+	fi
+}