x11-misc/vym: add 2.9.568

sync with live

Closes: https://bugs.gentoo.org/922309
Closes: https://bugs.gentoo.org/922310
Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Closes: https://github.com/gentoo/gentoo/pull/40302
Signed-off-by: Sam James <sam@gentoo.org>

x11-misc/vym/Manifest

@@ -1 +1,2 @@
 DIST vym-2.7.1.tar.bz2 6718924 BLAKE2B d7be8f2d40cedabb1bfaa3b89aac64de5e579f56ebfd757c22d4393ee712c4c4f5bf4747037683e4c6640ab0556ce4ef34bac5b27ecb747a15e58443d57f229f SHA512 985dbf18f743c36b484050ae24e4392eeae701c6c72fca6bd3dc5b70b38a283211946e279804c66253b5a394a642683ca4e3a66a7288400a9193fbcbfd8c9582
+DIST vym-2.9.568.tar.gz 9256371 BLAKE2B d87a4c8ab7dae7f4232b333fe3b14c2283a2ac40e5e92614c459a79a41657221600384961fef6a4276fbff7039fc62ab365c6ad438a52ae24b81626dd462bd8e SHA512 05f0492b7068524d052d75b387eb0183d2ac630b5692ce4b9088fd8a2f29ca21a5b1b3810acc2618a5b672ecfd22bf815b7ae1c287a1e1ceb4154e2a14c3daab

x11-misc/vym/vym-2.9.568.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} = *9999* ]] ; then
+	EGIT_BRANCH="develop"
+	EGIT_REPO_URI="https://github.com/insilmaril/${PN}.git"
+	inherit git-r3
+else
+	COMMIT="d1ba122d89c1c580f26f3535d264250a4d5d6b64"
+	SRC_URI="https://github.com/insilmaril/${PN}/archive/develop/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-develop"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="View Your Mind, a mindmap tool"
+HOMEPAGE="https://www.insilmaril.de/vym/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="dbus"
+
+RDEPEND="
+	dev-qt/qtbase:6[dbus?,gui,network,ssl,widgets,xml]
+	dev-qt/qtdeclarative:6
+	dev-qt/qtsvg:6
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/qttools:6[linguist]"
+
+PATCHES=(
+	# fix install dir for doc, remove gzipped man, set VYM_DOCDIR
+	"${FILESDIR}"/${PN}-2.9-docdir.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	gunzip doc/vym.1.gz || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dbus DBus1)
+		-DCMAKE_INSTALL_DATAROOTDIR="share/${PN}"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	doman doc/vym.1
+
+	cmake_src_install
+}