app-cdr/dolphin-plugins-mountiso: 25.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-cdr/dolphin-plugins-mountiso/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-24.12.3.tar.xz 319108 BLAKE2B 0e6c5735b308cdea158b58f535335dedf1035920ec7cc6fc0bdb470dd0f58ce90c6efc3a4799b45fda7b967616babea980ce3792f2e9a507f543e4e8a488ae36 SHA512 4025ca9274e14d0f5c6bf880c8365ba5809f37d508174184daee6e7c45d5859fbeff3753a0c48d38ad9c59609be161ceea54cb38618de919ca762314e1001581
+DIST dolphin-plugins-25.04.0.tar.xz 329340 BLAKE2B 1ac49add95258837310aece77372cb5960909fdeadb78e1dcfce5bf56e1af1f94a3353894899d8e978658f40bde6365e93b582f33232721ee77e113a780dcc99 SHA512 6959f35e4b9699f4abe81a60b4a8823b17efa1cb46f12d1b6a3cc9477a78504f2401fbba61d69709598ad42c33245def21383fb315401db9bbe2d243a5a09952

app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-25.04.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=6.9.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# qtconcurrent only required by git
+	ecm_punt_qt_module Concurrent
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_makefileactions=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}