net-libs/libhubbub: bump to 0.3.7

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Closes: https://github.com/gentoo/gentoo/pull/17591
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

net-libs/libhubbub/Manifest

@@ -1 +1,2 @@
 DIST libhubbub-0.3.6-src.tar.gz 784692 BLAKE2B a24b2c7b33849d6f4b25867f8b801d157f19257a055dd9a5a6c49de6c2fbd3f234f648d542b7938fab249e14bb6839997530c47b931379a94ab85ccd750b71e0 SHA512 6ccf9d9bbe8fc8de21570994c4a2f6f6c6943d2b00b8939d0ec9ec72cb3d653c40b58f509a1a81a5500fc8d3b4c49595aec509129bc993208b51b29486d0c14f
+DIST libhubbub-0.3.7-src.tar.gz 784780 BLAKE2B dd7bd85d3401d87c7bc72dad5d6d0439ab826cf97e76a29367a045215621cb66ff6e97f4028f552b7f395691087f53df077075dc65115a41a59eca476f73305d SHA512 d8ae4a8c4ded2c0e73902bfcf4d5d353154e27f236be0f6ea878cc2daed8a399378a4a9c2021f96106e1c822585b1daa09c9bd49c1551d3e87f37348865cfce1

net-libs/libhubbub/libhubbub-0.3.7.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit netsurf flag-o-matic
+
+DESCRIPTION="HTML5 compliant parsing library, written in C"
+HOMEPAGE="https://www.netsurf-browser.org/projects/hubbub/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~m68k-mint"
+IUSE="doc test"
+
+BDEPEND="
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-lang/perl )
+"
+RDEPEND="dev-libs/libparserutils:="
+DEPEND="${RDEPEND}
+	test? ( dev-libs/json-c )"
+RESTRICT="!test? ( test )"
+
+DOCS=( README docs/{Architecture,Macros,Todo,Treebuilder,Updated} )
+PATCHES=( "${FILESDIR}/libhubbub-0.3.6-json-c.patch" )
+
+src_prepare() {
+	default
+	sed -e '1i#pragma GCC diagnostic ignored "-Wimplicit-fallthrough"' \
+		-i test/tree2.c || die
+}
+
+_emake() {
+	netsurf_define_makeconf
+	append-cflags -Wno-error
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+	use doc && _emake docs
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+	use doc && HTML_DOCS=( docs/html/. )
+	einstalldocs
+}