dev-python/pyside6-tools: add 6.7.2

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

dev-python/pyside6-tools/Manifest

@@ -1 +1,2 @@
 DIST pyside-setup-everywhere-src-6.7.1.tar.xz 14400976 BLAKE2B 1f6e2705aedc4151147e259da2a8fbab19a1815f19f1a36ea46dbf0bf2282a453e85a33ea8c6862072bb22699be39ab8375b48cd6d5b879de8bed5fad8cf60cb SHA512 6ca73f0b16ef43bc018aeb9e0f51d8ae91b13b79ebdfd71f5524bc0e8ef78322ba0aca81203cc5532e5096a55441fb4dabf3b628de3234b876b7a70327b714d4
+DIST pyside-setup-everywhere-src-6.7.2.tar.xz 14402156 BLAKE2B 321717ba46c7ed29404ee326f852cd4032f93e23b6b32a16e4e05305ff04a00a2029ee7c1d50ad7191a836ffd9a3ae858483bac35e8254bdcaeb474e2c92df60 SHA512 4376aba85867b5a04dab9d8889f5e32cb503cb8010757c1e810e60d29755f15a002b582594d0737a4119c030b48ede26964e8b1392700a6c061d7d631cdfe73e

dev-python/pyside6-tools/pyside6-tools-6.7.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# TODO: Add PyPy once officially supported. See also:
+#     https://bugreports.qt.io/browse/PYSIDE-535
+PYTHON_COMPAT=( python3_{10..13} )
+
+LLVM_COMPAT=( {15..18} )
+
+inherit cmake llvm-r1 python-r1
+
+MY_PN="pyside-setup-everywhere-src"
+
+DESCRIPTION="PySide development tools (pyside6-lupdate with support for Python)"
+HOMEPAGE="https://wiki.qt.io/PySide6"
+SRC_URI="https://download.qt.io/official_releases/QtForPython/pyside6/PySide6-${PV}-src/${MY_PN}-${PV}.tar.xz"
+S="${WORKDIR}/${MY_PN}-${PV}/sources/pyside-tools"
+
+LICENSE="GPL-2"
+SLOT="6/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Minimal supported version of Qt.
+QT_PV="$(ver_cut 1-3)*:6"
+
+RDEPEND="${PYTHON_DEPS}
+	=dev-python/shiboken6-${QT_PV}[${PYTHON_USEDEP},${LLVM_USEDEP}]
+	=dev-python/pyside6-${QT_PV}[quick,${PYTHON_USEDEP},${LLVM_USEDEP}]
+	!dev-python/pyside6-tools:0
+"
+DEPEND="${RDEPEND}
+	$(llvm_gen_dep '
+		sys-devel/clang:${LLVM_SLOT}
+		sys-devel/llvm:${LLVM_SLOT}
+	')
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	pyside-tools_configure() {
+		local mycmakeargs=(
+			# If this is enabled cmake just makes copies of /lib64/qt6/bin/*
+			-DNO_QT_TOOLS=yes
+		)
+		cmake_src_configure
+	}
+
+	python_foreach_impl pyside-tools_configure
+}
+
+src_compile() {
+	pyside-tools_compile() {
+		cmake_src_compile
+	}
+
+	python_foreach_impl pyside-tools_compile
+}
+
+src_install() {
+	pyside-tools_install() {
+		# This replicates the contents of the PySide6 pypi wheel
+		DESTDIR="${BUILD_DIR}" cmake_build install
+		cp __init__.py "${BUILD_DIR}/usr/bin" || die
+		rm -r  "${BUILD_DIR}/usr/bin/qtpy2cpp_lib/tests" || die
+		python_moduleinto PySide6/scripts
+		python_domodule "${BUILD_DIR}/usr/bin/."
+	}
+
+	python_foreach_impl pyside-tools_install
+
+	einstalldocs
+}