x11-wm/pekwm: Add another HOMEPAGE, fix SRC_URI

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

x11-wm/pekwm/Manifest

@@ -1,2 +1,3 @@
 DIST pekwm-0.1.17.tar.bz2 405742 BLAKE2B 6cb47f92f8d32358ece8502fd706880478403ec01bb1aea0a042b2f9a110672c923c7289583f4b63b0e190b3979631c60760fae70174ecb205dfccf15baac398 SHA512 fa4c95ddc7e17f737b4e90f32258a79bf2a0abe96a2ab1a4166b1aa6832ff7a978116d224c98c31a4b33444b3c59e9ecd6095ca062d8a65f0f6174803f5b0811
+DIST pekwm-0.1.17.tar.gz 429100 BLAKE2B 2b467539ef47f4404411f25146f9f945f9a63b7e4c85c997ed2cd0bf76ea713758e3a09dc9648064c02ab29818399623d12d78394f250c79f8f667a6e057281c SHA512 1950888402f11c5cd72c9d82de976c472d4a0443da206629a039d19a1729660fd7cd09535d35984d554dcdb366918d9e29536b1272521f36f7e54499df0c14af
 DIST pekwm-themes.tar.bz2 138599 BLAKE2B b0c103d7ade6f9bb1ed19b7e12cfcf00fb48be7e1ed141a4b52aee404ebf9c7af5d29af166ff7265a720ca8d122ad7eddb6eaf42a0a8e18b6c1ff3af7b5e12d0 SHA512 c95bc980b5aeeb4f4832cb2dbbf82adf72e4a784fcd46432fd6e6a6577ef02823ec1c4b861d07747c066050fc5040aca975e2cdc78342abab99a3d486888a25d

x11-wm/pekwm/pekwm-0.1.17-r2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools desktop
+
+DESCRIPTION="A lightweight window manager initially based on aewm++"
+HOMEPAGE="
+	https://www.pekwm.org/
+	https://github.com/pekdon/pekwm
+"
+SRC_URI="
+	https://github.com/pekdon/${PN}/archive/release-${PV}.tar.gz -> ${P}.tar.gz
+	themes? ( https://dev.gentoo.org/~jer/${PN}-themes.tar.bz2 )
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~ppc ~x86 ~x86-fbsd"
+IUSE="contrib debug themes truetype xinerama"
+
+RDEPEND="
+	media-libs/libpng:0=
+	virtual/jpeg:0
+	x11-libs/libXpm
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	truetype? ( x11-libs/libXft )
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+S=${WORKDIR}/${PN}-release-${PV}
+
+src_prepare() {
+	if use themes; then
+		rm "${WORKDIR}"/themes/Ace/.theme.swp || die
+	fi
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable truetype xft) \
+		$(use_enable xinerama) \
+		--enable-image-jpeg \
+		--enable-image-png \
+		--enable-image-xpm \
+		--enable-shape \
+		--enable-xrandr
+}
+
+src_install() {
+	default
+
+	# Install contributor scripts into doc folder
+	if use contrib ; then
+		docinto /usr/share/doc/${PF}/contrib
+		dodoc contrib/lobo/{check.png,pekwm_autoprop.pl,pekwm_menu_config.pl} \
+			contrib/lobo/{pekwm_menu_config.pl.vars,README,uncheck.png}
+	fi
+
+	if use themes; then
+		insinto /usr/share/${PN}/themes
+		doins -r "${WORKDIR}"/themes/*
+	fi
+
+	# Insert an Xsession
+	echo -e "#!/bin/sh\n\n/usr/bin/${PN}" > "${T}"/${PN} || die
+	exeinto /etc/X11/Sessions
+	doexe "${T}"/${PN}
+
+	# Insert a GDM/KDM xsession file
+	make_session_desktop ${PN} ${PN}
+}
+
+pkg_postinst() {
+	if use contrib ; then
+		elog " User contributed scripts have been installed into:"
+		elog " /usr/share/doc/${PF}/contrib"
+	fi
+}