dev-scheme/guile-ncurses: new package; add version 3.0

Closes: https://bugs.gentoo.org/352175
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

dev-scheme/guile-ncurses/Manifest

@@ -0,0 +1 @@
+DIST guile-ncurses-3.0.tar.gz 910030 BLAKE2B e7bfa1e7c7ff8fd4e8b653a5bcada99f8f047142322e4abb946cd42b27bd1d2014f904b5a73d5356ad95bec1c394d0b76ad06204a7d117ab4c2e9a3181633fa2 SHA512 6f36ec57b1835dc90f6691243e3b627e067522c78ea620fc109bf270016034842a933c2d9e09c1a3998a740ae17cb1b7ae291d3e4c578c54128eae4c88a450ac

dev-scheme/guile-ncurses/guile-ncurses-3.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Guile FFI to ncurses library for text-based console UI"
+HOMEPAGE="https://www.gnu.org/software/guile-ncurses/"
+SRC_URI="mirror://gnu/guile-ncurses/${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="strip"
+
+RDEPEND="
+	>=dev-scheme/guile-2.0.0:=
+	sys-libs/ncurses:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-apps/texinfo"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	# Remove bad tests
+	# > In procedure list-ref: Wrong type argument in position 1: #f
+	local bad_tests=(
+		curs_attr_attr_off_underline
+		curs_attr_attr_on_blink
+		curs_attr_attr_on_bold
+		curs_attr_attr_on_dim
+		curs_attr_attr_on_invis
+		curs_attr_attr_on_protect
+		curs_attr_attr_on_reverse
+		curs_attr_attr_on_standout
+		curs_attr_attr_on_underline
+		curs_attr_attr_set
+		curs_attr_attr_set_normal
+		curs_attr_standend
+		curs_attr_standout
+		curs_bkgd_bkgd
+		curs_bkgd_bkgdset
+	)
+	local bad_test
+	for bad_test in "${bad_tests[@]}" ; do
+		echo "#t" > test/${bad_test}.scm || die
+	done
+}
+
+src_test() {
+	emake check
+}

dev-scheme/guile-ncurses/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>scheme@gentoo.org</email>
+    <name>Gentoo Scheme Project</name>
+  </maintainer>
+  <longdescription>
+    GNU Guile-Ncurses is a library for the Guile Scheme interpreter that
+    provides functions for creating text user interfaces. The text user
+    interface functionality is built on the ncurses libraries: curses, form,
+    panel, and menu.
+  </longdescription>
+</pkgmetadata>