gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/protobuf-python: Use PEP517 build

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-05-18 08:57:58 +02:00
parent 7b7acddbf8
commit e4ca3a7b55
2 changed files with 77 additions and 3 deletions
Download Patch File Download Diff File Expand all files Collapse all files

72
dev-python/protobuf-python/protobuf-python-3.19.3-r3.ebuild Normal file
View File

@@ -0,0 +1,72 @@
# Copyright 2008-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
EGIT_SUBMODULES=()
fi
DESCRIPTION="Google's Protocol Buffers - Python bindings"
HOMEPAGE="
https://developers.google.com/protocol-buffers/
https://github.com/protocolbuffers/protobuf/
https://pypi.org/project/protobuf/
"
if [[ "${PV}" != "9999" ]]; then
SRC_URI="
https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz
-> protobuf-${PV}.tar.gz
"
fi
S="${WORKDIR}/protobuf-${PV}/python"
LICENSE="BSD"
SLOT="0/30"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
BDEPEND="
${PYTHON_DEPS}
~dev-libs/protobuf-${PV}
dev-python/six[${PYTHON_USEDEP}]
"
DEPEND="
${PYTHON_DEPS}
~dev-libs/protobuf-${PV}
"
RDEPEND="
${BDEPEND}
!dev-python/namespace-google
"
if [[ "${PV}" == "9999" ]]; then
EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
fi
distutils_enable_tests setup.py
python_prepare_all() {
pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
eapply "${FILESDIR}/${PN}-3.19.0-google.protobuf.pyext._message.PyUnknownFieldRef.patch"
eapply_user
popd > /dev/null || die
distutils-r1_python_prepare_all
}
src_configure() {
DISTUTILS_ARGS=(--cpp_implementation)
}
python_compile() {
distutils-r1_python_compile
find "${BUILD_DIR}/install" -name "*.pth" -type f -delete || die
}

8
dev-python/protobuf-python/protobuf-python-9999.ebuild
View File

@@ -3,6 +3,7 @@
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
@@ -18,6 +19,7 @@ DESCRIPTION="Google's Protocol Buffers - Python bindings"
HOMEPAGE="
https://developers.google.com/protocol-buffers/
https://github.com/protocolbuffers/protobuf/
https://pypi.org/project/protobuf/
"
if [[ "${PV}" != "9999" ]]; then
SRC_URI="
@@ -63,7 +65,7 @@ src_configure() {
DISTUTILS_ARGS=(--cpp_implementation)
}
python_install_all() {
distutils-r1_python_install_all
find "${ED}" -name "*.pth" -type f -delete || die
python_compile() {
distutils-r1_python_compile
find "${BUILD_DIR}/install" -name "*.pth" -type f -delete || die
}