gui-apps/deskflow: bump to version 1.23.0, correct 9999

Bug: https://bugs.gentoo.org/961039
Signed-off-by: Christian Schmidt <gentoo@digadd.de>
Part-of: https://github.com/gentoo/gentoo/pull/43302
Closes: https://github.com/gentoo/gentoo/pull/43302
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

gui-apps/deskflow/Manifest

@@ -1,2 +1,3 @@
 DIST deskflow-1.21.2.tar.gz 1884045 BLAKE2B 788823c9154ec9113944bb04e32b750412bec93e096357cb64b33d47a3e8e4b64e3532443ba73660210908e17f0f43c0666437faaf7089b7b527bf2a17c7a1a6 SHA512 e6ef54fb0abbab99dd14502db4e86a563b2fdbf05c632c718a65c8f4a9e85820b1ef61036abf074903d36265f951757148784c8b9331f9d589cf9cd6bfe64ee4
 DIST deskflow-1.22.0.tar.gz 1855676 BLAKE2B c66f94ff8a6c6cbb9fdce83ba1e677d53f11f6646aabc7b623c027236699f53e11faf431a9a01bccefbdd5dc3e3069de62d4eb99476cd6fedfdd9ee41c3a925d SHA512 a1ce959b287e3fa22216b098e21af6572ea38c5010fc2d916a895e05eb8e8ee9c6d7f13f5e4380ed6f760ca5b9ce8c513d5156a4dace8dcc71ca2a06a4b875bb
+DIST deskflow-1.23.0.tar.gz 1825112 BLAKE2B 4ff04858f75abeff121a4599bbd90b13dfad261d773abfc4d5f6784d56e7fae722ac2c3d28ea9d1e9feee892b5be7f862a7157b0868cfc5fe50f9616d4d54be7 SHA512 b65aa09374ae40b74336fbef851e3aa4334573f6935dbd15c01cfd29637440e46d8815dbb137a382f89e6bf99d4a9c371740140b5a49f534dc856fbae3182d86

gui-apps/deskflow/deskflow-1.23.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/deskflow/deskflow.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/deskflow/deskflow/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Share a mouse and keyboard between computers (FOSS version of Synergy)"
+HOMEPAGE="https://github.com/deskflow/deskflow"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gui test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/tomlplusplus
+	dev-libs/glib:2
+	>=dev-libs/libei-0.99.1
+	dev-libs/libportal:=
+	dev-libs/openssl:0=
+	dev-qt/qtbase:6[dbus,network,xml]
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	gui? (
+		dev-qt/qtbase:6[gui,widgets]
+	)
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXtst
+"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/cli11
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+"
+
+DOCS=(
+	README.md
+	doc/user/configuration.md
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_GUI=$(usex gui)
+		-DBUILD_TESTS=$(usex test)
+		$(usex test -DSKIP_BUILD_TESTS=ON "")
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/legacytests || die
+	BUILD_DIR+=/src/unittests virtx cmake_src_test
+}

gui-apps/deskflow/deskflow-9999.ebuild

@@ -55,7 +55,7 @@ BDEPEND="
 
 DOCS=(
 	README.md
-	doc/configuration.md
+	doc/user/configuration.md
 )
 
 src_configure() {