www-client/epiphany: Version bump

Package-Manager: portage-2.3.0_rc1
This commit is contained in:
Pacho Ramos
2016-07-03 18:33:27 +02:00
parent b9789805c4
commit eb232b5bdc
2 changed files with 77 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST epiphany-3.18.7.tar.xz 3059580 SHA256 90513aea04d66a4387da076db1b8104b54d3657a81aff2d629b527b32d9eec76 SHA512 a2a47bbe282f089b14ff48e33ec00dc11a66377d2583db3f7f2dc621e6e1d53640bca6861293933e988db200d221b1f36c74e32372fd6a89eeb7c436a8f8e3f2 WHIRLPOOL 05a6b13019daf9c598577300ab6addb934bacadd4c6b62b07c9a4d22dfdb0da686aea5d6dc7b73cdeff6b8e3f2f903b43a802c7707cfc70d42d68b9a728c895f
DIST epiphany-3.20.3.tar.xz 2182864 SHA256 4d9de1bdb44c14adf25aa6dc02ea3de60925cff5eb01fe89545e6032c9b424a2 SHA512 853a8efd67374f5550263cf4f102ac680b6b5bf1e948d5bb4448bc3dbe89401034709e391e527bce50a8f210cf2ae525d7f5c8e997fd665946986c5078caf3a9 WHIRLPOOL a7736abe4e121b15f27dc5ca32a7d9f6a26e2526523d605d8394d179e362b99c99067f7a2bc6f36004b9424e0fe295b2f6bb7a294b7dfbcceb7bb0ce3a80420c
@@ -0,0 +1,76 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
GNOME2_LA_PUNT="yes"
inherit eutils gnome2 virtualx
DESCRIPTION="GNOME webbrowser based on Webkit"
HOMEPAGE="https://wiki.gnome.org/Apps/Web"
LICENSE="GPL-2"
SLOT="0"
IUSE="test"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
COMMON_DEPEND="
>=app-crypt/gcr-3.5.5:=
>=app-crypt/libsecret-0.14
>=app-text/iso-codes-0.35
>=dev-libs/glib-2.44.0:2[dbus]
>=dev-libs/libxml2-2.6.12:2
>=dev-libs/libxslt-1.1.7
>=gnome-base/gsettings-desktop-schemas-0.0.1
>=net-dns/avahi-0.6.22[dbus]
>=net-libs/webkit-gtk-2.11.4:4=
>=net-libs/libsoup-2.48:2.4
>=x11-libs/gtk+-3.19.1:3
>=x11-libs/libnotify-0.5.1:=
gnome-base/gnome-desktop:3=
dev-db/sqlite:3
x11-libs/libwnck:3
x11-libs/libX11
"
# epiphany-extensions support was removed in 3.7; let's not pretend it still works
RDEPEND="${COMMON_DEPEND}
x11-themes/adwaita-icon-theme
!www-client/epiphany-extensions
"
# paxctl needed for bug #407085
# eautoreconf requires gnome-common-3.5.5
DEPEND="${COMMON_DEPEND}
app-text/yelp-tools
dev-libs/appstream-glib
>=dev-util/intltool-0.50
dev-util/itstool
sys-apps/paxctl
sys-devel/gettext
virtual/pkgconfig
"
PATCHES=(
# https://bugzilla.gnome.org/show_bug.cgi?id=751591
"${FILESDIR}"/${PN}-3.16.0-unittest-1.patch
# https://bugzilla.gnome.org/show_bug.cgi?id=751593
"${FILESDIR}"/${PN}-3.14.0-unittest-2.patch
)
src_configure() {
# Many years have passed since gecko based epiphany went away,
# hence, stop relying on nss for migrating from that versions.
gnome2_src_configure \
--disable-nss \
--enable-shared \
--disable-static \
--with-distributor-name=Gentoo \
$(use_enable test tests)
}
src_test() {
"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check
}