net-misc/moonlight: Version bump to 5.0.0

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

net-misc/moonlight/Manifest

@@ -1 +1,2 @@
 DIST MoonlightSrc-4.3.1.tar.gz 71454450 BLAKE2B cd6d8d95c3d53dbf73850cd30f86bdb9837806a642472454d70f6abee20ae91bc79c0671c4da0a74fb5f43086841a8318718c4f2f4e4768b395fb4b38d1dde9e SHA512 f5f7b23929aadb87716470522a315cba40d8155be6b76297eab4107e0fef71b48f9f4c9a4cc2b58bd48579db052a8ca8ecda9b49c78c3d229863a30886cf1847
+DIST MoonlightSrc-5.0.0.tar.gz 79821343 BLAKE2B 91a57f70863cd9c8a8a0cb28cc0475468485d449747fb3425dce41c046af992f9b636036cf735799042d895e69c2c88fbc48d1b1b874bd03a3b1eef97d6c98ad SHA512 067f862d2f33a7b2d47b6465951a5618a81f027219b9dcbe976154abaa7e0ba3913e59096584bbb8f86170d677804bb5e1412f7bd71727d9f8ac519adde097d3

net-misc/moonlight/moonlight-5.0.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/moonlight-stream/moonlight-qt.git"
+	EGIT_SUBMODULES=( '*' -libs -soundio )
+	inherit git-r3
+else
+	SRC_URI="https://github.com/moonlight-stream/moonlight-qt/releases/download/v${PV}/MoonlightSrc-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+	S="${WORKDIR}"
+fi
+
+inherit qmake-utils xdg
+
+DESCRIPTION="NVIDIA GameStream (and Sunshine) client"
+HOMEPAGE="https://github.com/moonlight-stream/moonlight-qt"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="cuda +libdrm embedded glslow mmal soundio +vaapi vdpau wayland X"
+
+RDEPEND="
+	dev-libs/openssl:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-libs/libglvnd
+	media-libs/libpulse
+	media-libs/libsdl2[haptic,kms,joystick,sound,video]
+	media-libs/opus
+	media-libs/sdl2-ttf
+	media-video/ffmpeg:=[cuda?,libdrm?,mmal?]
+	libdrm? ( x11-libs/libdrm )
+	soundio? ( media-libs/libsoundio:= )
+	vaapi? ( media-libs/libva:=[wayland?,X?] )
+	vdpau? ( x11-libs/libvdpau )
+	wayland? ( dev-libs/wayland )
+	X? ( x11-libs/libX11 )
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="
+	dev-qt/qtcore
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Force system libsoundio over bundled version.
+	rm -r soundio/ || die
+}
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}/usr" CONFIG+=" \
+		$(usex cuda "" disable-cuda) \
+		$(usex libdrm "" disable-libdrm) \
+		$(usex mmal "" disable-mmal) \
+		$(usex vaapi "" disable-libva) \
+		$(usex vdpau "" disable-libvdpau) \
+		$(usex wayland "" disable-wayland) \
+		$(usex X "" disable-x11) \
+		$(usev embedded) \
+		$(usev glslow) \
+		$(usev soundio) \
+	"
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+	einstalldocs
+}