gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/uvloop: Remove old

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-11-03 03:54:18 +01:00
parent 43929edab1
commit e81e1ab2fb
3 changed files with 0 additions and 172 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
dev-python/uvloop/Manifest
View File

@@ -1,4 +1,2 @@
DIST uvloop-0.19.0-cython3.patch.xz 6352 BLAKE2B 4a7056299d3d430ce5b6986d43ba4f20726ae4f9635042a43e2995ea373ed53ddce6af2eaa32202f81f80a27bd1d814e635a6be091b5f751bcf6825fd2c8e88a SHA512 aeda541f1327860d23b31ffda9923270a56a8311ec86b06f3bd653478bff591372106e8848af5229e3ad298e950b4c3a728ab4dd9056219b8afe55f5dd58ee3d
DIST uvloop-0.20.0.tar.gz 2329938 BLAKE2B c9f230b16227bc98c071e060c98b4920d919c732f20237aedb3af9eb0b21d224bcdd6bd10c77ad45d24c64c70fb7e0d3ccde6d1eb90c67c33c1671bacad2a3b0 SHA512 9597f66e735b039b3eb6ad9ae3a1e58e710e6ba38b9131384befde15795f2a5fde7d5724af0e6f4e6c335fa14605dde5d28256f05b1e36c706e851fbe3ccb46c
DIST uvloop-0.21.0.tar.gz 2492741 BLAKE2B bd890673ea420282929e2450977cf9ce86e5daf5bb6001fb8c3fef5d037a14071eb2e39e29020c22d34d3b8100485f10e6fba7a35dce6cde9e07fbd8bc0eaf98 SHA512 fd8684c1382178be72febf7ba3fa2cddf4303fceee79c1e475e6fcbf323ba8a53f516df1cd33a527d149f84807ad3cf8a61047d489601b43b21afd6e4fa088d6
DIST uvloop-0.21.0b1.tar.gz 2492824 BLAKE2B aa9b07ca6f95020e22384e848abc137e1b7fd95092b01e41471a620c4614a48f64fb1031b6f6842a62dcdf2c727c1849421bbfc862e1eb0bbb84173668cd2f07 SHA512 ae0caf4c79102ad12d0b1bedf4ec64929ad15a281908fbb336f806fa35194838ce14993e49d569b53e4aa8824e51a5a5a7156f938111ec4d2e0f1319db72b415

87
dev-python/uvloop/uvloop-0.20.0.ebuild
View File

@@ -1,87 +0,0 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 pypi
DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv"
HOMEPAGE="
https://github.com/magicstack/uvloop/
https://pypi.org/project/uvloop/
"
SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-0.19.0-cython3.patch.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm arm64 ppc ppc64 -riscv sparc x86"
IUSE="examples"
DEPEND="
>=dev-libs/libuv-1.11.0:=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
>=dev-python/cython-0.29.36[${PYTHON_USEDEP}]
test? (
dev-python/aiohttp[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-22.0.0[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
)
"
PATCHES=(
"${WORKDIR}"/${PN}-0.19.0-cython3.patch
)
distutils_enable_tests pytest
python_prepare_all() {
rm -r vendor || die
cat <<-EOF >> setup.cfg || die
[build_ext]
use_system_libuv=True
cython_always=True
EOF
# force cythonization
rm uvloop/loop.c || die
distutils-r1_python_prepare_all
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local EPYTEST_IGNORE=(
# linting
tests/test_sourcecode.py
)
local EPYTEST_DESELECT=(
# TODO: expects some... cython_helper?
tests/test_libuv_api.py::Test_UV_libuv::test_libuv_get_loop_t_ptr
# unhappy about sandbox injecting its envvars
tests/test_process.py::Test_UV_Process::test_process_env_2
tests/test_process.py::Test_AIO_Process::test_process_env_2
# hangs
tests/test_tcp.py::Test_AIO_TCPSSL::test_remote_shutdown_receives_trailing_data
# crashes on assertion
# https://github.com/MagicStack/uvloop/issues/574
tests/test_cython.py::TestCythonIntegration::test_cython_coro_is_coroutine
# Internet
tests/test_dns.py::Test_UV_DNS::test_getaddrinfo_{8,9}
)
rm -rf uvloop || die
epytest -s
}
python_install_all() {
use examples && dodoc -r examples
distutils-r1_python_install_all
}

83
dev-python/uvloop/uvloop-0.21.0_beta1.ebuild
View File

@@ -1,83 +0,0 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv"
HOMEPAGE="
https://github.com/magicstack/uvloop/
https://pypi.org/project/uvloop/
"
SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-0.19.0-cython3.patch.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm arm64 ppc ppc64 -riscv sparc x86"
IUSE="examples"
DEPEND="
>=dev-libs/libuv-1.11.0:=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
>=dev-python/cython-3.0[${PYTHON_USEDEP}]
test? (
>=dev-python/aiohttp-3.10.5[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-22.0.0[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
rm -r vendor || die
cat <<-EOF >> setup.cfg || die
[build_ext]
use_system_libuv=True
cython_always=True
EOF
# force cythonization
rm uvloop/loop.c || die
distutils-r1_python_prepare_all
# don't append -O2... however, it's not splitting args correctly,
# so let's pass something safe
export UVLOOP_OPT_CFLAGS=-Wall
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local EPYTEST_IGNORE=(
# linting
tests/test_sourcecode.py
)
local EPYTEST_DESELECT=(
# unhappy about sandbox injecting its envvars
tests/test_process.py::Test_UV_Process::test_process_env_2
tests/test_process.py::Test_AIO_Process::test_process_env_2
# crashes on assertion
# https://github.com/MagicStack/uvloop/issues/574
tests/test_cython.py::TestCythonIntegration::test_cython_coro_is_coroutine
# Internet
tests/test_dns.py::Test_UV_DNS::test_getaddrinfo_{8,9}
)
rm -rf uvloop || die
epytest -s
}
python_install_all() {
use examples && dodoc -r examples
distutils-r1_python_install_all
}