mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-10 06:57:08 -08:00
media-libs/oneVPL: add 2023.3.0
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST oneVPL-2023.2.1.tar.gz 6315268 BLAKE2B f5b5609c27f5f2eddd4533480e053bd6868eab736b88fca5b061311374d8a4f2cadec100ad313b8a062604c6b38848d33a26a775524c250dbef7e2930204d82f SHA512 333df9fc58b9d1d0c832241420321f8cbc84d722d1453f24b7f1990ae1e3065b103940d88f84d7d339b527c4cf5fe6e72c6eaa0b2c736d1b980e09228093f279
|
||||
DIST oneVPL-2023.3.0.tar.gz 6310097 BLAKE2B 09d63cbed73a93727f770306ca4ee4b6418f87ffe2d0d6f53988569028ad8dba4226e5a4d19dedc4b5e10f037a798683e74acd456469413c9f7161c30bb5b010 SHA512 2f3b8f6b3bb26df062bf7e962ae45eb11f5a60d24f7a69e653e7afc9c0c7960b1c708a2d1c5bf18ad5e2981b01f877a08be2c7513bfc30b62574cd932ea9549b
|
||||
|
||||
@@ -0,0 +1,82 @@
|
||||
# Copyright 2022-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit cmake-multilib optfeature
|
||||
|
||||
DESCRIPTION="oneAPI Video Processing Library, dispatcher, tools, and examples"
|
||||
HOMEPAGE="https://github.com/oneapi-src/oneVPL"
|
||||
SRC_URI="https://github.com/oneapi-src/oneVPL/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64"
|
||||
|
||||
IUSE="dri drm examples experimental tools test vaapi wayland X"
|
||||
RESTRICT="!test? ( test )"
|
||||
# Tools fails to compile on 32-bit
|
||||
REQUIRED_USE="
|
||||
dri? ( X drm )
|
||||
X? ( vaapi )
|
||||
wayland? ( drm )
|
||||
abi_x86_32? ( !tools )
|
||||
abi_x86_x32? ( !tools )
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
x11-libs/libpciaccess[${MULTILIB_USEDEP}]
|
||||
vaapi? ( media-libs/libva[X?,wayland?,drm(+)?,${MULTILIB_USEDEP}] )
|
||||
drm? ( x11-libs/libdrm[${MULTILIB_USEDEP}] )
|
||||
wayland? (
|
||||
dev-libs/wayland[${MULTILIB_USEDEP}]
|
||||
)
|
||||
X? (
|
||||
x11-libs/libX11[${MULTILIB_USEDEP}]
|
||||
x11-libs/libxcb[${MULTILIB_USEDEP}]
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
wayland? (
|
||||
dev-libs/wayland-protocols
|
||||
)
|
||||
"
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
multilib_src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_SHARED_LIBS=ON
|
||||
-DBUILD_DISPATCHER=ON
|
||||
# Headers, cmake and pkgconfig files
|
||||
-DBUILD_DEV=ON
|
||||
-DBUILD_EXAMPLES="$(usex examples)"
|
||||
-DINSTALL_EXAMPLE_CODE="$(usex examples)"
|
||||
-DBUILD_PREVIEW="$(usex experimental)"
|
||||
-DBUILD_DISPATCHER_ONEVPL_EXPERIMENTAL="$(usex experimental)"
|
||||
# Fails to build with experimental tools off if tools on
|
||||
-DBUILD_TOOLS_ONEVPL_EXPERIMENTAL="$(usex tools)"
|
||||
-DBUILD_TESTS="$(usex test)"
|
||||
-DBUILD_TOOLS="$(usex tools)"
|
||||
-DENABLE_WAYLAND="$(usex wayland)"
|
||||
-DENABLE_X11="$(usex X)"
|
||||
-DENABLE_DRI3="$(usex dri)"
|
||||
-DENABLE_VA="$(usex vaapi)"
|
||||
-DENABLE_DRM="$(usex drm)"
|
||||
-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
|
||||
-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
|
||||
)
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
cmake_src_install
|
||||
# Remove these license files
|
||||
rm -r "${ED}/usr/share/vpl/licensing" || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature_header "This package provides only the dispatcher, to use it install one or more implementations"
|
||||
optfeature "CPUs" media-libs/oneVPL-cpu
|
||||
optfeature "Intel GPUs newer then, and including, Intel Xe" media-libs/oneVPL-intel-gpu
|
||||
optfeature "Intel GPUs older then Intel Xe" media-libs/intel-mediasdk
|
||||
}
|
||||
Reference in New Issue
Block a user