gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

net-libs/nghttp2: add 1.50.0

Browse Source 
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
This commit is contained in:
Bernard Cafarelli
2022-09-23 21:21:53 +02:00
parent ff3e4459a2
commit e664a5513c
2 changed files with 77 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
net-libs/nghttp2/Manifest
View File

@@ -2,3 +2,4 @@ DIST nghttp2-1.47.0.tar.xz 4028580 BLAKE2B 4f5302701c8d8a89c3ae72cbb8acb4cbcbe32
DIST nghttp2-1.48.0-pthread.patch 24917 BLAKE2B 22013d89685be603094aa82f69da8741d4c0d76aea8a01de1322c19cef053964fdf0bec937650382f85607ac74466d4d052e6d40217101bc1e40326ad0ddc003 SHA512 bdebc50f13584826d6693aae201db9be63fcadcb8a68af188e94f008e005a2fd6aa6b91b31de2f07f84b93d981a003c8752c5fb4d47502f768bd94e21635627f
DIST nghttp2-1.48.0.tar.xz 4112072 BLAKE2B a52dc1ef4c9658298acef5ad703bec1708e538ebe19584dd5fcfe39089777e105594a998c7db696ee54bc8f17d3086828c09e921d8714b7ad3efbf33d04aaca0 SHA512 77c22371290f77e8a538b9efea225d23567cc27cb60b71703cbcb057839b5f117cf50796aa82bf4518f22b38a5773e90a1c273eafff4b17c435ac5858bdf7c6f
DIST nghttp2-1.49.0.tar.xz 4112260 BLAKE2B 47e892917e52b820d13a6721213550587f6e6652d94701de3d69d923e16d1cd44d9ddf7eb2733f51ec73c0055a432e9b2f636ff4dcfa22cde637e0c421b0c073 SHA512 599bc8e52bbe7f5bdfbf493ea2199c4c4bdeb9eac174d4c56b11fb321b11b86e82674bd3c7f60d7ea975ef60eec3f258b5438d1157491cfa23a1b9adccd7948a
DIST nghttp2-1.50.0.tar.xz 4110336 BLAKE2B ae5d89a1f7287a3f2f2b9380ff5e9efb7f0646950d15ed281f268dafc65eb34ad7e34610333b4c98db8a657034ea462e7f1eda80ff2e94a918751dbb112c9a2a SHA512 c2f7f14972cb268a85966f2bd26ac515fa61d9cf6b6bcaa5cffc04f02a18abf116b15537eb4dfbdfa79e7b1472de7034dfdbce7a082cc5b23627d87e2939e529

76
net-libs/nghttp2/nghttp2-1.50.0.ebuild Normal file
View File

@@ -0,0 +1,76 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# TODO: Add python support.
EAPI=8
inherit autotools multilib-minimal
DESCRIPTION="HTTP/2 C Library"
HOMEPAGE="https://nghttp2.org/"
SRC_URI="https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz
https://dev.gentoo.org/~voyageur/distfiles/${PN}-1.48.0-pthread.patch"
LICENSE="MIT"
SLOT="0/1.14" # <C++>.<C> SONAMEs
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="cxx debug hpack-tools jemalloc static-libs test utils xml"
RESTRICT="!test? ( test )"
SSL_DEPEND="
>=dev-libs/openssl-1.0.2:0=[-bindist(-),${MULTILIB_USEDEP}]
"
RDEPEND="
cxx? (
${SSL_DEPEND}
dev-libs/boost:=[${MULTILIB_USEDEP}]
)
hpack-tools? ( >=dev-libs/jansson-2.5:= )
jemalloc? ( dev-libs/jemalloc:=[${MULTILIB_USEDEP}] )
utils? (
${SSL_DEPEND}
>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
>=sys-libs/zlib-1.2.3[${MULTILIB_USEDEP}]
net-dns/c-ares:=[${MULTILIB_USEDEP}]
)
xml? ( >=dev-libs/libxml2-2.7.7:2[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${DISTDIR}"/${PN}-1.48.0-pthread.patch
)
src_prepare() {
default
eautoreconf
}
multilib_src_configure() {
local myeconfargs=(
--disable-examples
--disable-failmalloc
--disable-python-bindings
--disable-werror
--enable-threads
--without-cython
$(use_enable cxx asio-lib)
$(use_enable debug)
$(multilib_native_use_enable hpack-tools)
$(use_enable static-libs static)
$(use_with test cunit)
$(multilib_native_use_enable utils app)
$(multilib_native_use_with jemalloc)
$(multilib_native_use_with xml libxml2)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
if ! use static-libs ; then
find "${ED}"/usr -type f -name '*.la' -delete || die
fi
}