net-im/mattermost-desktop-bin: add 6.1.0_rc4

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Viorel Munteanu
2026-02-20 16:01:55 +02:00
parent 1f05f0de46
commit e4fdd3044e
2 changed files with 115 additions and 0 deletions
+2
View File
@@ -4,3 +4,5 @@ DIST mattermost-desktop-6.0.4-linux-arm64.tar.gz 115339375 BLAKE2B 7327e329b437f
DIST mattermost-desktop-6.0.4-linux-x64.tar.gz 115350581 BLAKE2B f3b8421a37787943b944a5a0eef8d60492f2987ccc34f69d089532c6a4cf32a99dfada0b7ee20dc58c901d5c221874cef4b3ab786614aa6253d8a446b6a8373c SHA512 2b789d76f7b10f9566a7a8efa20fd1dc054f30ecee6802ee5bf7eb7238f1684c9d668db3006bfd966704840dad2c434069973f0cf43789bfb5161af95f0ba6a9
DIST mattermost-desktop-6.1.0-rc.3-linux-arm64.tar.gz 115942291 BLAKE2B 5d3bfa538a5d066733de0120f2953d86b2daa0665a244c6c3ec8391bbfdac4150b9b67310d38d86f01382b6755f8b92e106e4b3e34875de6460bfc64b72d2286 SHA512 1e46b0a7826fcf345d9f1d3191ec473039ecc42bff8cd5826334335498e081a40ebb065289b645d923558b84dd933526afa29f4c4aca748d2bc87c33ae2ca9dc
DIST mattermost-desktop-6.1.0-rc.3-linux-x64.tar.gz 115522226 BLAKE2B a84cb48a1f40c2bb3216cb5cdf0c7c49268f9bc31224c0aab9913f72851c2848a7ee8350ba8726351adc83ebffc505f0836b09df05bed985e1cb9bfc63096fa4 SHA512 04df8c5eb330cbc83ae301e4138aa425bd3a553d5f9eccaf177003c85b547ba72c686ec717210f1cffdbb2ae65386d52e3d70105f2197706b297506c75d3cb41
DIST mattermost-desktop-6.1.0-rc.4-linux-arm64.tar.gz 116061423 BLAKE2B da556c0fba4dfaa62c4eb53e8953b31e66d80d616162ffccd68628807dce773fb604c667d320fbcff4b95c0ac42d281502360c412ec0315ed73e66f666b96b50 SHA512 fe86241e383661d344fb83cde63baa10b62815ab927a1baff4f92f0f96697599f3d45509954d4d9d1476b72f908b9d09b7e87542ef9a7993a9642a62de8b5217
DIST mattermost-desktop-6.1.0-rc.4-linux-x64.tar.gz 115643557 BLAKE2B 4846c96bcdb5cd0d7c005159674327a7d31a017a9de097c7e2e5b311c596f6df8bc82ee7800728e2889ed3ae510ffc9a5ef282351a1405f0293b0b97662a4500 SHA512 3de98ece66d3fbc20d9a119e157f5f03d30d161a59a4a62da6d7564c30dbc332be5afc6f9c2cf0b87316b63e3cc85ced401a7c0bdf4163abf88a12f0ba03d8be
@@ -0,0 +1,113 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PN="${PN%-*}"
MY_PV="${PV/_rc/-rc.}"
inherit desktop toolchain-funcs xdg
DESCRIPTION="Mattermost Desktop application"
HOMEPAGE="https://mattermost.com/"
SRC_URI="
amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
"
S="${WORKDIR}"
LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
SLOT="0"
if [[ ${PV} != *rc* ]]; then
KEYWORDS="~amd64 ~arm64"
fi
RDEPEND="
>=app-accessibility/at-spi2-core-2.46.0:2[X]
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
dev-libs/wayland
media-libs/alsa-lib
media-libs/mesa
net-print/cups
sys-apps/dbus
sys-libs/glibc
virtual/libudev
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:3[X]
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libdrm
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/pango
"
BDEPEND="
dev-util/debugedit
"
QA_PREBUILT="
opt/mattermost-desktop/mattermost-desktop
opt/mattermost-desktop/libnode.so
opt/mattermost-desktop/libffmpeg.so
opt/mattermost-desktop/libGLESv2.so
opt/mattermost-desktop/libEGL.so
opt/mattermost-desktop/libvk_swiftshader.so
opt/mattermost-desktop/libvulkan.so.1
opt/mattermost-desktop/resources/*
"
DOCS=(
NOTICE.txt
)
src_prepare() {
default
# file collision with FEATURES=splitdebug, see bug #961437
tc-export OBJCOPY
find . -type f ! -name '*$(*)*' -print0 | while IFS= read -r -d '' file; do
if file "${file}" | grep -qE "ELF (32|64)-bit"; then
${OBJCOPY} --remove-section .note.gnu.build-id "${file}" || die
debugedit -b "${EPREFIX}/opt/${MY_PN}" -d "/usr/lib/debug" -i "${file}" || die
fi
done
}
src_install() {
if use amd64; then
cd mattermost-desktop-${MY_PV}-linux-x64 || die
elif use arm64; then
cd mattermost-desktop-${MY_PV}-linux-arm64 || die
fi
newicon app_icon.png ${MY_PN}.png
insinto "/opt/${MY_PN}/locales"
doins locales/*.pak
insinto "/opt/${MY_PN}/resources"
doins -r resources/*.asar*
insinto "/opt/${MY_PN}"
doins *.pak *.bin *.dat
exeinto "/opt/${MY_PN}"
doexe *.so *.so.* "${MY_PN}"
dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
make_desktop_entry \
"${MY_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
Mattermost "${MY_PN}" "Network;InstantMessaging;" \
"MimeType=x-scheme-handler/mattermost;\nStartupWMClass=Mattermost"
einstalldocs
}