dev-python/translate-toolkit: Bump to 3.8.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1,2 +1,3 @@
 DIST translate-3.8.3.gh.tar.gz 1157587 BLAKE2B 4dc8ca9cb7f0040364ceeb6fae47d9189642e8383fb1c808713aeb82452690ffe5957c63d649994eae486efaa51aee664fa7b0bb199036d869a87d7a0bf21806 SHA512 ad5a814cc03ed0d41aeac60bea72133fcd47470ab254849647d674bc00b71f2afe1c0956891decc6906fafbd07c4e3d5efcf4212c0e449f3fb3fb4fdbee9aab8
 DIST translate-3.8.4.gh.tar.gz 1158012 BLAKE2B 37d26792b9382d318e359db3c7087cbf71a444c4f76c9b3fcec9311820ade1d3f346d7ff4b22983d6a49e0afd47b4277d2c0222e2982d56f52fcf7f655bd349b SHA512 28d452d9da1d1b400e88a30b9f997dd70ab2db5e6ae33a7882203bf6b59abf6bd315bee97c9f01de536dc752fde93429bb65aeb7b6386482193a68a472bd2e9a
+DIST translate-3.8.5.gh.tar.gz 1158381 BLAKE2B efa51a672bac419e0cf847099f68f33882b8a60c339b157f2a3144014e10b5c241a0817fd93755e2327afd9b9dd923f28c4f22c3a950fe95189bfb6592dd4c83 SHA512 687aadbdaeddd33de64224e33fdf2f47f3b368d5f22e8d79f580ab407595bda0fbdbbb45edeeddff4b0d583eb4238de9ecb7514289ff4ae8fb387c3d089374de

dev-python/translate-toolkit/translate-toolkit-3.8.5.ebuild

@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/Levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# Apparently a change in line wrapping x_x
+		translate/storage/test_cpo.py::TestCPOFile::test_wrap_gettext
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}