sci-libs/rpp: add 6.3.0

Signed-off-by: Sv. Lockal <lockalsash@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

sci-libs/rpp/Manifest

@@ -1 +1,2 @@
 DIST rpp-6.1.1.tar.gz 37016755 BLAKE2B 884090ab50e0a4a3aed4e52c5bbd934a8c5b62eca310471c30cf4c5a7cafdd36fed7894320b4d5246620b3c47e90fafd0f8160a7d4ed0295c7668c8d147f4b18 SHA512 a7c10bdd08739eba08209783decf0f4fd7c12194b9ebc63bd16e4cb998645110c089833efb83a77d4bed7f8599cf3a320608be28633f0dc956079f9d70e765f8
+DIST rpp-6.3.0.tar.gz 56092581 BLAKE2B 1a36d98b64745e7cb36322cf21a6983a7efcde737136cbf12c428edd315ce1dff5f92540e5f23750cce01a65d25c0a87e4429bb3ea98059c747569591fb0e22a SHA512 8bab18af168dca51f6a5c2d32e46ca133307d2cf48057c4e9cda6100ea17df54b22533fedbad6d4273904eca53df5a322153a2d7eb45c6ce7faff54d2e57a482

sci-libs/rpp/rpp-6.3.0.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ROCM_VERSION=${PV}
+
+inherit cmake flag-o-matic rocm
+
+DESCRIPTION="AMD ROCm Performance Primitives (RPP) high-performance computer vision library"
+HOMEPAGE="https://github.com/ROCm/rpp"
+SRC_URI="https://github.com/ROCm/rpp/archive/refs/tags/rocm-${PV}.tar.gz -> rpp-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-rocm-${PV}"
+
+LICENSE="BSD"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64"
+
+# pkgcheck warning: RequiredUseDefaults
+REQUIRED_USE="
+	cpu_flags_x86_avx2 cpu_flags_x86_fma3 cpu_flags_x86_f16c
+	${ROCM_REQUIRED_USE}
+"
+
+RDEPEND="
+	dev-util/hip:${SLOT}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-build/cmake-3.22
+	>=dev-libs/half-1.12.0-r1
+	test? (
+		dev-cpp/gtest
+		media-libs/opencv:=
+	)
+"
+
+IUSE="cpu_flags_x86_avx2 cpu_flags_x86_fma3 cpu_flags_x86_f16c test"
+RESTRICT="!test? ( test )"
+
+DOCS=( CHANGELOG.md LICENSE README.md )
+
+rcc_test_wrapper() {
+	local S="${WORKDIR}/${PN}-rocm-${PV}/utilities/rpp-unittests/HIP_NEW"
+	local CMAKE_USE_DIR="${S}"
+	local BUILD_DIR="${BUILD_DIR}/utilities/rpp-unittests/HIP_NEW"
+	cd "${S}" || die
+	$@
+}
+
+src_prepare() {
+	sed -e "s:\${ROCM_PATH}/llvm/bin/clang++:hipcc:" \
+		-i CMakeLists.txt || die
+
+	cmake_src_prepare
+	if use test; then
+		local PATCHES=()
+		rcc_test_wrapper cmake_src_prepare
+	fi
+}
+
+src_configure() {
+	rocm_use_hipcc
+
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DAMDGPU_TARGETS="$(get_amdgpu_flags)"
+		-DROCM_PATH=/usr
+		-DBACKEND=HIP
+		-DBUILD_WITH_AMD_ADVANCE=OFF
+	)
+
+	cmake_src_configure
+
+	if use test; then
+		append-cxxflags -I"${S}/include"
+		append-ldflags -L"${BUILD_DIR}/lib64"
+		local mycmakeargs=(-DROCM_PATH=/usr)
+		use test && rcc_test_wrapper cmake_src_configure
+	fi
+}
+
+src_compile() {
+	cmake_src_compile
+	use test && rcc_test_wrapper cmake_src_compile
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove unneeded copy
+	rm -r "${ED}/usr/share/doc/${PF}-asan" || die
+}
+
+src_test() {
+	check_amdgpu
+
+	cd "${BUILD_DIR}"/utilities/rpp-unittests/HIP_NEW || die
+	for params in "0 0" "0 1" "1 1" "2 1" "5 1" "0 2" "0 3" "0 4" "0 5" "0 8"; do
+		LD_LIBRARY_PATH="${BUILD_DIR}"/lib64 ./uniqueFunctionalities_hip $params || die
+	done
+}