mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
games-fps/doomsday: bump to version 2.1.1
Also fixed file collision with games-fps/eduke32[tools]. Closes: https://bugs.gentoo.org/684994 Package-Manager: Portage-2.3.65, Repoman-2.3.12 Signed-off-by: Conrad Kostecki <conrad@kostecki.com> Closes: https://github.com/gentoo/gentoo/pull/11888 Signed-off-by: James Le Cuirot <chewi@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST doomsday-2.0.3.tar.gz 18060670 BLAKE2B e01545f5d719310a78f01de77249a72f9c3c61a1d295ee0827475439b63653f613660bdc033c1651180cc390469c89120d262c15c6e22cece52600e2889e1437 SHA512 4f8e737df9e004cf3ac3cf16b84ffce0c85e2180af552bac41a224595c7f6932397c39f7d3e9fa522e1ae62828cb87f564a5fa411e742eb07bbee96f14c3ee7c
|
||||
DIST doomsday-2.1.1.tar.gz 47526008 BLAKE2B bf941048d160058273df09d67b09e140c10d141cd73ff56d0f3162045696d81533aba9a8c9ff39fc29530248ee8b2f6dd2b3da76a929fb6263c311e65bcbdd82 SHA512 9df0afa0465ef3c3bb30cccf8ca51596e8e6e5584775a695c9c3278f15bcf7e9f7aaeaa0917f0a1de9fbb1174f2ae83a1ee85fba63bef6e49be957836f1107a3
|
||||
|
||||
@@ -0,0 +1,100 @@
|
||||
# Copyright 1999-2019 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
|
||||
inherit cmake-utils python-r1 readme.gentoo-r1
|
||||
|
||||
DESCRIPTION="A modern gaming engine for Doom, Heretic, and Hexen"
|
||||
HOMEPAGE="https://www.dengine.net"
|
||||
SRC_URI="https://downloads.sourceforge.net/project/deng/Doomsday%20Engine/${PV}/${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-3+ LGPL-3+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
|
||||
IUSE="demo +doom fmod freedoom fluidsynth heretic hexen openal tools"
|
||||
REQUIRED_USE="
|
||||
${PYTHON_REQUIRED_USE}
|
||||
demo? ( doom )
|
||||
freedoom? ( doom )
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
dev-qt/qtcore:5
|
||||
dev-qt/qtgui:5[-gles2]
|
||||
dev-qt/qtnetwork:5
|
||||
dev-qt/qtopengl:5
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtx11extras:5
|
||||
media-libs/assimp
|
||||
net-misc/curl
|
||||
sys-libs/zlib
|
||||
fmod? ( media-libs/fmod )
|
||||
fluidsynth? ( media-sound/fluidsynth )
|
||||
openal? ( media-libs/openal )
|
||||
tools? ( sys-libs/ncurses:0 )
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
virtual/pkgconfig
|
||||
"
|
||||
PDEPEND="
|
||||
demo? ( games-fps/doom-data )
|
||||
freedoom? ( games-fps/freedoom )
|
||||
"
|
||||
|
||||
S="${WORKDIR}/${P}/${PN}"
|
||||
|
||||
DISABLE_AUTOFORMATTING="yes"
|
||||
|
||||
DOC_CONTENTS="
|
||||
You need to copy Doom, Doom 2, Chex Quest, Heretic, Hexen, HexenDD,
|
||||
and Doom64 wads to a folder of your choice. Then configure in game
|
||||
engine where that folder is. This is different than old versions,
|
||||
which had centralized launchers for each game, and required the
|
||||
files to be in a specific place
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Fix QA warning for "installing to one or more unexpected paths"
|
||||
sed -e "10s:/texc:/${PF}:" -i tools/texc/CMakeLists.txt || die
|
||||
}
|
||||
|
||||
internal_src_configure() {
|
||||
export QT_SELECT=qt5
|
||||
local mycmakeargs=(
|
||||
-DDENG_ASSIMP_EMBEDDED="OFF"
|
||||
-DDENG_ENABLE_TOOLS="$(usex tools)"
|
||||
-DPYTHON_EXECUTABLE="${PYTHON}"
|
||||
)
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
python_foreach_impl internal_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
|
||||
if use tools; then
|
||||
mv "${ED%/}"/usr/bin/md2tool "${ED%/}"/usr/bin/md2tool.doomsday || die
|
||||
fi
|
||||
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
readme.gentoo_print_elog
|
||||
|
||||
if use tools; then
|
||||
einfo "In order to prevent a file collision with games-fps/eduke32[tools],"
|
||||
einfo "the utility md2tool has been renamed to md2tool.doomsday."
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user