sys-cluster/resource-agents: add 4.15.1

Signed-off-by: Sam James <sam@gentoo.org>

sys-cluster/resource-agents/Manifest

@@ -1 +1,2 @@
 DIST resource-agents-4.12.0.tar.gz 865910 BLAKE2B fe10a86620e9b549b7634721697d04eb331bb87e50c28dadeb4590ae74febc3a793b9d7bce7fbb8de7d1b8a6ace2546882627e506020e1006cb9fb193b114d19 SHA512 1c1ec1ae4a96b6832eb8631f8e2aa064adac04093e1e98c444376e18d27db4b630c840c45bc3486160a2a8f5c510bb05c15362b8b65197387a31b7adc059e87b
+DIST resource-agents-4.15.1.tar.gz 891596 BLAKE2B 17a8e8268508ae539f88a10e8d8b5cfab6449d4a8678b2aac4422a5e4fe33746f99b4b3964b6372eb2ad186a629b85927ba93543a47b1c5f2ca28cc4fb675cf5 SHA512 e5990fa28bef5795183dc198340f5cba1f379f73b89bd53cf1ecb2e7c8337e0ac8f47e85f7f2a66af45b9d7dd500e60f78d757f316168ed2592689d9d88fc0ea

sys-cluster/resource-agents/resource-agents-4.15.1.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${P/resource-}"
+inherit autotools tmpfiles
+
+DESCRIPTION="Resources pack for Heartbeat / Pacemaker"
+HOMEPAGE="http://www.linux-ha.org/wiki/Resource_Agents"
+SRC_URI="https://github.com/ClusterLabs/resource-agents/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="doc libnet rgmanager systemd"
+
+RDEPEND="
+	sys-apps/iproute2
+	sys-apps/which
+	>=sys-cluster/cluster-glue-1.0.12-r1
+	sys-cluster/libqb:=
+	libnet? ( net-libs/libnet:1.1 )
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-apps/which
+	doc? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+		app-text/docbook-xsl-stylesheets
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/4.6.1-configure.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# TODO: fix systemd automagic
+	# TODO: python support
+	local myeconfargs=(
+		--disable-fatal-warnings
+		--localstatedir=/var
+		# --with-ocf-root needs to be /usr/lib, see bug #720420
+		--with-ocf-root=/usr/lib/ocf
+		--with-rsctmpdir=/run/resource-agents
+		$(use_enable doc)
+		$(use_enable libnet)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	rm -rf "${ED}/usr/lib/ocf/resource.d/redhat" || die
+	rm -rf "${ED}"/etc/init.d/ || die
+	rm -rf "${ED}"{,/var}/run || die
+
+	use rgmanager || rm -rf "${ED}"/usr/share/cluster/ "${ED}"/var/
+
+	if ! use systemd ; then
+		newtmpfiles - resource-agents.conf <<-EOF
+		d /var/run/resource-agents 1755 root root
+		EOF
+	fi
+}
+
+pkg_postinst() {
+	tmpfiles_process resource-agents.conf
+
+	elog "To use Resource Agents installed in ${EROOT}/usr/lib/ocf/resource.d"
+	elog "you have to emerge required runtime dependencies manually."
+	elog ""
+	elog "Description and dependencies of all Agents can be found on"
+	elog "http://www.linux-ha.org/wiki/Resource_Agents"
+	elog "or in the documentation of this package."
+}