gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-02 23:48:17 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/sentry-sdk: Bump to 0.20.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2021-02-16 01:20:48 +01:00
parent c1ec7d9c08
commit e8fbccbb4e
2 changed files with 68 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/sentry-sdk/Manifest
View File

@@ -1,2 +1,3 @@
DIST sentry-sdk-0.19.5.tar.gz 206164 BLAKE2B 9d7ce2a64fcb511c659188dc18bc4af18052c0f12ff5d31848f341ef20cbc6c9cf1102d17e6e8d8b741eb8000f94978f840f3ec66b43367820e0ccce97b1fd1b SHA512 082ace137656e8cc8317e70cf4fe9823ccf8cc3ed7b54af059990cede72179924a36896a31a806de4adbbf3bd66e54d5385eb630c047b929583e32c39ed69d61
DIST sentry-sdk-0.20.1.tar.gz 210762 BLAKE2B 64ff322667374c914aa00a80ffa5eca2d92ec0965bc6bf7bdc65cf89e75a3cd5f5db32cd7e442caae515348b1f7948209e9810729f4fbc913730337f06444b73 SHA512 cd7871bd3da31340752477058fcf788401910a4e0b4ac38d53beafbedcdfe62b3216d6d2bcf2d1998e8c3e02886da76f6a8aa2809ba1e473421f96257890e75c
DIST sentry-sdk-0.20.2.tar.gz 210799 BLAKE2B 7a7b4350b664ee6947fcba64aa07a4e9f8ec274de7433d64acce55d490ea91f97a19ab7116e7af3109f806c91261f50127c72627bca1bbf76c43ad4ac89455e2 SHA512 3fb2d4ae960c86582e778afb0fdf12f3ff9103a83fb12a6c920bd6fe1e210842d29d2cfba12c254199a491a5b42288df0c388b37a8709fdabc9e6e9687b178c1

67
dev-python/sentry-sdk/sentry-sdk-0.20.2.ebuild Normal file
View File

@@ -0,0 +1,67 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit distutils-r1
DESCRIPTION="Python client for Sentry"
HOMEPAGE="https://sentry.io/ https://pypi.org/project/sentry-sdk/"
SRC_URI="https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/sentry-python-${PV}"
LICENSE="PSF-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
RDEPEND="
dev-python/urllib3[${PYTHON_USEDEP}]
dev-python/certifi[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/asttokens[${PYTHON_USEDEP}]
dev-python/django[${PYTHON_USEDEP}]
dev-python/executing[${PYTHON_USEDEP}]
dev-python/eventlet[${PYTHON_USEDEP}]
dev-python/fakeredis[${PYTHON_USEDEP}]
dev-python/flask-login[${PYTHON_USEDEP}]
dev-python/gevent[${PYTHON_USEDEP}]
dev-python/jsonschema[${PYTHON_USEDEP}]
dev-python/pyrsistent[${PYTHON_USEDEP}]
dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
dev-python/pytest-django[${PYTHON_USEDEP}]
dev-python/pytest-forked[${PYTHON_USEDEP}]
dev-python/pytest-localserver[${PYTHON_USEDEP}]
dev-python/werkzeug[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
local deselect=(
# tests require Internet access
tests/integrations/stdlib/test_httplib.py
tests/integrations/requests/test_requests.py
# wtf is it supposed to do?!
tests/integrations/gcp/test_gcp.py
# hangs
'tests/test_transport.py::test_transport_works[eventlet'
# TODO
'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
tests/test_client.py::test_databag_depth_stripping
tests/test_client.py::test_databag_string_stripping
tests/test_client.py::test_databag_breadth_stripping
# test_circular_references: apparently fragile
'tests/integrations/threading/test_threading.py::test_circular_references'
)
# Prevent tests/integrations/modules/test_modules.py:test_basic failure
# Needs to detect sentry-sdk in the installed modules
distutils_install_for_testing
pytest -vv ${deselect[@]/#/--deselect } || die "Tests failed with ${EPYTHON}"
}