app-emacs/magit: Use emake to generate magit-version.el

So it can use VERSIONLIB_TMPL from lisp/Makefile. However, replace
default.mk with an empty file, otherwise it would execute lots of
potentially fragile commands which we don't need.

Update EAPI to 9.

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

app-emacs/magit/magit-4.5.0-r1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+NEED_EMACS="29.2"
+
+inherit elisp
+
+DESCRIPTION="A Git porcelain inside Emacs"
+HOMEPAGE="https://magit.vc/
+	https://github.com/magit/magit/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+S="${WORKDIR}/${P}/lisp"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	app-emacs/compat
+	app-emacs/cond-let
+	app-emacs/dash
+	app-emacs/llama
+	app-emacs/transient
+	app-emacs/with-editor
+"
+BDEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+"
+RDEPEND+="
+	>=dev-vcs/git-2.44.2
+"
+
+DOCS=( ../README.md ../docs/AUTHORS.md ../docs/RelNotes )
+ELISP_TEXINFO="../docs/*.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	default
+	> ../default.mk || die
+	emake magit-version.el PKG="${PN}" VERSION="${PV}"
+}

app-emacs/magit/magit-9999.ebuild

@@ -1,7 +1,7 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=8
+EAPI=9
 
 NEED_EMACS="29.2"
 
@@ -11,7 +11,7 @@ DESCRIPTION="A Git porcelain inside Emacs"
 HOMEPAGE="https://magit.vc/
 	https://github.com/magit/magit/"
 
-if [[ "${PV}" == *9999* ]] ; then
+if [[ ${PV} == *9999* ]] ; then
 	inherit git-r3
 
 	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
@@ -49,6 +49,6 @@ SITEFILE="50${PN}-gentoo.el"
 
 src_prepare() {
 	default
-
-	echo "(setq ${PN}-version \"${PV}\")" > "./${PN}-version.el" || die
+	> ../default.mk || die
+	emake magit-version.el PKG="${PN}" VERSION="${PV}"
 }