dev-python/trimesh: Bump to 4.12.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/trimesh/Manifest

@@ -1,3 +1,4 @@
 DIST trimesh-4.11.4.gh.tar.gz 13710953 BLAKE2B 799a9eae33a781d303a6a732b41c1744aae1aaf344d9d59dd33165865c023928246bca4fba023ceffc5d1e7131d43fe6a66457282791bda2ccf57aeb53af3714 SHA512 028b089293cac6c487a20188ef429f11813eb13641b0775ec192e3ae2c07ccb234813f94b29a3bfa7639332586889ddfe2db9f1d56fd7b0170baf919f0ac1ad8
 DIST trimesh-4.11.5.gh.tar.gz 13711494 BLAKE2B 4a03edebf9be2bb6d6fb06d6085d8d144175279ec5d876aae79d449aba93ded2410167a3b6f3692ad0ad1da96f62d2c3333beb951b0ef17586a7def8a0b4a4a3 SHA512 da32e900ab14b0abf86703db9caa7475cb906035c9b5f096cf44bb40a24d3d65dd53e2e028e3f78e14c3dd7a91a357b54c4fa802fb09ff1688022b7dd8770f14
 DIST trimesh-4.12.0.gh.tar.gz 13717504 BLAKE2B d712b44ca8fe2acbaeba61f1281294183624e54c4dbb8976ab521b49792acdc4f1b98bbfcbc8ee40f12f2f732f15bf42d6034822a28e7f9a6303390a00795a78 SHA512 80e09da861ebef2568ee61719db18eea349b7d21ab9e7b0bb5a4b4deccc43bfc52dd9e492b9c04fd5ae95e6a59a4130e69b96727ebdef989adeccbd40c9a91c6
+DIST trimesh-4.12.1.gh.tar.gz 13716880 BLAKE2B 81b32c95976169413e76e36ed03873b7ae9b67d4c2d298a660dc483557b5299c6cb23ae8d1faf8065ac5b4f47bc0a58cdd75c497514068276f00ffc00f99e4f6 SHA512 7511dfc3e1d52ac452c4b4225a9ada2c176951e18ee176b4d47236f782b4d4760121a4e3b42063eb499e7df3f046102554f1fc3684c93bc58669ab6bdc6f0b62

dev-python/trimesh/trimesh-4.12.1.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+: ${EPYTEST_TIMEOUT:=300}
+EPYTEST_RERUNS=3
+EPYTEST_XDIST=1
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires manifold3d
+	tests/test_boolean.py::test_multiple_difference
+	# timing nonsense
+	tests/test_bounds.py::BoundsTest::test_obb_mesh_large
+)
+EPYTEST_IGNORE=(
+	# require pyinstrument
+	tests/test_sweep.py
+)
+
+python_test() {
+	# We run tests in parallel, so avoid having n^2 threads in lapack
+	# tests.
+	local -x BLIS_NUM_THREADS=1
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local -x OPENBLAS_NUM_THREADS=1
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}