xfce-base/xfce4-panel: Bump to 4.20.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.20.4.tar.bz2 2287183 BLAKE2B 368b1fbdabbbf41c1b7fffb321738c6f5a32e1973c7c47bf9f47e709107ef971f7d59e94c3addc72582df13e32194d4475bee59e94ca5f90d0c74a4c12bd7a35 SHA512 89d835617cab0afce1344495fa29f9cba49fdd1472fb079474c4511befebd1771eb5f4d6f968b98c43517f61e2e284760597a437e39a4956a56abb6d73e43265
+DIST xfce4-panel-4.20.5.tar.bz2 2293754 BLAKE2B 29983f16c75070640613d733524243df85e81c5ac53721d704ae4380004e95e9d80a909e802b1e1d16c462645364839105205ced07bf3a05cf1467ba0a42dc19 SHA512 bde9d94a463b526bf41cf0f6568c70f899f03da8dbe5c654f9857e2bcc5ac1d25681f47c185ab3a0b4af4516703b0e30c55ff9a26a8ba52a36db24955e705327
 DIST xfce4-panel-4.21.0.tar.xz 834780 BLAKE2B cf06cd31589e3f2ce854df7677e6ae54e59432f69cb552a1bd4069798d61a287b0e476e355a3f65c5862134b8a1b1b231fe5660fa7a1e306ca912da5796b4d5e SHA512 64e848af99eb6d11676819ee96b97bf49db7054d12d688177e0f21d9af74cecf3d14a102c01198a2e901568e848149d2c8e9bdb5489a5ddddb8150a78c6f53a6

xfce-base/xfce4-panel/xfce4-panel-4.20.5.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-panel/start
+	https://gitlab.xfce.org/xfce/xfce4-panel/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+dbusmenu introspection vala wayland X"
+REQUIRED_USE="
+	|| ( wayland X )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
+	>=xfce-base/exo-4.18.0:=
+	>=xfce-base/garcon-4.18.0:=
+	>=xfce-base/libxfce4ui-4.18.0:=
+	>=xfce-base/libxfce4util-4.18.0:=[introspection?,vala?]
+	>=xfce-base/libxfce4windowing-4.20.1:=[X?]
+	>=xfce-base/xfconf-4.18.0:=
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+	wayland? (
+		>=dev-libs/wayland-1.20
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXext-1.0.0
+		x11-libs/libwnck:3
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-build/xfce4-dev-tools
+	dev-lang/perl
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable dbusmenu dbusmenu-gtk3)
+		$(use_enable vala)
+		$(use_enable wayland)
+		$(use_enable wayland gtk-layer-shell)
+		$(use_enable X x11)
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}