kde-plasma/plasma-firewall: 6.1.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-plasma/plasma-firewall/Manifest

@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.27.11.tar.xz 362988 BLAKE2B 484e853f4a8c61823e2a235fe5d5e40b6861c04044ca5058b8e866d9a9d9cb072b8a64c2c1b8a950f1604acc85dd27c38314735db2b6e4f59e8fb9085eda0ea8 SHA512 9c6a41448ef83a1c464e1e10441ae811bc898afc451b821fbd46141df4ffe1ad395692c420ce02dd5618197a307fa2729dbe8f0f703c1a64b14068f6c018ba7b
 DIST plasma-firewall-6.0.90.tar.xz 372752 BLAKE2B f69d46b1cb1e4bce83a259094986f7641d77434d718fc710ec88eccedfa8c0c184f75e3db1a14dd7b83f7d52ab699dc4d78f2fec4698524d9e467143d847edb7 SHA512 dd9b791b0099212d5309724bb61c7cb64d75704efd888877a4a24b8a8683a99f811de63b55b804d2993c14d93ad162fb20e5c5569f0f2d749c51483d7e844268
+DIST plasma-firewall-6.1.0.tar.xz 372628 BLAKE2B e2ce183f927213c21148e3c758ecccb175484dad79767509efbcf289551156cf895974ae11f73ebe4015e30da090489b29ff720852d0001ae1614e429a57da5e SHA512 00b8db564a4ae18a6524495238f8206a066afe944e846cea8b794ab603f4ef7401762ae06cf176a23ed10df8e772cf6033697b10894888c0462adb815fed163d

kde-plasma/plasma-firewall/plasma-firewall-6.1.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..12} )
+KFMIN=6.3.0
+QTMIN=6.7.1
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}