dev-python/pdm-backend: Bump to 2.1.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-06-26 06:51:45 +02:00
parent 96cb92526a
commit e4df75540f
2 changed files with 72 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST pdm-backend-2.1.0.gh.tar.gz 134050 BLAKE2B 941795a8e108442d8ab651cee2c87f72d01c55e16634d9028f6e6300576ae7c67eaff90cbd6bcd4e24131ddabe92626583cbaf3af1807fd03490650d85653376 SHA512 999940464a467e5a8a6cb232cb8602846461cf7e146256be5f745743e47bfeab7b2b8157dc49ba7b03cff46051d080efe2097c450cfab037e0594ffa5fc3802b
DIST pdm-backend-2.1.1.gh.tar.gz 134089 BLAKE2B a92d29b3d5f32e0bfbf407f354ba672922feb833ad2078857244a40fac7be210c5ba93810d6db7c0edd7fe874f7c9bcb9bd902dde5aa255c2b682855c9a00eed SHA512 710a574822beffad0ff3e812afa69a13878ada8ec10092d4c2f47c37345118dc972ea12fef7b26a835e9d76c774134dfad6fb77902c1755df072ef5acc7160a4
@@ -0,0 +1,71 @@
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( python3_{10..12} pypy3 )
inherit distutils-r1
DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
HOMEPAGE="
https://pypi.org/project/pdm-backend/
https://github.com/pdm-project/pdm-backend/
"
SRC_URI="
https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
' 3.{9..10})
$(python_gen_cond_dep '
>=dev-python/importlib-metadata-3.6[${PYTHON_USEDEP}]
' 3.9)
"
BDEPEND="
${RDEPEND}
test? (
dev-python/setuptools[${PYTHON_USEDEP}]
dev-vcs/git
)
"
# setuptools are used to build C extensions
RDEPEND+="
dev-python/setuptools[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
src_prepare() {
rm -r src/pdm/backend/_vendor || die
find -name '*.py' -exec sed \
-e 's:from pdm\.backend\._vendor\.:from :' \
-e 's:from pdm\.backend\._vendor ::' \
-e 's:import pdm\.backend\._vendor\.:import :' \
-i {} + || die
distutils-r1_src_prepare
}
src_compile() {
# this must not be set during src_test()
local -x PDM_BUILD_SCM_VERSION=${PV}
distutils-r1_src_compile
}
src_test() {
git config --global user.email "test@example.com" || die
git config --global user.name "Test User" || die
distutils-r1_src_test
}