gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-11-09 06:37:10 -08:00
Code Issues Projects Releases Wiki Activity

kde-apps/dolphin: 23.08.5 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2024-02-15 13:22:22 +01:00
parent 3356fcec76
commit eade181db2
2 changed files with 99 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files
kde-apps/dolphin/Manifest
+1
View File
@@ -1,2 +1,3 @@
DIST dolphin-23.04.3.tar.xz 5737968 BLAKE2B 5942d5894c2d51cc3f0c5ab599bb82c2e324203f26a6b7a65dca2198cf046011c37d809ca71c2ef36db1687d8159bdbe97f33eb99d550eada982555d903c381e SHA512 6078947b3dd6c1c62ba2306109c9dcc4be6ebb64bb69699f0457aaa1e0b6b0168d8767d73f0f8731984f5b412200c5463df7237c65990ee073f2d35946ad7b9e
DIST dolphin-23.08.4.tar.xz 5769716 BLAKE2B dd9f27258b3e8a04c53efee66cead0a3c193a4fe0050a7d7fddaba544503da1a2d0f8bc3f8d1700303f900e69e374d0c7d9d912897ae90899d05d7c17f111543 SHA512 f0e7af7a066f71b155292d7a49ff217f89be5f062629e67ed9a43ce3ed77cbb09b3b037de71bea7d21fc97732c0545fda3530e5eabed54a581384792d3195db9
DIST dolphin-23.08.5.tar.xz 5770048 BLAKE2B d46cbd81d2f6e020998fe560affa45916fdcf53e7acbb62503221d4a53cd582d692c025b7c9c16f6285a5d97fda696ff75198b479b7316c95e6b782c39bbb570 SHA512 0b25cc8ec1222fcd6eba971aa701a2ddcf5297c4d78b1cd63fde7ecf8e267f1af76ca1bf544ea4a4f98309b40c41aba441cfda1a9c3fb0e4df2a426e4402cb4b
kde-apps/dolphin/dolphin-23.08.5.ebuild
+98
View File
@@ -0,0 +1,98 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=5.106.0
QTMIN=5.15.9
inherit ecm gear.kde.org optfeature
DESCRIPTION="Plasma filemanager focusing on usability"
HOMEPAGE="https://apps.kde.org/dolphin/ https://userbase.kde.org/Dolphin"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="activities semantic-desktop telemetry"
DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtx11extras-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5=
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=media-libs/phonon-4.11.0[qt5(+)]
activities? ( >=kde-plasma/plasma-activities-${KFMIN}:5 )
semantic-desktop? (
>=kde-apps/baloo-widgets-${PVCUT}:5
>=kde-frameworks/baloo-${KFMIN}:5
>=kde-frameworks/kfilemetadata-${KFMIN}:5
)
telemetry? ( kde-frameworks/kuserfeedback:5 )
"
RDEPEND="${DEPEND}
|| (
kde-apps/kio-extras-kf5:5
>=kde-apps/kio-extras-${PVCUT}:5
)
"
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
$(cmake_use_find_package activities KF5Activities)
$(cmake_use_find_package semantic-desktop KF5Baloo)
$(cmake_use_find_package semantic-desktop KF5BalooWidgets)
$(cmake_use_find_package semantic-desktop KF5FileMetaData)
$(cmake_use_find_package telemetry KUserFeedback)
)
ecm_src_configure
}
src_test() {
local myctestargs=(
# servicemenuinstaller requires ruby, no thanks
# dolphinmainwindowtest, kitemlistcontrollertest, kfileitemlistviewtest, kfileitemmodeltest hang forever
# placesitemmodeltest requires DBus
-E "(servicemenuinstaller|dolphinmainwindowtest|kfileitemlistviewtest|kfileitemmodeltest|kitemlistcontrollertest|placesitemmodeltest)"
)
ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "compress/extract and other actions" kde-apps/ark:${SLOT}
optfeature "crypto actions" kde-apps/kleopatra:${SLOT}
optfeature "video file thumbnails" kde-apps/ffmpegthumbs:${SLOT}
optfeature "graphics file thumbnails" kde-apps/thumbnailers:${SLOT}
optfeature "'Share' context menu actions" kde-frameworks/purpose:${SLOT}
fi
ecm_pkg_postinst
}