media-libs/simage: add 1.8.4

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44211
Signed-off-by: Sam James <sam@gentoo.org>

media-libs/simage/Manifest

@@ -1 +1,2 @@
 DIST simage-1.8.3.tar.gz 829994 BLAKE2B 794ee3a1c71727af7e92839542470a4732584715b01cbfd5be7b34d8ea8295ca65f5634e10027e0e7e4eb36a024d31704ad31d9aa0a6ad6b66c08612879a1603 SHA512 193137bd00a322fe6c170d3ff318ac81e4cc685bdfa40a0415c5bb95802b6290174fea630eb79956f362b4e79fa0b60916976c63ef26d6a65a6a51d5d9f7de03
+DIST simage-1.8.4.tar.gz 6798392 BLAKE2B 8135d26075516d35f11917b1c5b0ebc60c559ee6fb4e84c9601e85b28d15ff83eb5031d45e9332b9fcfc113d20c26639e6d118d73601e59a36f15797c2cbe60e SHA512 8dcd55a5ce4b2b135acc3dd2e5e7b589697e545ca68aaf496350202d9bdeeed2c4623d85a56fc8c73f28ece5f02c0047088c8b68732d5067020d487e2ff99965

media-libs/simage/simage-1.8.4.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Image and video texturing library"
+HOMEPAGE="https://github.com/coin3d/simage/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/coin3d/simage.git"
+else
+	SRC_URI="https://github.com/coin3d/simage/releases/download/v${PV}/${P}-src.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="BSD-1"
+# SONAME
+SLOT="0/20"
+IUSE="gif jpeg png qt6 sndfile test tiff vorbis zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	gif? ( media-libs/giflib:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
+	qt6? ( dev-qt/qtbase:6[gui] )
+	sndfile? (
+		media-libs/libsndfile
+		media-libs/flac:=
+	)
+	tiff? (
+		media-libs/tiff:=[lzma,zstd]
+		app-arch/xz-utils
+		app-arch/zstd:=
+	)
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+		media-libs/opus
+	)
+	zlib? ( sys-libs/zlib:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="test? ( media-libs/libsndfile )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.1-0001-Gentoo-specific-remove-RELEASE-flag-from-pkg-config.patch
+)
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DSIMAGE_BUILD_SHARED_LIBS=ON
+		-DSIMAGE_BUILD_EXAMPLES=OFF
+		-DSIMAGE_BUILD_TESTS=$(usex test)
+		-DSIMAGE_BUILD_DOCUMENTATION=OFF
+		-DSIMAGE_USE_AVIENC=OFF # Windows only
+		-DSIMAGE_USE_GDIPLUS=OFF # Windows
+		-DSIMAGE_USE_CGIMAGE=OFF # OS X only
+		-DSIMAGE_USE_QUICKTIME=OFF # OS X only
+		-DSIMAGE_USE_QIMAGE=$(usex qt6)
+		-DSIMAGE_USE_QT5=OFF
+		-DSIMAGE_USE_QT6=$(usex qt6)
+		-DSIMAGE_USE_CPACK=OFF
+		-DSIMAGE_USE_STATIC_LIBS=OFF
+		-DSIMAGE_LIBJASPER_SUPPORT=OFF
+		-DSIMAGE_LIBSNDFILE_SUPPORT=$(usex sndfile)
+		-DSIMAGE_OGGVORBIS_SUPPORT=$(usex vorbis)
+		-DSIMAGE_EPS_SUPPORT=ON
+		-DSIMAGE_MPEG2ENC_SUPPORT=ON
+		-DSIMAGE_PIC_SUPPORT=ON
+		-DSIMAGE_RGB_SUPPORT=ON
+		-DSIMAGE_TGA_SUPPORT=ON
+		-DSIMAGE_XWD_SUPPORT=ON
+		-DSIMAGE_ZLIB_SUPPORT=$(usex zlib)
+		-DSIMAGE_GIF_SUPPORT=$(usex gif)
+		-DSIMAGE_JPEG_SUPPORT=$(usex jpeg)
+		-DSIMAGE_PNG_SUPPORT=$(usex png)
+		-DSIMAGE_TIFF_SUPPORT=$(usex tiff)
+	)
+	cmake_src_configure
+}