mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
net-im/mattermost-desktop-bin: add 5.13.4
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
@@ -1,4 +1,6 @@
|
||||
DIST mattermost-desktop-5.13.3-linux-arm64.tar.gz 114224846 BLAKE2B d7eabdd35d5b29279c19af5295cb9faa71997f775ed820c28e497699d3ac3959d1bf297b01f68eefbcd6f6185a440adde7a5d41a9f4554d74e4a12e176d9782c SHA512 8f79f64f67a6d2080740e2b166b4ae65f26282e32f98bed3beab3fbf01b383e27f860739ded36533334601031566422b831313d37330380c1466d66cb1fbf118
|
||||
DIST mattermost-desktop-5.13.3-linux-x64.tar.gz 114232989 BLAKE2B 2e91fdfe46f273b7674ece324a79826e09ad80f5a32eb95d651b96bf6cbb30561fab26a2e642f275b391e4497f5aeb9b7dc7e1864969d4842a9443efe154d29b SHA512 8a7a0bf111b26fe437226c01efb74218e0c81e0097dc41fc264381805b503463f8a5c35b0371871300cf5d6ad3704e9172f78f7c29d9ed4ffb03849aa58bba72
|
||||
DIST mattermost-desktop-5.13.4-linux-arm64.tar.gz 114224875 BLAKE2B 0a71e12149663f51467db6923fcce149fcce20112eb93357d722ab7cf41ff3d50087c6373a0e154def8d3142b1c1b3a802fdaa9037771e7ac872a06d23199803 SHA512 4d60bff91fbf32338ebd201a7d871d2f0be68a12fbf86fe33b15124eb0bc00a69ca1f3442a5db51a4a218df5deb26b46e80f0fe53cf68a10d3c12b02f42b3202
|
||||
DIST mattermost-desktop-5.13.4-linux-x64.tar.gz 114232972 BLAKE2B c21e53bf4c92fbcc6e18d038997b9b394b687a182c01d1022fe8ee260766ee172be1c1107bde1452a3d4bcd74cb7be7510b9b80f275c1fbfdab704f4eb8727cc SHA512 22f93d294b049cd53fbf6f723d2eabbc33e14c72a45f28f290925c3a80e312f636b2df9c5fadb593f375532a2c5fb508a93cb0eb3f484b0208008c51d2541f27
|
||||
DIST mattermost-desktop-6.0.4-linux-arm64.tar.gz 115339375 BLAKE2B 7327e329b437f56a1046b1b62a5b9db28b75c5c9dd4816142752614adb5b425c03b8af68a2072771683506f89656201024d5a7d4a97a07a4a98045e93e6756f8 SHA512 7f2eb9d2d0b8ba5f4068e7130f5cfb946b8cf91fd8d381af3e7bc63c44bb00e60f0e0a37e5685754bf01e0fa15629d764232055c1c96bdd73d94d2f639b51846
|
||||
DIST mattermost-desktop-6.0.4-linux-x64.tar.gz 115350581 BLAKE2B f3b8421a37787943b944a5a0eef8d60492f2987ccc34f69d089532c6a4cf32a99dfada0b7ee20dc58c901d5c221874cef4b3ab786614aa6253d8a446b6a8373c SHA512 2b789d76f7b10f9566a7a8efa20fd1dc054f30ecee6802ee5bf7eb7238f1684c9d668db3006bfd966704840dad2c434069973f0cf43789bfb5161af95f0ba6a9
|
||||
|
||||
@@ -0,0 +1,114 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
MY_PN="${PN%-*}"
|
||||
MY_PV="${PV/_rc/-rc.}"
|
||||
|
||||
inherit desktop toolchain-funcs xdg
|
||||
|
||||
DESCRIPTION="Mattermost Desktop application"
|
||||
HOMEPAGE="https://mattermost.com/"
|
||||
|
||||
SRC_URI="
|
||||
amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
|
||||
arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
|
||||
"
|
||||
S="${WORKDIR}"
|
||||
|
||||
LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
|
||||
SLOT="0"
|
||||
# Starting with 5.2.0 upstream dropped x86 for their binary release #879519
|
||||
if [[ ${PV} != *rc* ]]; then
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
fi
|
||||
|
||||
RDEPEND="
|
||||
>=app-accessibility/at-spi2-core-2.46.0:2[X]
|
||||
dev-libs/expat
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
dev-libs/wayland
|
||||
media-libs/alsa-lib
|
||||
media-libs/mesa
|
||||
net-print/cups
|
||||
sys-apps/dbus
|
||||
sys-libs/glibc
|
||||
virtual/libudev
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf:2
|
||||
x11-libs/gtk+:3[X]
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libdrm
|
||||
x11-libs/libxcb
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/pango
|
||||
"
|
||||
|
||||
BDEPEND="
|
||||
dev-util/debugedit
|
||||
"
|
||||
|
||||
QA_PREBUILT="
|
||||
opt/mattermost-desktop/mattermost-desktop
|
||||
opt/mattermost-desktop/libnode.so
|
||||
opt/mattermost-desktop/libffmpeg.so
|
||||
opt/mattermost-desktop/libGLESv2.so
|
||||
opt/mattermost-desktop/libEGL.so
|
||||
opt/mattermost-desktop/libvk_swiftshader.so
|
||||
opt/mattermost-desktop/libvulkan.so.1
|
||||
opt/mattermost-desktop/resources/*
|
||||
"
|
||||
|
||||
DOCS=(
|
||||
NOTICE.txt
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# file collision with FEATURES=splitdebug, see bug #961437
|
||||
tc-export OBJCOPY
|
||||
find . -type f ! -name '*$(*)*' -print0 | while IFS= read -r -d '' file; do
|
||||
if file "${file}" | grep -qE "ELF (32|64)-bit"; then
|
||||
${OBJCOPY} --remove-section .note.gnu.build-id "${file}" || die
|
||||
debugedit -b "${EPREFIX}/opt/${MY_PN}" -d "/usr/lib/debug" -i "${file}" || die
|
||||
fi
|
||||
done
|
||||
}
|
||||
|
||||
src_install() {
|
||||
if use amd64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-x64 || die
|
||||
elif use arm64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-arm64 || die
|
||||
fi
|
||||
newicon app_icon.png ${MY_PN}.png
|
||||
|
||||
insinto "/opt/${MY_PN}/locales"
|
||||
doins locales/*.pak
|
||||
|
||||
insinto "/opt/${MY_PN}/resources"
|
||||
doins -r resources/*.asar*
|
||||
|
||||
insinto "/opt/${MY_PN}"
|
||||
doins *.pak *.bin *.dat
|
||||
exeinto "/opt/${MY_PN}"
|
||||
doexe *.so *.so.* "${MY_PN}"
|
||||
|
||||
dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
|
||||
|
||||
make_desktop_entry \
|
||||
"${MY_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
|
||||
Mattermost "${MY_PN}" "Network;InstantMessaging;" \
|
||||
"MimeType=x-scheme-handler/mattermost;\nStartupWMClass=Mattermost"
|
||||
|
||||
einstalldocs
|
||||
}
|
||||
Reference in New Issue
Block a user