sys-libs/libosinfo: revbump with many fixes for 1.0.0

- Depend on the split osinfo-db package for proper runtime functionality; don't bother
avoiding build dependency on it, as tests will need it anyway. This also fixes tests.
- Add missing build deps on perl and intltool
- Pass hwids paths to configure and depends on required hwids USE flags properly
- Adjust rdeps to configure.ac check order and minimum deps expressed there
- Don't uselessly subslot := operator dep on things that don't have (sub)slots

Gentoo-bug: 602204
Gentoo-bug: 605124

sys-libs/libosinfo/libosinfo-1.0.0-r1.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 udev vala
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="http://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+
+IUSE="+introspection +vala test"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~amd64"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwids[pci,usb]
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+# perl dep is for pod2man
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-libs/gobject-introspection-common
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-usb-ids-path=/usr/share/misc/usb.ids \
+		--with-pci-ids-path=/usr/share/misc/pci.ids \
+		--disable-static \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--disable-coverage
+}