dev-python/pdm: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pdm/Manifest

@@ -1,2 +1 @@
-DIST pdm-2.24.0.tar.gz 2655682 BLAKE2B 8c84f15e319308c1c05b74e9a2594c69f6b923cd3ba1ecf303444eab48ca205d26621991cbf1b47e26358f499cbb9d2d9cb527593fcd3fd5d53327f3880d71b4 SHA512 a0308e747e723a1a855d4973d0457d63cc8a9e19ecaf0266b75c5f39f27e0326911e942b5a72808752924ad28de07ef7541f35c5cf29a730738662981e9cdb08
 DIST pdm-2.24.1.tar.gz 2655876 BLAKE2B 557a1a8dac5fe2770a46f9f9baf17ee334795c88f17347924b5450dd681ac90da8c13f184020ee1d200d3d41bc91a6dadde98c210f3a7707c2ee8c83418b917c SHA512 5e41ffeeb8ebf431c840b156caa72e86c22313589f31430258c5002508cb9956f2bbf723c168697721bedb79af7d90bed54a00d53ad1a226f613324830a32146

dev-python/pdm/pdm-2.24.0-r1.ebuild

@@ -1,94 +0,0 @@
-# Copyright 2023-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=pdm-backend
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
-HOMEPAGE="
-	https://pdm-project.org/
-	https://github.com/pdm-project/pdm/
-	https://pypi.org/project/pdm/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-
-RDEPEND="
-	dev-python/certifi[${PYTHON_USEDEP}]
-	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
-	<dev-python/findpython-1[${PYTHON_USEDEP}]
-	>=dev-python/findpython-0.6.0[${PYTHON_USEDEP}]
-	dev-python/blinker[${PYTHON_USEDEP}]
-	dev-python/filelock[${PYTHON_USEDEP}]
-	>=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
-	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
-	dev-python/httpx[${PYTHON_USEDEP}]
-	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
-	dev-python/installer[${PYTHON_USEDEP}]
-	dev-python/msgpack[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/pbs-installer-2024.4.18[${PYTHON_USEDEP}]
-	dev-python/platformdirs[${PYTHON_USEDEP}]
-	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
-	dev-python/python-dotenv[${PYTHON_USEDEP}]
-	>=dev-python/resolvelib-1.1[${PYTHON_USEDEP}]
-	dev-python/rich[${PYTHON_USEDEP}]
-	dev-python/shellingham[${PYTHON_USEDEP}]
-	dev-python/tomlkit[${PYTHON_USEDEP}]
-	>=dev-python/truststore-0.9[${PYTHON_USEDEP}]
-	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
-	dev-python/virtualenv[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/tomli[${PYTHON_USEDEP}]
-	' 3.10)
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
-		dev-python/pytest-httpx[${PYTHON_USEDEP}]
-		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
-		dev-python/uv
-	)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	local PATCHES=(
-		# https://github.com/pdm-project/pdm/issues/3486
-		"${FILESDIR}/${P}-respect-python.patch"
-	)
-
-	distutils-r1_src_prepare
-
-	# unpin deps
-	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Internet
-		# https://github.com/pdm-project/pdm/pull/3488
-		# (the third one I can't reproduce)
-		tests/models/test_candidates.py::test_find_candidates_from_find_links
-		'tests/test_project.py::test_find_interpreters_with_PDM_IGNORE_ACTIVE_VENV[True]'
-		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
-
-		# unhappy about extra packages being installed?
-		# (also fails randomly in venv)
-		tests/cli/test_build.py::test_build_with_no_isolation
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest  -m "not network and not integration and not path" \
-		-p pytest_mock -p pytest_httpx -p pytest_httpserver
-}