media-gfx/sxiv: version bump to 26

Signed-off-by: Tim Harder <radhermit@gentoo.org>

media-gfx/sxiv/Manifest

@@ -1 +1,2 @@
 DIST sxiv-25.tar.gz 48814 BLAKE2B 17ef2ff0e75acd6acce068dfc17dfbce78bb1a38b652e948b5f88902adcbae504e9322c92d125b71c511a95c7e8e47b58060ff58e2c804a7296b5a801d3fc0e8 SHA512 ca0d834c9982c5e98c0bae51d21b7d08692af2d692eeb2ac55e19c4da7d09b16bbaa8022af0a0d00c52def4120058d895f37a2f8b14f453a0ceb65eebe564814
+DIST sxiv-26.tar.gz 48569 BLAKE2B a73707e2fd699b53e38ddc48710a73b945d4e102743567283d7351c92c513e4e57a32c409267593a2c5808caf811b7caeb555f8ba2762f1cc76a421aceff0e95 SHA512 c4bd56ea14e520ea9b116e275009f2089e5c434d6894281215b09d07572b2d3190c3c3eca015a2933328d704afb7d443a66e858b4e6904a3d4d45378b35d22cb

media-gfx/sxiv/sxiv-26.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop xdg-utils savedconfig toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/muennich/sxiv.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/muennich/sxiv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Simple (or small or suckless) X Image Viewer"
+HOMEPAGE="https://github.com/muennich/sxiv/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="exif gif +jpeg +png"
+
+RDEPEND="
+	exif? ( media-libs/libexif )
+	gif? ( media-libs/giflib:0= )
+	media-libs/imlib2[X,gif?,jpeg?,png?]
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	restore_config config.h
+	default
+}
+
+src_compile() {
+	emake V=1 CC="$(tc-getCC)" HAVE_LIBEXIF=$(usex exif 1 0) HAVE_GIFLIB=$(usex gif 1 0)
+}
+
+src_install() {
+	emake DESTDIR="${ED}" PREFIX=/usr install
+	emake -C icon DESTDIR="${ED}" PREFIX=/usr install
+	dodoc README.md
+	domenu sxiv.desktop
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}

media-gfx/sxiv/sxiv-9999.ebuild

@@ -1,9 +1,9 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-inherit desktop xdg-utils gnome2-utils savedconfig toolchain-funcs
+inherit desktop xdg-utils savedconfig toolchain-funcs
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="https://github.com/muennich/sxiv.git"
@@ -47,16 +47,12 @@ src_install() {
 	save_config config.h
 }
 
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
 pkg_postinst() {
 	xdg_desktop_database_update
-	gnome2_icon_cache_update
+	xdg_icon_cache_update
 }
 
 pkg_postrm() {
 	xdg_desktop_database_update
-	gnome2_icon_cache_update
+	xdg_icon_cache_update
 }