media-libs/quarter: rework ebuild

Align media-libs/quarter, media-libs/simage, media-libs/SoQt & media-libs/SoXt
as they share a common build layout.

Force CMAKE_BUILD_TYPE=DEBUG for USE=debug.
It's evaluated in the build files for `QUARTER_DEBUG`.

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1856
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Paul Zander
2026-09-15 16:35:06 +01:00
committed by Sam James
parent 0909212e8e
commit ec741fc1eb
2 changed files with 80 additions and 66 deletions
@@ -0,0 +1,80 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="GUI binding for using Coin/Open Inventor with Qt"
HOMEPAGE="https://github.com/coin3d/quarter https://github.com/coin3d/coin/wiki"
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/coin3d/${PN,,}.git"
else
SRC_URI="https://github.com/coin3d/${PN,,}/releases/download/v${PV}/${P/${PN}/${PN,,}}-src.tar.gz"
S="${WORKDIR}/${PN,,}"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="debug designer doc qch"
REQUIRED_USE="qch? ( doc )"
RESTRICT="test"
RDEPEND="
dev-qt/qtbase:6[gui,opengl,widgets]
dev-qt/qttools:6[widgets,designer?]
media-libs/coin
virtual/opengl
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? (
app-text/doxygen[dot]
qch? ( dev-qt/qttools:6[assistant] )
)
"
PATCHES=(
"${FILESDIR}/${PN}-1.2.1-cmake.patch"
"${FILESDIR}/${PN}-1.2.2-find-qhelpgenerator.patch" # bug 933432
)
DOCS=( AUTHORS NEWS README.md )
src_prepare() {
cmake_src_prepare
sed -e 's|/lib$|/lib@LIB_SUFFIX@|' \
-i Quarter.pc.cmake.in || die
}
src_configure() {
use debug && CMAKE_BUILD_TYPE="Debug"
local mycmakeargs=(
-D${PN^^}_BUILD_SHARED_LIBS=ON
-D${PN^^}_BUILD_PLUGIN=$(usex designer)
-D${PN^^}_BUILD_EXAMPLES=OFF
-D${PN^^}_BUILD_AWESOME_DOCUMENTATION=$(usex doc)
-D${PN^^}_BUILD_DOCUMENTATION=$(usex doc)
-D${PN^^}_BUILD_DOC_MAN=$(usex doc)
-D${PN^^}_BUILD_DOC_QTHELP=$(usex qch)
-D${PN^^}_BUILD_DOC_CHM=OFF
-D${PN^^}_BUILD_INTERNAL_DOCUMENTATION=OFF
-D${PN^^}_USE_QT5="no"
-D${PN^^}_USE_QT6="yes"
)
use doc && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Git=ON )
cmake_src_configure
}
-66
View File
@@ -1,66 +0,0 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
DESCRIPTION="GUI binding for using Coin/Open Inventor with Qt"
HOMEPAGE="https://github.com/coin3d/coin/wiki"
SRC_URI="https://github.com/coin3d/quarter/releases/download/v${PV}/${P}-src.tar.gz"
S="${WORKDIR}/quarter"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug designer doc qch"
REQUIRED_USE="qch? ( doc )"
RDEPEND="
dev-qt/qtbase:6[gui,opengl,widgets]
dev-qt/qttools:6[widgets]
media-libs/coin
virtual/opengl
designer? ( dev-qt/qttools:6[designer] )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? (
app-text/doxygen[dot]
qch? ( dev-qt/qttools:6[assistant] )
)
"
PATCHES=(
"${FILESDIR}"/${PN}-1.2.1-cmake.patch
"${FILESDIR}"/${PN}-1.2.2-find-qhelpgenerator.patch # bug 933432
)
DOCS=( AUTHORS NEWS README.md )
src_prepare() {
cmake_src_prepare
sed -e 's|/lib$|/lib@LIB_SUFFIX@|' \
-i Quarter.pc.cmake.in || die
}
src_configure() {
use debug && append-cppflags -DQUARTER_DEBUG=1
local mycmakeargs=(
-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
-DQUARTER_BUILD_SHARED_LIBS=ON
-DQUARTER_BUILD_PLUGIN=$(usex designer)
-DQUARTER_BUILD_EXAMPLES=OFF
-DQUARTER_BUILD_DOCUMENTATION=$(usex doc)
-DQUARTER_BUILD_AWESOME_DOCUMENTATION=$(usex doc)
-DQUARTER_BUILD_DOC_MAN=$(usex doc)
-DQUARTER_BUILD_INTERNAL_DOCUMENTATION=OFF
-DQUARTER_BUILD_DOC_QTHELP=$(usex qch)
-DQUARTER_BUILD_DOC_CHM=OFF
-DQUARTER_USE_QT6=ON
)
use doc && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Git=ON )
cmake_src_configure
}