x11-wm/icewm: Bump to version 1.5.3

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
2019-03-28 13:14:41 +01:00
parent 8773519a6a
commit eb4e22d29b
2 changed files with 120 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST icewm-1.4.2.tar.gz 1709850 BLAKE2B 1a9dde495345f1601b3ae901b3e98554b60a9b9a8e94b7079f3c766971eb31bde5a3cd3972f5c96d86b5e02e413811df2a0689efc15a461bca39a70842f3df69 SHA512 c01661a7b07b4f42a32b20ecc9e45fb1e9c84c27d33105ec165e75aa9ac84129d55e992cac0d53fb10298bae28bc93ef07f68e874c1c2fccd9adecceb987a872
DIST icewm-1.5.1.tar.xz 1666056 BLAKE2B 2cd417a9d3097f57cef1bf44b8c4ef4237db962ea5edd8b902338de90d9b28a46aa7f0a720abe87361847836ffd8feb9e0269124260b324ed14b27f0ba7d94b2 SHA512 e7329ccf87da5ad12402c70a3946303f58c76563d25319b9e8f6d153b34a67df0e17612874f8af3bea701b52d15168557842e8ffce0a5a255c59e67bd2022a01
DIST icewm-1.5.2.tar.xz 1662664 BLAKE2B 612cf919a685a50844b0085d63855a7fdbbd322cb9792fe250420566b1188efc390cfe79fef40386d9328b896f60ba94cc7cc7d87b78866433e2234666ec4206 SHA512 f2a542d162e984dcc6f7b8e3fc2dbd7df46510f961431b4c3b6651351f7b236ef4724a07ce01dfa163b08c9a130e7ee3ed62e1c5b1f364340998d31290323614
DIST icewm-1.5.3.tar.xz 1679384 BLAKE2B 6a855e6305083815173ed16f043ee6da3041b0b8ee537e5ac217dc6aca1d5a9b4303b7cf81ea4cd857fed55b64bd0842f6e2e7cacdf19d9c7abfb50df93a73d9 SHA512 3fb7bb3002687fc3105c61f062600015cf59173e054e3dc3dc1af4ec960991790bbb5b4ba842e9c67c8f73fb8189ae76772f3df58fd679884c85239e6d93a3cb
+119
View File
@@ -0,0 +1,119 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Ice Window Manager with Themes"
HOMEPAGE="https://ice-wm.org/ https://github.com/ice-wm/icewm"
LICENSE="GPL-2"
SRC_URI="https://github.com/ice-wm/icewm/releases/download/${PV}/${P}.tar.xz"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="+alsa ao bidi debug nls truetype uclibc xinerama"
# Tests broken in all versions, patches welcome, bug #323907, #389533
RESTRICT="test"
REQUIRED_USE="|| ( alsa ao )"
#fix for icewm preversion package names
S="${WORKDIR}/${P/_}"
RDEPEND="
media-libs/fontconfig
x11-libs/gdk-pixbuf:2[X]
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXft
x11-libs/libXrandr
x11-libs/libXrender
alsa? (
media-libs/alsa-lib
media-libs/libsndfile[alsa]
)
ao? (
media-libs/libao
media-libs/libsndfile
)
bidi? ( dev-libs/fribidi )
truetype? ( x11-libs/libXext )
xinerama? ( x11-libs/libXinerama )
"
DEPEND="
${RDEPEND}
gnome-base/librsvg
x11-base/xorg-proto
truetype? ( >=media-libs/freetype-2.0.9 )
"
BDEPEND="
app-text/asciidoc
nls? ( >=sys-devel/gettext-0.19.6 )
"
src_prepare() {
# Fix bug #486710 - TODO: Still needed?
#use uclibc && PATCHES+=( "${FILESDIR}/${PN}-1.3.8-uclibc.patch" )
default
eautoreconf
}
src_configure() {
local icesound
if use alsa && use ao ; then
icesound="alsa,ao"
elif use alsa ; then
icesound="alsa"
elif use ao ; then
icesound="ao"
fi
local myconf=(
--enable-gdk-pixbuf
--enable-logevents
--enable-xrandr
--enable-xrender
--with-cfgdir=/etc/icewm
--with-docdir=/usr/share/doc/${PF}/html
--with-icesound="${icesound}"
--with-libdir=/usr/share/icewm
$(use_enable bidi fribidi)
$(use_enable debug)
$(use_enable nls i18n)
$(use_enable nls)
$(use_enable xinerama)
)
if use truetype ; then
myconf+=(
--enable-shape
)
else
myconf+=(
--disable-xfreetype
--enable-corefonts
)
fi
CXXFLAGS="${CXXFLAGS}" econf "${myconf[@]}"
sed -i "s:/icewm-\$(VERSION)::" src/Makefile || die
sed -i "s:ungif:gif:" src/Makefile || die "libungif fix failed"
}
src_install(){
local DOCS=( AUTHORS ChangeLog NEWS README.md TODO VERSION )
default
docinto html
dodoc doc/icewm.html
dodoc man/*.html
exeinto /etc/X11/Sessions
doexe "${FILESDIR}/icewm"
}