mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-cluster/ceph: Fix init script
The previous defaults were subtly insane, and very wrong. "supervise-daemon: unable to open the logfile for stdout '/dev/null.96-stdout.log': Permission denied" ? No thanks, let's set some values that allow ceph to start, and log to a reasonable place. Package-Manager: Portage-2.3.24, Repoman-2.3.6
This commit is contained in:
Patrick Lauer
306
sys-cluster/ceph/ceph-10.2.10-r2.ebuild
Normal file
306
sys-cluster/ceph/ceph-10.2.10-r2.ebuild
Normal file
@@ -0,0 +1,306 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
|
||||
|
||||
inherit check-reqs autotools eutils python-r1 udev user \
|
||||
readme.gentoo-r1 systemd versionator flag-o-matic toolchain-funcs
|
||||
|
||||
if [[ ${PV} == *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/ceph/ceph.git"
|
||||
SRC_URI=""
|
||||
else
|
||||
SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Ceph distributed filesystem"
|
||||
HOMEPAGE="https://ceph.com/"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="0"
|
||||
|
||||
IUSE="babeltrace cephfs cryptopp debug fuse gtk jemalloc ldap +libaio"
|
||||
IUSE+=" libatomic lttng +nss +radosgw static-libs +tcmalloc test xfs zfs"
|
||||
|
||||
# unbundling code commented out pending bugs 584056 and 584058
|
||||
#>=dev-libs/jerasure-2.0.0-r1
|
||||
#>=dev-libs/gf-complete-2.0.0
|
||||
COMMON_DEPEND="
|
||||
app-arch/snappy:=
|
||||
sys-libs/zlib:=
|
||||
app-arch/lz4:=
|
||||
app-arch/bzip2:=
|
||||
app-arch/zstd:=
|
||||
dev-libs/boost:=[threads]
|
||||
dev-libs/libaio:=
|
||||
dev-libs/leveldb:=[snappy]
|
||||
nss? ( dev-libs/nss:= )
|
||||
libatomic? ( dev-libs/libatomic_ops:= )
|
||||
cryptopp? ( dev-libs/crypto++:= )
|
||||
sys-apps/keyutils
|
||||
sys-apps/util-linux
|
||||
dev-libs/libxml2:=
|
||||
radosgw? ( dev-libs/fcgi:= )
|
||||
ldap? ( net-nds/openldap:= )
|
||||
babeltrace? ( dev-util/babeltrace )
|
||||
fuse? ( sys-fs/fuse:0= )
|
||||
xfs? ( sys-fs/xfsprogs:= )
|
||||
zfs? ( sys-fs/zfs:= )
|
||||
gtk? (
|
||||
x11-libs/gtk+:2=
|
||||
dev-cpp/gtkmm:2.4
|
||||
gnome-base/librsvg:=
|
||||
)
|
||||
radosgw? (
|
||||
dev-libs/fcgi:=
|
||||
dev-libs/expat:=
|
||||
net-misc/curl:=
|
||||
)
|
||||
jemalloc? ( dev-libs/jemalloc:= )
|
||||
!jemalloc? ( =dev-util/google-perftools-2.4*:= )
|
||||
lttng? ( dev-util/lttng-ust:= )
|
||||
${PYTHON_DEPS}
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
dev-python/cython[${PYTHON_USEDEP}]
|
||||
app-arch/cpio
|
||||
dev-lang/yasm
|
||||
virtual/pkgconfig
|
||||
dev-python/sphinx
|
||||
test? (
|
||||
sys-fs/btrfs-progs
|
||||
sys-apps/grep[pcre]
|
||||
dev-python/tox[${PYTHON_USEDEP}]
|
||||
dev-python/virtualenv[${PYTHON_USEDEP}]
|
||||
)"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
sys-apps/hdparm
|
||||
sys-block/parted
|
||||
sys-fs/cryptsetup
|
||||
sys-apps/gptfdisk
|
||||
!<sys-apps/openrc-0.26.3
|
||||
dev-python/flask[${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
"
|
||||
REQUIRED_USE="
|
||||
$(python_gen_useflags 'python2*')
|
||||
${PYTHON_REQUIRED_USE}
|
||||
^^ ( nss cryptopp )
|
||||
?? ( jemalloc tcmalloc )
|
||||
"
|
||||
|
||||
# work around bug in ceph compilation (rgw/ceph_dencoder-rgw_dencoder.o... undefined reference to `vtable for RGWZoneGroup')
|
||||
REQUIRED_USE+=" radosgw"
|
||||
|
||||
#RESTRICT="test? ( userpriv )"
|
||||
|
||||
# distribution tarball does not include everything needed for tests
|
||||
RESTRICT+=" test"
|
||||
|
||||
STRIP_MASK="/usr/lib*/rados-classes/*"
|
||||
|
||||
UNBUNDLE_LIBS=(
|
||||
src/erasure-code/jerasure/jerasure
|
||||
src/erasure-code/jerasure/gf-complete
|
||||
)
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/ceph-10.2.0-dont-use-virtualenvs.patch"
|
||||
#"${FILESDIR}/ceph-10.2.1-unbundle-jerasure.patch"
|
||||
"${FILESDIR}/${PN}-10.2.1-libzfs.patch"
|
||||
"${FILESDIR}/${PN}-10.2.3-build-without-openldap.patch"
|
||||
"${FILESDIR}/${PN}-10.2.5-Make-RBD-Python-bindings-compatible-with-Python-3.patch"
|
||||
"${FILESDIR}/${PN}-10.2.5-Make-CephFS-bindings-and-tests-compatible-with-Python-3.patch"
|
||||
"${FILESDIR}/${PN}-10.2.7-fix-compilation-with-zstd.patch"
|
||||
"${FILESDIR}/${PN}-10.2.9-cflags.patch"
|
||||
"${FILESDIR}/${PN}-10.2.9-dont-run-lsb_release.patch"
|
||||
)
|
||||
|
||||
check-reqs_export_vars() {
|
||||
if use debug; then
|
||||
CHECKREQS_DISK_BUILD="23G"
|
||||
CHECKREQS_DISK_USR="7G"
|
||||
elif use amd64; then
|
||||
CHECKREQS_DISK_BUILD="12G"
|
||||
CHECKREQS_DISK_USR="450M"
|
||||
else
|
||||
CHECKREQS_DISK_BUILD="1400M"
|
||||
CHECKREQS_DISK_USR="450M"
|
||||
fi
|
||||
|
||||
export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
|
||||
}
|
||||
|
||||
user_setup() {
|
||||
enewgroup ceph ${CEPH_GID}
|
||||
enewuser ceph "${CEPH_UID:--1}" -1 /var/lib/ceph ceph
|
||||
}
|
||||
|
||||
emake_python_bindings() {
|
||||
local action="${1}" params binding module
|
||||
shift
|
||||
params=("${@}")
|
||||
|
||||
__emake_python_bindings_do_impl() {
|
||||
ceph_run_econf "${EPYTHON}"
|
||||
emake "${params[@]}" PYTHON="${EPYTHON}" "${binding}-pybind-${action}"
|
||||
|
||||
# these don't work and aren't needed on python3
|
||||
if [[ ${EBUILD_PHASE} == install ]]; then
|
||||
for module in "${S}"/src/pybind/*.py; do
|
||||
module_basename="$(basename "${module}")"
|
||||
if [[ ${module_basename} == ceph_volume_client.py ]] && ! use cephfs; then
|
||||
continue
|
||||
elif [[ ! -e "${ED}/$(python_get_sitedir)/${module_basename}" ]]; then
|
||||
python_domodule ${module}
|
||||
fi
|
||||
done
|
||||
fi
|
||||
}
|
||||
|
||||
pushd "${S}/src"
|
||||
for binding in rados rbd $(use cephfs && echo cephfs); do
|
||||
python_foreach_impl __emake_python_bindings_do_impl
|
||||
done
|
||||
popd
|
||||
|
||||
unset __emake_python_bindings_do_impl
|
||||
}
|
||||
|
||||
pkg_pretend() {
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_pretend
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
python_setup
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_setup
|
||||
user_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# remove tests that need root access
|
||||
rm src/test/cli/ceph-authtool/cap*.t
|
||||
|
||||
#rm -rf "${UNBUNDLE_LIBS[@]}"
|
||||
|
||||
append-flags -fPIC
|
||||
|
||||
if tc-is-gcc && [[ $(gcc-fullversion) == "7.2.0" ]] && is-flag "-g*"; then
|
||||
ewarn "Filtering out -g* flags since gcc-7.2 tends to ICE with them and ceph"
|
||||
filter-flags "-g*"
|
||||
fi
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
ECONFARGS=(
|
||||
--without-hadoop
|
||||
--includedir=/usr/include
|
||||
$(use_with cephfs)
|
||||
$(use_with debug)
|
||||
$(use_with fuse)
|
||||
$(use_with libaio)
|
||||
$(use_with libatomic libatomic-ops)
|
||||
$(use_with nss)
|
||||
$(use_with cryptopp)
|
||||
$(use_with radosgw)
|
||||
$(use_with gtk gtk2)
|
||||
$(use_enable static-libs static)
|
||||
$(use_with jemalloc)
|
||||
$(use_with xfs libxfs)
|
||||
$(use_with zfs libzfs)
|
||||
$(use_with lttng )
|
||||
$(use_with babeltrace)
|
||||
$(use_with ldap openldap)
|
||||
$(use jemalloc || usex tcmalloc " --with-tcmalloc" " --with-tcmalloc-minimal")
|
||||
--with-mon
|
||||
--with-eventfd
|
||||
--with-cython
|
||||
--without-kinetic
|
||||
--without-librocksdb
|
||||
--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
|
||||
)
|
||||
|
||||
# we can only use python2.7 for building at the moment
|
||||
ceph_run_econf "python2*"
|
||||
}
|
||||
|
||||
ceph_run_econf() {
|
||||
[[ -z ${ECONFARGS} ]] && die "called ${FUNCNAME[0]} with ECONFARGS unset"
|
||||
[[ -z ${1} ]] && die "called ${FUNCNAME[0]} without passing python implementation"
|
||||
|
||||
pushd "${S}" >/dev/null || die
|
||||
#
|
||||
# This generates a QA warning about running econf in src_compile
|
||||
# and src_install. Unfortunately the only other way to do this would
|
||||
# involve building all of for each python implementation times, which
|
||||
# wastes a _lot_ of CPU time and disk space. This hack will no longer
|
||||
# be needed with >=ceph-11.2.
|
||||
#
|
||||
python_setup "${1}"
|
||||
econf "${ECONFARGS[@]}"
|
||||
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake
|
||||
emake_python_bindings all
|
||||
|
||||
use test && emake check-local
|
||||
}
|
||||
|
||||
src_test() {
|
||||
make check || die "make check failed"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
emake_python_bindings install-exec "DESTDIR=\"${D}\""
|
||||
|
||||
prune_libtool_files --all
|
||||
|
||||
exeinto /usr/$(get_libdir)/ceph
|
||||
newexe src/init-ceph ceph_init.sh
|
||||
|
||||
insinto /etc/logrotate.d/
|
||||
newins "${FILESDIR}"/ceph.logrotate ${PN}
|
||||
|
||||
keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
|
||||
|
||||
fowners -R ceph:ceph /var/lib/ceph /var/log/ceph
|
||||
|
||||
newinitd "${FILESDIR}/rbdmap.initd" rbdmap
|
||||
newinitd "${FILESDIR}/${PN}.initd-r7" ${PN}
|
||||
newconfd "${FILESDIR}/${PN}.confd-r3" ${PN}
|
||||
|
||||
insinto /etc/sysctl.d
|
||||
newins "${FILESDIR}"/sysctld 90-${PN}.conf
|
||||
|
||||
use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
|
||||
|
||||
systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" "ceph-mds@.service"
|
||||
systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" "ceph-osd@.service"
|
||||
|
||||
udev_dorules udev/*.rules
|
||||
|
||||
readme.gentoo_create_doc
|
||||
|
||||
python_setup 'python2*'
|
||||
python_fix_shebang "${ED}"/usr/{,s}bin/
|
||||
|
||||
# python_fix_shebang apparently is not idempotent
|
||||
sed -i -r 's:(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]:\1:' \
|
||||
"${ED}"/usr/{sbin/ceph-disk,bin/ceph-detect-init} || die "sed failed"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
288
sys-cluster/ceph/ceph-12.2.2-r1.ebuild
Normal file
288
sys-cluster/ceph/ceph-12.2.2-r1.ebuild
Normal file
@@ -0,0 +1,288 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
|
||||
DISTUTILS_OPTIONAL=1
|
||||
|
||||
inherit check-reqs cmake-utils distutils-r1 python-r1 udev user systemd \
|
||||
readme.gentoo-r1 flag-o-matic
|
||||
|
||||
if [[ ${PV} == *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/ceph/ceph.git"
|
||||
SRC_URI=""
|
||||
else
|
||||
SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Ceph distributed filesystem"
|
||||
HOMEPAGE="https://ceph.com/"
|
||||
|
||||
LICENSE="LGPL-2.1 CC-BY-SA-1.0 GPL-2 BSD Boost-1.0 MIT"
|
||||
SLOT="0"
|
||||
|
||||
CPU_FLAGS_X86=(sse{,2,3,4_1,4_2} ssse3)
|
||||
|
||||
IUSE="babeltrace cephfs fuse jemalloc ldap lttng +mgr nss +radosgw +ssl"
|
||||
IUSE+=" static-libs systemd +tcmalloc test xfs zfs"
|
||||
IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
|
||||
|
||||
# unbundling code commented out pending bugs 584056 and 584058
|
||||
#>=dev-libs/jerasure-2.0.0-r1
|
||||
#>=dev-libs/gf-complete-2.0.0
|
||||
COMMON_DEPEND="
|
||||
virtual/libudev
|
||||
app-arch/bzip2:=[static-libs?]
|
||||
app-arch/lz4:=[static-libs?]
|
||||
app-arch/snappy:=[static-libs?]
|
||||
app-arch/zstd:=[static-libs?]
|
||||
app-misc/jq:=[static-libs?]
|
||||
dev-libs/boost:=[threads,context,python,static-libs?,${PYTHON_USEDEP}]
|
||||
dev-libs/crypto++:=[static-libs?]
|
||||
dev-libs/leveldb:=[snappy,static-libs?]
|
||||
dev-libs/libaio:=[static-libs?]
|
||||
dev-libs/libxml2:=[static-libs?]
|
||||
sys-apps/keyutils:=[static-libs?]
|
||||
sys-apps/util-linux:=[static-libs?]
|
||||
sys-libs/zlib:=[static-libs?]
|
||||
babeltrace? ( dev-util/babeltrace )
|
||||
ldap? ( net-nds/openldap:=[static-libs?] )
|
||||
lttng? ( dev-util/lttng-ust:= )
|
||||
nss? ( dev-libs/nss:= )
|
||||
fuse? ( sys-fs/fuse:0=[static-libs?] )
|
||||
ssl? ( dev-libs/openssl:=[static-libs?] )
|
||||
xfs? ( sys-fs/xfsprogs:=[static-libs?] )
|
||||
zfs? ( sys-fs/zfs:=[static-libs?] )
|
||||
radosgw? (
|
||||
dev-libs/expat:=[static-libs?]
|
||||
dev-libs/openssl:=[static-libs?]
|
||||
net-misc/curl:=[static-libs?]
|
||||
)
|
||||
jemalloc? ( dev-libs/jemalloc:=[static-libs?] )
|
||||
!jemalloc? ( >=dev-util/google-perftools-2.4:=[static-libs?] )
|
||||
${PYTHON_DEPS}
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
app-arch/cpio
|
||||
dev-lang/yasm
|
||||
dev-python/cython[${PYTHON_USEDEP}]
|
||||
dev-python/sphinx
|
||||
dev-util/gperf
|
||||
dev-util/valgrind
|
||||
sys-apps/which
|
||||
sys-devel/bc
|
||||
virtual/pkgconfig
|
||||
test? (
|
||||
dev-python/tox[${PYTHON_USEDEP}]
|
||||
dev-python/virtualenv[${PYTHON_USEDEP}]
|
||||
sys-apps/grep[pcre]
|
||||
sys-fs/btrfs-progs
|
||||
)"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
net-misc/socat
|
||||
sys-apps/gptfdisk
|
||||
sys-block/parted
|
||||
sys-fs/cryptsetup
|
||||
!<sys-apps/openrc-0.26.3
|
||||
dev-python/cherrypy[${PYTHON_USEDEP}]
|
||||
dev-python/flask[${PYTHON_USEDEP}]
|
||||
dev-python/pecan[${PYTHON_USEDEP}]
|
||||
dev-python/prettytable[${PYTHON_USEDEP}]
|
||||
dev-python/pyopenssl[${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
dev-python/werkzeug[${PYTHON_USEDEP}]
|
||||
"
|
||||
REQUIRED_USE="
|
||||
$(python_gen_useflags 'python2*')
|
||||
${PYTHON_REQUIRED_USE}
|
||||
?? ( ssl nss )
|
||||
?? ( jemalloc tcmalloc )
|
||||
"
|
||||
|
||||
RESTRICT="test? ( userpriv )"
|
||||
|
||||
# distribution tarball does not include everything needed for tests
|
||||
RESTRICT+=" test"
|
||||
|
||||
STRIP_MASK="/usr/lib*/rados-classes/*"
|
||||
|
||||
UNBUNDLE_LIBS=(
|
||||
src/erasure-code/jerasure/jerasure
|
||||
src/erasure-code/jerasure/gf-complete
|
||||
)
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/ceph-12.2.0-use-provided-cpu-flag-values.patch"
|
||||
"${FILESDIR}/ceph-12.2.0-cflags.patch"
|
||||
"${FILESDIR}/ceph-12.2.1-systemd-unitdir.patch"
|
||||
"${FILESDIR}/ceph-12.2.2-build-without-radosgw.patch"
|
||||
)
|
||||
|
||||
check-reqs_export_vars() {
|
||||
if use amd64; then
|
||||
CHECKREQS_DISK_BUILD="12G"
|
||||
CHECKREQS_DISK_USR="460M"
|
||||
else
|
||||
CHECKREQS_DISK_BUILD="1400M"
|
||||
CHECKREQS_DISK_USR="450M"
|
||||
fi
|
||||
|
||||
export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
|
||||
}
|
||||
|
||||
user_setup() {
|
||||
enewgroup ceph ${CEPH_GID}
|
||||
enewuser ceph "${CEPH_UID:--1}" -1 /var/lib/ceph ceph
|
||||
}
|
||||
|
||||
pkg_pretend() {
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_pretend
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
python_setup 'python2*'
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_setup
|
||||
user_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# remove tests that need root access
|
||||
rm src/test/cli/ceph-authtool/cap*.t
|
||||
|
||||
#rm -rf "${UNBUNDLE_LIBS[@]}"
|
||||
}
|
||||
|
||||
ceph_src_configure() {
|
||||
local flag
|
||||
local mycmakeargs=(
|
||||
-DWITH_BABELTRACE=$(usex babeltrace)
|
||||
-DWITH_CEPHFS=$(usex cephfs)
|
||||
-DWITH_FUSE=$(usex fuse)
|
||||
-DWITH_LTTNG=$(usex lttng)
|
||||
-DWITH_MGR=$(usex mgr)
|
||||
-DWITH_NSS=$(usex nss)
|
||||
-DWITH_OPENLDAP=$(usex ldap)
|
||||
-DWITH_RADOSGW=$(usex radosgw)
|
||||
-DWITH_SSL=$(usex ssl)
|
||||
-DWITH_SYSTEMD=$(usex systemd)
|
||||
-DWITH_TESTS=$(usex test)
|
||||
-DWITH_XFS=$(usex xfs)
|
||||
-DWITH_ZFS=$(usex zfs)
|
||||
-DENABLE_SHARED=$(usex static-libs '' 'yes' 'no')
|
||||
-DALLOCATOR=$(usex tcmalloc 'tcmalloc' '' "$(usex jemalloc 'jemalloc' '' 'libc' '')" '')
|
||||
-DWITH_SYSTEM_BOOST=yes
|
||||
-DWITH_RDMA=no
|
||||
-DSYSTEMD_UNITDIR=$(systemd_get_systemunitdir)
|
||||
)
|
||||
if use amd64 || use x86; then
|
||||
for flag in ${CPU_FLAGS_X86[@]}; do
|
||||
mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_INTEL_${flag^^}=1")")
|
||||
done
|
||||
fi
|
||||
|
||||
rm -f "${BUILD_DIR:-${S}}/CMakeCache.txt"
|
||||
cmake-utils_src_configure
|
||||
|
||||
# bug #630232
|
||||
sed -i "s:\"${T//:\\:}/${EPYTHON}/bin/python\":\"${PYTHON}\":" \
|
||||
"${BUILD_DIR:-${CMAKE_BUILD_DIR:-${S}}}"/include/acconfig.h \
|
||||
|| die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
ceph_src_configure
|
||||
}
|
||||
|
||||
python_compile() {
|
||||
local CMAKE_USE_DIR="${S}"
|
||||
|
||||
ceph_src_configure
|
||||
pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
|
||||
emake VERBOSE=1 all
|
||||
|
||||
# python modules are only compiled with "make install" so we need to do this to
|
||||
# prevent doing a bunch of compilation in src_install
|
||||
DESTDIR="${T}" emake VERBOSE=1 install
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cmake-utils_src_make all
|
||||
|
||||
# we have to do this here to prevent from building everything multiple times
|
||||
BUILD_DIR="${CMAKE_BUILD_DIR}" python_copy_sources
|
||||
python_foreach_impl python_compile
|
||||
}
|
||||
|
||||
src_test() {
|
||||
make check || die "make check failed"
|
||||
}
|
||||
|
||||
python_install() {
|
||||
local CMAKE_USE_DIR="${S}"
|
||||
pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
|
||||
DESTDIR="${D}" emake install
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
python_foreach_impl python_install
|
||||
|
||||
prune_libtool_files --all
|
||||
|
||||
exeinto /usr/$(get_libdir)/ceph
|
||||
newexe "${CMAKE_BUILD_DIR}/bin/init-ceph" ceph_init.sh
|
||||
|
||||
insinto /etc/logrotate.d/
|
||||
newins "${FILESDIR}"/ceph.logrotate ${PN}
|
||||
|
||||
keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
|
||||
|
||||
fowners -R ceph:ceph /var/lib/ceph /var/log/ceph
|
||||
|
||||
newinitd "${FILESDIR}/rbdmap.initd" rbdmap
|
||||
newinitd "${FILESDIR}/${PN}.initd-r7" ${PN}
|
||||
newconfd "${FILESDIR}/${PN}.confd-r4" ${PN}
|
||||
|
||||
insinto /etc/sysctl.d
|
||||
newins "${FILESDIR}"/sysctld 90-${PN}.conf
|
||||
|
||||
use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
|
||||
|
||||
# units aren't installed by the build system unless systemd is enabled
|
||||
# so no point installing these with the USE flag disabled
|
||||
if use systemd; then
|
||||
systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" \
|
||||
"ceph-mds@.service"
|
||||
|
||||
systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" \
|
||||
"ceph-osd@.service"
|
||||
fi
|
||||
|
||||
udev_dorules udev/*.rules
|
||||
|
||||
readme.gentoo_create_doc
|
||||
|
||||
python_setup 'python2*'
|
||||
|
||||
# bug #630232
|
||||
sed -i -r "s:${T//:/\\:}/${EPYTHON}:/usr:" "${ED}"/usr/bin/ceph \
|
||||
|| die "sed failed"
|
||||
|
||||
python_fix_shebang "${ED}"/usr/{,s}bin/
|
||||
|
||||
# python_fix_shebang apparently is not idempotent
|
||||
sed -i -r 's:(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]:\1:' \
|
||||
"${ED}"/usr/{sbin/ceph-disk,bin/ceph-detect-init} || die "sed failed"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
87
sys-cluster/ceph/files/ceph.initd-r7
Normal file
87
sys-cluster/ceph/files/ceph.initd-r7
Normal file
@@ -0,0 +1,87 @@
|
||||
#!/sbin/openrc-run
|
||||
|
||||
ceph_conf="${ceph_conf:-/etc/ceph/ceph.conf}"
|
||||
extra_commands="reload"
|
||||
daemon_type="${RC_SVCNAME#ceph-}"
|
||||
daemon_type="${daemon_type%%.*}"
|
||||
daemon_id="${RC_SVCNAME#ceph-*.}"
|
||||
daemon_id="${daemon_id:-0}"
|
||||
: ${rundir:=/run/ceph}
|
||||
: ${user:=ceph}
|
||||
: ${group:=ceph}
|
||||
: ${rc_ulimit:=-n 1048576 -u 1048576}
|
||||
|
||||
pidfile="${rundir}/supervisor-${daemon_type}.${daemon_id}.pid"
|
||||
daemon_pidfile="${rundir}/${daemon_type}.${daemon_id}.pid"
|
||||
|
||||
command="/usr/bin/${RC_SVCNAME%%.*}"
|
||||
command_args="-i ${daemon_id} --pid-file ${daemon_pidfile} -c ${ceph_conf}"
|
||||
command_args_foreground="--foreground"
|
||||
|
||||
retry="${CEPH_TERMTIMEOUT:-TERM/120/KILL/5}"
|
||||
start_stop_daemon_args="--user ${user} --group ${group}"
|
||||
supervise_daemon_args="--user ${user} --group ${group}"
|
||||
|
||||
: ${supervisor:=supervise-daemon}
|
||||
: ${stdout:=/var/log/ceph/ceph}
|
||||
: ${stderr:=/var/log/ceph/ceph}
|
||||
: ${respawn_delay:=10}
|
||||
: ${respawn_max:=5}
|
||||
: ${respawn_period:=1800}
|
||||
|
||||
: ${osd_respawn_delay:=15}
|
||||
: ${osd_respawn_max:=10}
|
||||
|
||||
: ${radosgw_respawn_max:=5}
|
||||
: ${radosgw_respawn_period:=30}
|
||||
|
||||
depend() {
|
||||
use dns logger
|
||||
after net ntpd ntp-client chronyd
|
||||
before netmount
|
||||
}
|
||||
|
||||
is_type_valid() {
|
||||
case ${daemon_type} in
|
||||
mon|mds|osd|mgr|radosgw) return 0;;
|
||||
*) return 1;;
|
||||
esac
|
||||
}
|
||||
|
||||
start_pre() {
|
||||
export CEPH_CONF="${ceph_conf}"
|
||||
|
||||
checkpath -d -q -o "${user}:${group}" "${rundir}"
|
||||
|
||||
if ! is_type_valid ;then
|
||||
eerror "Please give valid Ceph Server Type: mds, mon, osd"
|
||||
return 1
|
||||
|
||||
elif pgrep -f "[c]eph-${daemon_type} -i ${daemon_id} "; then
|
||||
eerror "${daemon_type}.${daemon_id} is still running, refusing to start"
|
||||
return 1
|
||||
fi
|
||||
|
||||
local arg_name arg_val
|
||||
for arg_name in std{out,err} respawn_{delay,max,period}; do
|
||||
eval arg_val="\${${daemon_type}_${arg_name}}"
|
||||
|
||||
if [ -z "${arg_val}" ]; then
|
||||
eval arg_val="\${${arg_name}}"
|
||||
else
|
||||
eval "${arg_name}=\"${arg_val}\""
|
||||
fi
|
||||
|
||||
if [ "${arg_name}" = "stderr" ] || [ "${arg_name}" = "stdout" ]; then
|
||||
supervise_daemon_args="${supervise_daemon_args} --${arg_name//_/-}=${arg_val}.${daemon_id}-${arg_name}.log"
|
||||
fi
|
||||
done
|
||||
}
|
||||
|
||||
reload() {
|
||||
ebegin "Reloading Ceph ${daemon_type}.${daemon_id}"
|
||||
start-stop-daemon --signal 1 "${start_stop_daemon_args}"
|
||||
eend ${?}
|
||||
}
|
||||
|
||||
# vim:ft=gentoo-init-d:ts=4:sts=4:sw=4:noet:
|
||||
Reference in New Issue
Block a user