gui-libs/wlroots: 0.13.0 bump

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

gui-libs/wlroots/Manifest

@@ -1,2 +1,3 @@
 DIST wlroots-0.11.0.tar.gz 481126 BLAKE2B d2262298f24948293643b02c823851b4643289f776bc087d7b67240f4c9c76a7aca03c7dc7e13a65b3d0d3a7c8a5f5246a0e282d2cb3b88bbae0ef94b906f18a SHA512 a8a0c498d10664ff0a5aab8ad1a4fd034179542eff38b058e1da7e4653c42136e4a3586634f3d0a25a985aa7f4c5d17260117d9f4a70a7f8060494c04456f575
 DIST wlroots-0.12.0.tar.gz 476936 BLAKE2B 4129c87a148085f95f4cee6973308d79ab3f8b024247287a68dadd6729da8a5f8cc1e4ada63c15477a2c8e8258032440afe4a21a26f947143d17c87b0ca8a1a4 SHA512 560eae30932b777c1f07fb44592d5601c5d10ef74b31b6b9e4166a14caadab2bfa88d39282f159785d4c7f22f78d204f9bb7fab65d58afaf14b72a8486f9b415
+DIST wlroots-0.13.0.tar.gz 503575 BLAKE2B bfcd40ea5cf9f85157b9a44a4a49f0fef1c82c2199ee428316b578e8d53cc39276b42d0a2c4b6b94d1a1f49df5d312539cdf4d053ea2472e0de93254e39dc015 SHA512 1c942a6b8a628383e2b68cd9096d3525021347c5c363a8239a3b4fb0d5736ffcd3e2c1333fdd7d95ecf214dd04bf01062b4f1b4fbbcd88d1d086a55261ca0c82

gui-libs/wlroots/wlroots-0.13.0.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://github.com/swaywm/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/9999"
+IUSE="elogind icccm seatd systemd x11-backend X"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=dev-libs/libinput-1.14.0:0=
+	>=dev-libs/wayland-1.19.0
+	>=dev-libs/wayland-protocols-1.17.0
+	media-libs/mesa[egl,gles2,gbm]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	elogind? ( >=sys-auth/elogind-237 )
+	icccm? ( x11-libs/xcb-util-wm )
+	seatd? ( sys-auth/seatd:= )
+	systemd? ( >=sys-apps/systemd-237 )
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xorg-server[wayland]
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-image
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.17
+	>=dev-util/meson-0.56.0
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		-Dxcb-icccm=$(usex icccm enabled disabled)
+		-Dxwayland=$(usex X enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+		"-Dexamples=false"
+		"-Dwerror=false"
+		-Dlibseat=$(usex seatd enabled disabled)
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}

gui-libs/wlroots/wlroots-9999.ebuild

@@ -22,7 +22,7 @@ IUSE="elogind icccm seatd systemd x11-backend X"
 REQUIRED_USE="?? ( elogind systemd )"
 
 DEPEND="
-	>=dev-libs/libinput-1.9.0:0=
+	>=dev-libs/libinput-1.14.0:0=
 	>=dev-libs/wayland-1.19.0
 	>=dev-libs/wayland-protocols-1.17.0
 	media-libs/mesa[egl,gles2,gbm]