app-text/sigil: add 1.9.2

Closes: https://bugs.gentoo.org/834289
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

app-text/sigil/Manifest

@@ -1 +1,2 @@
 DIST sigil-1.8.0.tar.gz 21217901 BLAKE2B 78615652859d1f61bab18b1b248d342dc6892943a2310659859ab577981c4452fbaeb567758097427453c8dfe95e42b499616a423b5c11b42238f763ac0653c8 SHA512 1a911aac996d3519f501820f8da9c810db9793063e481a6169288d402ef7e6b797308cf7ca5517162d0eb4d80f38f968627bca676b724ea5be5109c427473c95
+DIST sigil-1.9.2.tar.gz 23225656 BLAKE2B 410b2cf1772158aa9b0d499ba54bb7fc176c479acf7e9f48c5113a4e253becab35b6b4aeaa83da249d7c36f824cb1ee9b7a2e95e29c023b37afed9e864f94134 SHA512 fd6a71ce3b05b08651476f86a166d1ccdbecca31b19ecfa31c9d18ebe4daccfd69cf51d687686917c401f4b6e26cc6a57dbae5f9b1d8ba49fe08ccdd0bdf75d7

app-text/sigil/sigil-1.9.2.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="tk"
+
+inherit xdg cmake python-single-r1
+
+DESCRIPTION="Multi-platform WYSIWYG ebook editor for ePub format"
+HOMEPAGE="https://sigil-ebook.com/ https://github.com/Sigil-Ebook/Sigil"
+SRC_URI="https://github.com/Sigil-Ebook/Sigil/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="GPL-3+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+plugins system-mathjax"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-text/hunspell:=
+	dev-libs/libpcre:3=[pcre16]
+	$(python_gen_cond_dep '
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]')
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	sys-libs/zlib[minizip]
+	plugins? ( $(python_gen_cond_dep '
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		dev-python/dulwich[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]') )
+	system-mathjax? ( dev-libs/mathjax )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( ChangeLog.txt README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DTRY_NEWER_FINDPYTHON3=1
+		-DPython3_INCLUDE_DIR="$(python_get_includedir)"
+		-DPython3_LIBRARY="$(python_get_library_path)"
+		-DPython3_EXECUTABLE="${PYTHON}"
+
+		-DINSTALL_BUNDLED_DICTS=0
+		-DSYSTEM_LIBS_REQUIRED=1
+		-DUSE_SYSTEM_LIBS=1
+		-DUSE_QT6=0
+	)
+	use system-mathjax && mycmakeargs+=( -DMATHJAX_DIR="${EPREFIX}"/usr/share/mathjax )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_fix_shebang "${ED}"/usr/share/sigil/
+	python_optimize "${ED}"/usr/share/sigil/
+}