gui-libs/libadwaita: Bump to 1.5.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

gui-libs/libadwaita/Manifest

@@ -1 +1,2 @@
 DIST libadwaita-1.4.4.tar.xz 3957408 BLAKE2B ba165260677d3dabd47d31e6895271e793ccca5525253eca1147e6ac44326563f5dc8d30e01997b6c8ffe984d32d17ab5652b7f98fcbdab1e031b9025d7c019f SHA512 3b5110753efca53133ab2d5e4dc50b50727e43427744e517c8afb15ec6ff9da2cd6b280d3c590034b3f4e0960084cc1354942831d528732d5649218743a56c71
+DIST libadwaita-1.5.0.tar.xz 4352384 BLAKE2B f64fee58b2b9482a512977daef3b222b23f9a345c24f8c5aa3408f7f7013ee2c14def6a2414b4edfc7be35bc28d8e58a30c33df312a4b0fbcf9a08627a5a2640 SHA512 cdd6d128a461f4a19c663fe6af7df7aa3e97b416574311f26f16b1355a9a3164d78f498cf5cd397c8ea7617234f85ecebf1095a53117bb715ecd84bf199600ac

gui-libs/libadwaita/libadwaita-1.5.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit gnome.org meson python-any-r1 vala virtualx
+
+DESCRIPTION="Building blocks for modern GNOME applications"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+IUSE="+introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.76:2
+	>=gui-libs/gtk-4.13.4:4[introspection?]
+	dev-libs/appstream:=
+	dev-libs/fribidi
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		# Never use gi-docgen subproject
+		--wrap-mode nofallback
+
+		-Dprofiling=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		-Dgtk_doc=false # we ship pregenerated docs
+		$(meson_use test tests)
+		-Dexamples=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test --timeout-multiplier 2
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/gtk-doc/html
+	# This will install libadwaita API docs unconditionally, but this is intentional
+	doins -r "${S}"/doc/libadwaita-1
+}