media-libs/libde265: add 1.0.16

Signed-off-by: Sam James <sam@gentoo.org>

media-libs/libde265/Manifest

@@ -1 +1,2 @@
 DIST libde265-1.0.15.tar.gz 846016 BLAKE2B b968a46dd56c3dda7da0e24289ccf24d08baf382771794dafacba942de41b7458b3a515e22abe2f35465bac731e67f29b409dbc95ced3531a211e6e40a1ea774 SHA512 375d8e781108247e0e8b4d7a036d20cc5d0670bdbf6ddb40a6d3dbf912fa776d2f001fb762301cb97e4d43be29eb415b0cdbfc6e07aa18b3f2346f7409c64fce
+DIST libde265-1.0.16.tar.gz 835657 BLAKE2B 7095d2659036e7323c2c26fea7c45c67152dd054856b2534456ec679ff6b75ba6375a3b154f68eb86b938d08ea99ae654e782ef1ff8a253252bd65d8225caaa8 SHA512 07f4dd75238030ed86f1b86d990a5a1c31866d5217db2aa23757432da214a19c5f4094a6c2f8fe3453c64d36ee745ca4f1e22a19a80b2685b6530431a35eb4e1

media-libs/libde265/libde265-1.0.16.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strukturag/libde265/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Open h.265 video codec implementation"
+HOMEPAGE="https://github.com/strukturag/libde265"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="enc265 dec265 sdl tools debug cpu_flags_x86_sse4_1 cpu_flags_arm_neon cpu_flags_arm_thumb"
+# IUSE+=" sherlock265" # Require libvideogfx or libswscale
+
+RDEPEND="
+	dec265? (
+		sdl? ( media-libs/libsdl2 )
+	)"
+
+# Sherlock265 require libvideogfx or libswscale
+#RDEPEND+="
+#	sherlock265? (
+#		media-libs/libsdl
+#		dev-qt/qtcore:5
+#		dev-qt/qtgui:5
+#		dev-qt/qtwidgets:5
+#		media-libs/libswscale
+#	)
+#"
+
+DEPEND="${RDEPEND}"
+BDEPEND="dec265? ( virtual/pkgconfig )"
+
+# Sherlock265 require libvideogfx or libswscale
+#BDEPEND+=" sherlock265? ( virtual/pkgconfig )"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.2-qtbindir.patch )
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# without this, headers would be missing and make would fail
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-log-error
+		ax_cv_check_cflags___msse4_1=$(usex cpu_flags_x86_sse4_1)
+		ax_cv_check_cflags___mfpu_neon=$(usex cpu_flags_arm_neon)
+		$(use_enable cpu_flags_arm_thumb thumb)
+		$(use_enable debug log-info)
+		$(use_enable debug log-debug)
+		$(use_enable debug log-trace)
+		$(multilib_native_use_enable enc265 encoder)
+		$(multilib_native_use_enable dec265)
+	)
+
+	# myeconfargs+=( $(multilib_native_use_enable sherlock265) ) # Require libvideogfx or libswscale
+	myeconfargs+=( --disable-sherlock265 )
+
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi; then
+		# Remove useless, unready and test tools
+		rm "${ED}"/usr/bin/{tests,gen-enc-table,yuv-distortion} || die
+		if ! use tools; then
+			rm "${ED}"/usr/bin/{bjoentegaard,block-rate-estim,rd-curves} || die
+			# Disabled as of 1.0.16
+			# https://github.com/strukturag/libde265/commit/edf58dd61c50fb28f4b31569c250389f125bd826
+			#rm "${ED}"/usr/bin/acceleration_speed || die
+		fi
+	else
+		# Remove all non-native binary tools
+		rm "${ED}"/usr/bin/* || die
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+	einstalldocs
+}

media-libs/libde265/libde265-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -81,7 +81,9 @@ multilib_src_install() {
 		rm "${ED}"/usr/bin/{tests,gen-enc-table,yuv-distortion} || die
 		if ! use tools; then
 			rm "${ED}"/usr/bin/{bjoentegaard,block-rate-estim,rd-curves} || die
-			rm "${ED}"/usr/bin/acceleration_speed || die
+			# Disabled as of 1.0.16
+			# https://github.com/strukturag/libde265/commit/edf58dd61c50fb28f4b31569c250389f125bd826
+			#rm "${ED}"/usr/bin/acceleration_speed || die
 		fi
 	else
 		# Remove all non-native binary tools