app-admin/vault: add 1.11.3

Signed-off-by: Zac Medico <zmedico@gentoo.org>
This commit is contained in:
Zac Medico
2022-09-03 08:47:31 -07:00
parent 56b0256221
commit e7defd4a3d
2 changed files with 88 additions and 0 deletions
+2
View File
@@ -4,3 +4,5 @@ DIST vault-1.11.1-vendor.tar.gz 52063513 BLAKE2B adb2fb6ab7991e94ce00aa298837f2f
DIST vault-1.11.1-webui.tar.xz 1335740 BLAKE2B 6a6fdcb22563ad4c3f18bf3816fe8a016c11d19a014458594c2dade3dc8e908db252c34bad88be9e80c2a6408af28af6324158e1e69b40061af6d6fe1a66c655 SHA512 1c02e0ef645df946ffb9d967a9be230800e67597d0ed6cf8afb2688eed9ca863a1f29efeefbb51e0257d2be588da443864df9e1306956844645b0168c2d58d9b
DIST vault-1.11.2-vendor.tar.gz 52069450 BLAKE2B aa28c4e79fe7e95fee12fcf039c890780dfd4c3983025b5c39c53ed81be99e9c8cdb19580f23a0e05e607693dd46fa868abcaaad04d2abdcaeb0151af8fa6f60 SHA512 2339bd8fa1768cb3e719af00f581116d5d6decad826de00a4e726c212dcd5b29e89426ac3aba86dbb01bb2cb6f7feae899924134040ada7d10a1bc90d42b8f67
DIST vault-1.11.2-webui.tar.xz 1335748 BLAKE2B ce38383d4f37fc88215f6554b6f07a3527481a31bbcf7c3047a735817f259a947f0c0cea8d0f87a0e5e8a1523173e922ac5dab3c1571366383dc97952cfc7d5b SHA512 218fd7c034b3e0dc9ed0217ae450d290d5b677d31b936b85c735783fed993da91590e5d4f22527840386b14837f56849e485f3f2d5196e68b0557e0c02122104
DIST vault-1.11.3-vendor.tar.gz 52098996 BLAKE2B 98f590661d59fb7fe13cc90269592c9dd556dca5feb3834cc056d966bdea7164acd29483cb4179781089ff30a18c7c253414688b5e8127483539779f478099e9 SHA512 9be3d9401574005608b7d2e72856966cf93786d0a4c1e945b51a00f66e0d3152039efccd9d415378914492d6c544e1a3d2a8707406c3331521a5fe960c9cf44b
DIST vault-1.11.3-webui.tar.xz 1335776 BLAKE2B bf98149a8bd71286b0dcacab9847723536c616db6cdc78f4dafd0dacdab2d5d2a203eadbe0bd0f6937f6132cf06e4ec488c1c290a96f9b7f5b88dd4b186ca570 SHA512 136f61519ed4ebf765ea3c76cfba7732c615c7187a821265cbb4b31d9d11c5141fc8e3ad701e15246eaad550ac27a08185d32b26ed4b734eb592de8767d3004f
+86
View File
@@ -0,0 +1,86 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit fcaps go-module systemd
DESCRIPTION="A tool for managing secrets"
HOMEPAGE="https://vaultproject.io/"
VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
SRC_URI="https://github.com/zmedico/vault/archive/refs/tags/v${PV}-vendor.tar.gz -> ${P}-vendor.tar.gz
webui? (
https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
)"
LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+webui"
BDEPEND="
app-arch/zip
dev-go/gox
>=dev-lang/go-1.15.3"
COMMON_DEPEND="acct-group/vault
acct-user/vault"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
FILECAPS=(
-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
)
RESTRICT+=" test"
S=${WORKDIR}/${P}-vendor
src_unpack() {
default
}
src_prepare() {
default
# Avoid the need to have a git checkout
sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
-e 's:^\(GIT_DIRTY=\).*:\1:' \
-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
-e "s|^BUILD_DATE=.*|BUILD_DATE=$(date +%Y-%m-%dT%H:%M:%SZ)|" \
-i scripts/build.sh || die
sed -e "/hooks/d" \
-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
-e "s/gofumpt/gofmt/g" \
-i Makefile || die
if [[ -d "${WORKDIR}/http/web_ui" ]]; then
rm -rf "${S}/http/web_ui" || die
mv "${WORKDIR}/http/web_ui" "${S}/http/web_ui" ||
die "mv failed"
else
mkdir -p "${S}/http/web_ui" || die
touch "${S}/http/web_ui/no_web_ui" || die
fi
}
src_compile() {
mkdir "${T}"/bin || die
BUILD_TAGS="$(usex webui ui '')" \
GOPATH="${T}" \
XC_ARCH=$(go env GOARCH) \
XC_OS=$(go env GOOS) \
XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
emake bin
}
src_install() {
dobin bin/${PN}
dodoc CHANGELOG.md CONTRIBUTING.md README.md
insinto /etc/${PN}.d
doins "${FILESDIR}/"*.json.example
insinto /etc/logrotate.d
newins "${FILESDIR}/${PN}.logrotated" "${PN}"
newinitd "${FILESDIR}/${PN}.initd" "${PN}"
newconfd "${FILESDIR}/${PN}.confd" "${PN}"
systemd_dounit "${FILESDIR}/${PN}.service"
keepdir /var/log/${PN}
fowners ${PN}:${PN} /var/log/${PN}
}