dev-libs/intel-compute-runtime: add 25.31.34666.3

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-libs/intel-compute-runtime/Manifest

@@ -1,2 +1,3 @@
 DIST intel-compute-runtime-24.35.30872.32.tar.gz 7376572 BLAKE2B af924c111d288621ddcb14b9d77ff384c632668705e4858ed27424522b6c96e1e7b54012b202c6ade64da668681f3089d0a35d64ecb97ddec642ace8774b3e47 SHA512 2ac8dbefcc1a86b33afd78b8a1d30a959fb980e47402852514d43503df87ea70ea35f192243b78faedce749b3087f244631080f16ddb099a93ec79698176f6b5
 DIST intel-compute-runtime-25.22.33944.9.tar.gz 7734332 BLAKE2B 3a76ed162a4bd30de167c1a262dcd94242221e33d7511f02cac64b1e8dbd4ecb03f4fda0da6b1b29ec86b5216979a3174f8d71b96abc9ec64d038d9573381b83 SHA512 1876d474002833ab50eed97b93d38b89c4b16e6e92df94c71b5724a98233d23ba2876c07acc9ecc3c54b8d8ead63322941776a602671043b40846b146517e46a
+DIST intel-compute-runtime-25.31.34666.3.tar.gz 8030033 BLAKE2B e80bd3ca184b17b5243a6d84b68c5ae76dec6d3d1108e4e0de395db82f28facf20c352289cf3ffd7565929b934f04ef6309f336c7c67d1182c91e43507f60f17 SHA512 1ca6f411e17f18912a0137babdc5322e2d9c97da96ce302de9e78b652c3e40b98f9ed85785bcb68d305bd7f25e37f0c2a34391ed62202d4b08161e569c7b4eea

dev-libs/intel-compute-runtime/intel-compute-runtime-25.31.34666.3.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0/1.6.$(ver_cut 3)"
+KEYWORDS="~amd64"
+IUSE="disable-mitigations +l0 +vaapi"
+
+RDEPEND="
+	!dev-libs/intel-compute-runtime:legacy
+	>=dev-util/intel-graphics-compiler-2.16.0:0
+	!dev-util/intel-graphics-compiler:legacy
+	>=media-libs/gmmlib-22.7.1:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.198:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-0.9.6:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.24.1:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO_DISABLE_MITIGATIONS="$(usex disable-mitigations)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}