dev-go/go-crypto: version bump to 0_pre20160126

Package-Manager: portage-2.2.27

dev-go/go-crypto/Manifest

@@ -1 +1,2 @@
 DIST go-crypto-0_pre20150808.tar.gz 876947 SHA256 9ff25a17515c6c7ff0d13fb076ba7a1df868ce30fca105277b3f0356ce801518 SHA512 86826102ff7242259d79a31e543a03192d6b68a06635b46ebac349111bb8451605df1ad9b249c08d75895c38fb4ebbbfc716d40c8c981485395164e87db5a519 WHIRLPOOL 5e1a0372d0a2f493e68c213ce866237cab316c1bf712f2c58a95c16c6864c48ea795e5a6e1346aad7459f666802170aeb0db8f781423fb1d8e252e5bced2e435
+DIST go-crypto-0_pre20160126.tar.gz 902001 SHA256 c1efa4d05d59ef64db60e872fd80afe4e0060cf4cd6924bb51940ef98b45e4ff SHA512 168129ab9581b7348fb3285e045d99a0a837ac7bd65bf9f5e7a220fffbb9e2abf76da5f521c66eea7179eba0ad8da68d6f41cd9624ea40a9da25a18838427846 WHIRLPOOL dbe3067085b5a08c4dd2e13385691aadeda35336c479140684fdb2b08de27ab9447b63cf404c14b9a69520c585a09051f21374c81101599671be091b24fc92d5

dev-go/go-crypto/go-crypto-0_pre20160126.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+EGO_PN=golang.org/x/crypto/...
+EGO_SRC=golang.org/x/crypto
+
+if [[ ${PV} = *9999* ]]; then
+	inherit golang-vcs
+else
+	KEYWORDS="~amd64"
+	EGIT_COMMIT="1f22c0103821b9390939b6776727195525381532"
+	SRC_URI="https://github.com/golang/crypto/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+inherit golang-build
+
+DESCRIPTION="Go supplementary cryptography libraries"
+HOMEPAGE="https://godoc.org/golang.org/x/crypto"
+LICENSE="BSD"
+SLOT="0/${PVR}"
+IUSE=""
+DEPEND=""
+RDEPEND=""
+
+src_prepare() {
+	# disable broken tests
+	sed -e 's:TestAgentForward(:_\0:' \
+		-i src/${EGO_SRC}/ssh/test/agent_unix_test.go || die
+	sed -e 's:TestRunCommandSuccess(:_\0:' \
+		-e 's:TestRunCommandStdin(:_\0:' \
+		-e 's:TestRunCommandStdinError(:_\0:' \
+		-e 's:TestRunCommandWeClosed(:_\0:' \
+		-e 's:TestFuncLargeRead(:_\0:' \
+		-e 's:TestKeyChange(:_\0:' \
+		-e 's:TestValidTerminalMode(:_\0:' \
+		-i src/${EGO_SRC}/ssh/test/session_test.go || die
+}
+
+src_compile() {
+	# Create a writable GOROOT in order to avoid sandbox violations.
+	cp -sR "$(go env GOROOT)" "${T}/goroot" || die
+	rm -rf "${T}/goroot/src/${EGO_SRC}" || die
+	rm -rf "${T}/goroot/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_SRC}" || die
+	export GOROOT="${T}/goroot"
+	golang-build_src_compile
+}