mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
kde-plasma/plasma-workspace: 5.20.2 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST plasma-workspace-5.19.5.tar.xz 5682264 BLAKE2B 435ea4c73fe50fb78911efb607f1a22ce6fe4a8f089b90b44374e7932d4f0111069dbce0168eedb61de09affdae3549563365bf85b4bbafb33fc69fad6b343e8 SHA512 4cab64c1f817f391a61ae15e37bf1fc936ddd3fb3b234e281a3e5750b67dab05c1c156789446096cbde719bf972e876757c1c5ae78adde4e85f3591fa8df5df9
|
||||
DIST plasma-workspace-5.20.1.1.tar.xz 8994820 BLAKE2B e95b80630bf203f5b2deacac5972636289ef505d1f3828bd8382a966395d6fc547e7eef4faa16fdb0db937addf182a9a09f1cc62db6ef9cb4c07864622fef48e SHA512 db7acbe7fc441429ffcefea152fe4036344a4f3fce3a83b0b3ccce781e5e453944541342b64f5e89535296976c837d45e25c03843d01ee083ff9d0a04ec2a8cf
|
||||
DIST plasma-workspace-5.20.2.tar.xz 8995036 BLAKE2B b75d4dcfbf41fe9379bb132486604ac18702641b7d14e1f3ea20f5cc434b385c7f45446a471a761e7a7a3cc0c1d6996ad3545b84ac78cbbbc27dcebf51bf497f SHA512 fb65ed1ee61c25cba282432157b96401c32bbbd0eec1da56dc7727760e817aa333ed3088b1ea707d3593c530d4987de9cb4c73200314e9064d8e880e82be0e1e
|
||||
|
||||
@@ -0,0 +1,201 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
ECM_TEST="forceoptional"
|
||||
KFMIN=5.74.0
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
QTMIN=5.15.1
|
||||
VIRTUALX_REQUIRED="test"
|
||||
inherit ecm kde.org
|
||||
|
||||
DESCRIPTION="KDE Plasma workspace"
|
||||
|
||||
LICENSE="GPL-2" # TODO: CHECK
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
|
||||
IUSE="appstream +calendar +fontconfig geolocation gps qalculate screencast +semantic-desktop systemd telemetry"
|
||||
|
||||
REQUIRED_USE="gps? ( geolocation )"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
COMMON_DEPEND="
|
||||
>=dev-libs/wayland-1.15
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
|
||||
>=dev-qt/qtgui-${QTMIN}:5=[jpeg]
|
||||
>=dev-qt/qtnetwork-${QTMIN}:5
|
||||
>=dev-qt/qtsql-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwayland-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=dev-qt/qtx11extras-${QTMIN}:5
|
||||
>=dev-qt/qtxml-${QTMIN}:5
|
||||
>=kde-frameworks/kactivities-${KFMIN}:5
|
||||
>=kde-frameworks/kactivities-stats-${KFMIN}:5
|
||||
>=kde-frameworks/kauth-${KFMIN}:5
|
||||
>=kde-frameworks/kbookmarks-${KFMIN}:5
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:5
|
||||
>=kde-frameworks/kconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kcrash-${KFMIN}:5
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kdeclarative-${KFMIN}:5
|
||||
>=kde-frameworks/kded-${KFMIN}:5
|
||||
>=kde-frameworks/kdelibs4support-${KFMIN}:5
|
||||
>=kde-frameworks/kglobalaccel-${KFMIN}:5
|
||||
>=kde-frameworks/kguiaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:5
|
||||
>=kde-frameworks/kidletime-${KFMIN}:5
|
||||
>=kde-frameworks/kio-${KFMIN}:5
|
||||
>=kde-frameworks/kitemmodels-${KFMIN}:5
|
||||
>=kde-frameworks/kitemviews-${KFMIN}:5
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:5
|
||||
>=kde-frameworks/knotifications-${KFMIN}:5
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kpackage-${KFMIN}:5
|
||||
>=kde-frameworks/kpeople-${KFMIN}:5
|
||||
>=kde-frameworks/krunner-${KFMIN}:5
|
||||
>=kde-frameworks/kservice-${KFMIN}:5
|
||||
>=kde-frameworks/ktexteditor-${KFMIN}:5
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kwallet-${KFMIN}:5
|
||||
>=kde-frameworks/kwayland-${KFMIN}:5
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:5
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:5
|
||||
>=kde-frameworks/plasma-${KFMIN}:5
|
||||
>=kde-frameworks/prison-${KFMIN}:5[qml]
|
||||
>=kde-frameworks/solid-${KFMIN}:5
|
||||
>=kde-plasma/kscreenlocker-${PVCUT}:5
|
||||
>=kde-plasma/kwin-${PVCUT}:5
|
||||
>=kde-plasma/libkscreen-${PVCUT}:5
|
||||
>=kde-plasma/libksysguard-${PVCUT}:5
|
||||
>=kde-plasma/libkworkspace-${PVCUT}:5
|
||||
>=media-libs/phonon-4.11.0
|
||||
sys-libs/zlib
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libX11
|
||||
x11-libs/libXau
|
||||
x11-libs/libxcb
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXtst
|
||||
x11-libs/xcb-util
|
||||
x11-libs/xcb-util-image
|
||||
appstream? ( dev-libs/appstream[qt5] )
|
||||
calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
|
||||
fontconfig? (
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
x11-libs/libXft
|
||||
x11-libs/xcb-util-image
|
||||
)
|
||||
geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
|
||||
gps? ( sci-geosciences/gpsd )
|
||||
qalculate? ( sci-libs/libqalculate:= )
|
||||
screencast? (
|
||||
>=media-video/pipewire-0.3:=
|
||||
x11-libs/libdrm
|
||||
)
|
||||
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
|
||||
telemetry? ( dev-libs/kuserfeedback:5 )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-libs/plasma-wayland-protocols-1.1.1
|
||||
>=dev-qt/qtconcurrent-${QTMIN}:5
|
||||
x11-base/xorg-proto
|
||||
fontconfig? ( x11-libs/libXrender )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
app-text/iso-codes
|
||||
>=dev-qt/qdbus-${QTMIN}:5
|
||||
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
|
||||
>=dev-qt/qtpaths-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
>=kde-apps/kio-extras-19.04.3:5
|
||||
>=kde-frameworks/kdesu-${KFMIN}:5
|
||||
>=kde-frameworks/kirigami-${KFMIN}:5
|
||||
>=kde-frameworks/kquickcharts-${KFMIN}:5
|
||||
>=kde-plasma/ksysguard-${PVCUT}:5
|
||||
>=kde-plasma/milou-${PVCUT}:5
|
||||
>=kde-plasma/plasma-integration-${PVCUT}:5
|
||||
x11-apps/xmessage
|
||||
x11-apps/xprop
|
||||
x11-apps/xrdb
|
||||
x11-apps/xsetroot
|
||||
systemd? ( sys-apps/dbus[user-session] )
|
||||
!systemd? ( sys-apps/dbus )
|
||||
!<kde-plasma/plasma-desktop-5.19.80:5
|
||||
"
|
||||
PDEPEND="
|
||||
>=kde-plasma/kde-cli-tools-${PVCUT}:5
|
||||
"
|
||||
|
||||
PATCHES=( "${FILESDIR}/${PN}-5.14.2-split-libkworkspace.patch" )
|
||||
|
||||
RESTRICT+=" test"
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
|
||||
cmake_comment_add_subdirectory libkworkspace
|
||||
# delete colliding libkworkspace translations
|
||||
if [[ ${KDE_BUILD_TYPE} = release ]]; then
|
||||
find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
|
||||
fi
|
||||
|
||||
# TODO: try to get a build switch upstreamed
|
||||
if ! use screencast; then
|
||||
sed -e "s/^pkg_check_modules.*PipeWire/#&/" \
|
||||
-i CMakeLists.txt || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_xembed-sni-proxy=OFF
|
||||
$(cmake_use_find_package appstream AppStreamQt)
|
||||
$(cmake_use_find_package calendar KF5Holidays)
|
||||
$(cmake_use_find_package fontconfig Fontconfig)
|
||||
$(cmake_use_find_package geolocation KF5NetworkManagerQt)
|
||||
$(cmake_use_find_package qalculate Qalculate)
|
||||
$(cmake_use_find_package semantic-desktop KF5Baloo)
|
||||
$(cmake_use_find_package telemetry KUserFeedback)
|
||||
)
|
||||
|
||||
use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
ecm_src_install
|
||||
|
||||
# default startup and shutdown scripts
|
||||
insinto /etc/xdg/plasma-workspace/env
|
||||
doins "${FILESDIR}"/10-agent-startup.sh
|
||||
|
||||
insinto /etc/xdg/plasma-workspace/shutdown
|
||||
doins "${FILESDIR}"/10-agent-shutdown.sh
|
||||
fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
|
||||
}
|
||||
|
||||
pkg_postinst () {
|
||||
ecm_pkg_postinst
|
||||
|
||||
# Clean up pre-5.17.4 dirs
|
||||
rmdir -v "${EROOT}"/etc/plasma{/startup,/shutdown,} 2> /dev/null
|
||||
|
||||
elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
|
||||
elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
|
||||
elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
|
||||
}
|
||||
Reference in New Issue
Block a user