app-office/skrooge: 2.27.0 version bump

See also: https://skrooge.org/node/246 Package-Manager: Portage-3.0.30, Repoman-3.0.3 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-06 17:47:07 -08:00 · 2022-01-26 11:01:43 +01:00
parent ba714930c6
commit eb08f2217f
2 changed files with 100 additions and 0 deletions
@@ -1 +1,2 @@
 DIST skrooge-2.26.1.tar.xz 22138584 BLAKE2B 15328406763c69a1a746dc099be815e8c49163c5e99e5d8c985a368b1d629759c519b261b2f06b27e83bb538f6ccbf4a2a2d25ca31262f0e407805639bab7d8d SHA512 03263689310e1c7538acdd133f7b6cfcd67c51a4d426ee4512609408c91968a1369f2ef09da851958c210b4399c706ad35af5b384fcea8ec7a25705a548ae537
+DIST skrooge-2.27.0.tar.xz 22185204 BLAKE2B 803281a5a5c491d696a43e046d28d9e846a1c8fa3456a5f93da1a2697d6d3a3181311eff50a06fa0190a99561f72afababa0d623bd8b93b22b8704106c48a8ba SHA512 d97ecb852c212d880b2ffc441e1a31915318800c06c386773cf9845f88e7ff4c8cefc72508e5d6c46f6bd1fdd93c0e9f2d2249c3ed05a878fd843a0c6c358d51
@@ -0,0 +1,99 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=5.82.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Personal finances manager, aiming at being simple and intuitive"
+HOMEPAGE="https://skrooge.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="5"
+IUSE="activities kde ofx"
+
+# hangs + installs files (also requires KF5DesignerPlugin)
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=app-crypt/qca-2.3.0:2
+	dev-db/sqlcipher
+	dev-libs/grantlee:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5=
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	kde? ( >=kde-frameworks/krunner-${KFMIN}:5 )
+	ofx? ( dev-libs/libofx:= )
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+"
+BDEPEND="
+	dev-libs/libxslt
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSKG_WEBENGINE=ON
+		-DSKG_WEBKIT=OFF
+		-DSKG_DESIGNER=OFF
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package kde KF5Runner)
+		$(cmake_use_find_package ofx LibOfx)
+		-DSKG_BUILD_TEST=$(usex test)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local mycmakeargs=(
+		-DSKG_BUILD_TEST=ON
+	)
+	ecm_src_test
+}