gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-04 00:08:09 -07:00
Code Issues Projects Releases Wiki Activity

www-misc/urlwatch: bump to 2.21, add Python 3.9 support

Browse Source 
Tests now use pytest instead of nose.

Package-Manager: Portage-3.0.3, Repoman-2.3.23
Signed-off-by: Louis Sautier <sbraz@gentoo.org>
This commit is contained in:
Louis Sautier
2020-08-24 15:43:59 +02:00
parent e6c830fc5e
commit e58b650cb0
2 changed files with 73 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
www-misc/urlwatch/Manifest
View File

@@ -1,2 +1,3 @@
DIST urlwatch-2.17.tar.gz 44178 BLAKE2B 46163b3305a50c3b5165da8f794c252aeb0a3581f16ba04cc1f0d920066accd02f7eba47718012e2ac0071f6bfa31019777a28840179a28a7fe365ae2e8f1d2c SHA512 635bca7e55641dd73447f5ec9ad429539decfaa8a1c19ab073c3bd46acfc518fa6012d855e0c37dd78654da28acf1446f580def611bcb85ae94fe13f567e3613
DIST urlwatch-2.18.tar.gz 48268 BLAKE2B e595a6ed27637463f14f92ecafd123eb0c7cef7102cc35ebbc3334804f7e09cc5f933aa2d54e24acd74a1419d6a8683a0d5fb2456b35ae0797c3d8a12efc33de SHA512 4b44a78fe7f2be6f507487ad5de57d79aa55ee790b29b97f2a364c0f3b58828fea5eb2b08235c15cafd3839b9261a7f148ebc9bceb5bedd1ff8319f7f039bb23
DIST urlwatch-2.21.tar.gz 126235 BLAKE2B 9e0f39e51e413355974ce886e019eb86dd07fb9a75c02c5c711ccdbba573c2e6b218cf11b42c714172ad00288ea0219a079fd9b8016d33c29f087537d160e80d SHA512 30d7312c72d839e8ef681a11065f82c2611b650ab1b9b9a33e718bb791712674afb31e4b2e6da97038379fb8cc4ae5bc58b4d0ee6a26c424cba01898b56566b7

72
www-misc/urlwatch/urlwatch-2.21.ebuild Normal file
View File

@@ -0,0 +1,72 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
# The package uses entry points but setup.py is weird
# so the eclass doesn't detect it
DISTUTILS_USE_SETUPTOOLS=manual
inherit distutils-r1
DESCRIPTION="A tool for monitoring webpages for updates"
HOMEPAGE="https://thp.io/2008/urlwatch/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-python/appdirs[${PYTHON_USEDEP}]
dev-python/cssselect[${PYTHON_USEDEP}]
dev-python/keyring[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/minidb[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
${RDEPEND}
dev-python/pytest[${PYTHON_USEDEP}]
)
"
DOCS=( CHANGELOG.md README.md )
python_test() {
local skipped_tests=(
# Require the pdftotext module
"lib/urlwatch/tests/test_filter_documentation.py::test_url[https://example.net/pdf-test.pdf-job12]"
"lib/urlwatch/tests/test_filter_documentation.py::test_url[https://example.net/pdf-test-password.pdf-job13]"
# Requires the pytesseract module
"lib/urlwatch/tests/test_filter_documentation.py::test_url[https://example.net/ocr-test.png-job26]"
)
pytest -vv ${skipped_tests[@]/#/--deselect } \
|| die "Tests failed with ${EPYTHON}"
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
if ! has_version dev-python/chump; then
elog "Install 'dev-python/chump' to enable Pushover" \
"notifications support"
fi
if ! has_version dev-python/pushbullet-py; then
elog "Install 'dev-python/pushbullet-py' to enable" \
"Pushbullet notifications support"
fi
elog "HTML parsing can be improved by installing one of the following packages"
elog "and changing the html2text subfilter parameter:"
elog "dev-python/beautifulsoup:4"
elog "app-text/html2text"
elog "dev-python/html2text"
elog "www-client/lynx"
fi
}