kde-apps/kdenlive: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kdenlive/Manifest

@@ -1 +1,2 @@
 DIST kdenlive-20.12.3.tar.xz 11514396 BLAKE2B eb789a2dcddc67a73122d3fcab06d43d72566de8aeec97dd7bc8b76918231a859e86c8859be7eaab4017c9048edaa951fd143d8e24187437252490464bef0773 SHA512 b21c9bd59171969ab84b93bab2617333160521c3b99b61a2182f9d9b5e65c3220b6dd960d71fe5eeb032733127392dafd40748b950b9973e0edfb5ae6317380a
+DIST kdenlive-21.04.0.tar.xz 11717116 BLAKE2B 4717757f24b81c3f8ece13e0968a14ae01254bcb168fef7d1827d3cc0b826d395f58454c59b8172621ff170411a7b29b9f3befb9340c9eb50412ebc7ed624aac SHA512 cc44df08e0fbe2a16646d005782aac3a8522e95cabc6cfb157b083f460e77e37bad0ef39b8a8ab2aa488faab161e81fb527108daf71d4f3b281b2ad18148a17f

kde-apps/kdenlive/kdenlive-21.04.0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=5.80.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Non-linear video editing suite by KDE"
+HOMEPAGE="https://kdenlive.org/en/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="gles2-only semantic-desktop share v4l"
+
+RESTRICT+=" test" # segfaults, bug 684132
+
+BDEPEND="
+	sys-devel/gettext
+"
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtnetworkauth-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=media-libs/mlt-6.26.0[ffmpeg,frei0r,kdenlive(+),melt(+),qt5,sdl,xml]
+	semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	v4l? ( media-libs/libv4l )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	media-video/ffmpeg[encode,sdl,X]
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package semantic-desktop KF5FileMetaData)
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package v4l LibV4L2)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	# Gentoo bug 603168
+	if ! has_version "media-libs/mlt[fftw]" ; then
+		elog "For 'Crop and Transform/Rotate and Shear' effect, please build media-libs/mlt with USE=fftw enabled."
+	fi
+}