mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-02 23:48:17 -07:00
media-gfx/imagemagick: bump to v6.9.10-84 & 7.0.9-14
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
This commit is contained in:
Thomas Deutschmann
@@ -1,2 +1,4 @@
|
||||
DIST ImageMagick-6.9.10-84.tar.xz 9072724 BLAKE2B 489d5f9e659f3bd7ad32f58780a5f2e2b95772801b8674f4591120d7643627717572c0b01d011fc5cf7b5592723467e331ca02a0fcfb54d41be482a952b5a7f7 SHA512 bb574cd322a57a79e90021e4e5868792d0005b268a282ecf6c6a0e58c79dbc20e422e6a491c2adf1e50841570a69405f8771245cc2f545f5e7f2150cdf84faae
|
||||
DIST ImageMagick-7.0.9-14.tar.xz 9485404 BLAKE2B be449bc258841eafc83571891c545ba3cecdf6ec8019e665c680ca7dcfb9639db0cf9aee1e53c63ddad03c57549b523e81b926e2613b559baafc833606169a8c SHA512 eaeac3820943c5ed941a5adfa1a5549864d9ac748523eea7b352c8b51e4eb1189586ed0c69e21b1ce2431203ff43973817d45b293f9e85ecbdf35569ef838c3f
|
||||
DIST imagemagick-6.9.10.78.tar.gz 13522518 BLAKE2B 1eab0f7bc6bbecc44b3f25a752ae2b6ad8f026fe700c78d0b914aa23e5737485c8c41785859035002e1dbd16e7d19af823ea71425cb56f732fbee08419212d7d SHA512 8ab6c91afcf2b8c1bd0a4f130d35abae914599ddf7e0c85d6bf57ace8822cdf1cc57929e047350b06532546827856420a484fc9754ae403684db9df04d0f66a9
|
||||
DIST imagemagick-7.0.9.8.tar.gz 13678831 BLAKE2B 3e5189fa244577fdc7d9e674ef0b2385a67dbfc4a0c80fac66a7224b31805925c97fe1955b8386e6d622dd64ffed1cc888657ba5f885d66fb0e8df32703b4ce8 SHA512 3797978e6da49bd6129a437110d9b2b15e1963178c5c62fd228e68295645b469f5cf7d3bb0974ce74a320094973137adfb7409f47248383fe63abc4a49a90ddf
|
||||
|
||||
250
media-gfx/imagemagick/imagemagick-6.9.10.84.ebuild
Normal file
250
media-gfx/imagemagick/imagemagick-6.9.10.84.ebuild
Normal file
@@ -0,0 +1,250 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
|
||||
inherit eapi7-ver eutils flag-o-matic libtool perl-functions toolchain-funcs multilib
|
||||
|
||||
MY_PV="$(ver_rs 3 '-')"
|
||||
MY_P="ImageMagick-${MY_PV}"
|
||||
|
||||
DESCRIPTION="A collection of tools and libraries for many image formats"
|
||||
HOMEPAGE="https://www.imagemagick.org/"
|
||||
SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
|
||||
|
||||
LICENSE="imagemagick"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
|
||||
IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
|
||||
|
||||
REQUIRED_USE="corefonts? ( truetype )
|
||||
test? ( corefonts )"
|
||||
|
||||
RESTRICT="perl? ( userpriv )
|
||||
!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libltdl:0
|
||||
bzip2? ( app-arch/bzip2 )
|
||||
corefonts? ( media-fonts/corefonts )
|
||||
djvu? ( app-text/djvu )
|
||||
fftw? ( sci-libs/fftw:3.0 )
|
||||
fontconfig? ( media-libs/fontconfig )
|
||||
fpx? ( >=media-libs/libfpx-1.3.0-r1 )
|
||||
graphviz? ( media-gfx/graphviz )
|
||||
heif? ( media-libs/libheif:= )
|
||||
jbig? ( >=media-libs/jbigkit-2:= )
|
||||
jpeg? ( virtual/jpeg:0 )
|
||||
jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
|
||||
lcms? ( media-libs/lcms:2= )
|
||||
lqr? ( media-libs/liblqr )
|
||||
opencl? ( virtual/opencl )
|
||||
openexr? ( media-libs/openexr:0= )
|
||||
pango? ( x11-libs/pango )
|
||||
perl? ( >=dev-lang/perl-5.8.8:0= )
|
||||
png? ( media-libs/libpng:0= )
|
||||
postscript? ( app-text/ghostscript-gpl )
|
||||
raw? ( media-libs/libraw:= )
|
||||
svg? ( gnome-base/librsvg )
|
||||
tiff? ( media-libs/tiff:0= )
|
||||
truetype? (
|
||||
media-fonts/urw-fonts
|
||||
>=media-libs/freetype-2
|
||||
)
|
||||
webp? ( media-libs/libwebp:0= )
|
||||
wmf? ( media-libs/libwmf )
|
||||
X? (
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libXext
|
||||
x11-libs/libXt
|
||||
)
|
||||
xml? ( dev-libs/libxml2:= )
|
||||
lzma? ( app-arch/xz-utils )
|
||||
zlib? ( sys-libs/zlib:= )"
|
||||
DEPEND="${RDEPEND}
|
||||
!media-gfx/graphicsmagick[imagemagick]
|
||||
virtual/pkgconfig
|
||||
X? ( x11-base/xorg-proto )"
|
||||
|
||||
#S="${WORKDIR}/${MY_P}"
|
||||
S="${WORKDIR}/ImageMagick6-${MY_PV}"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Apply hardening #664236
|
||||
cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
|
||||
sed -i -e '/^<policymap>$/ {
|
||||
r policy-hardening.snippet
|
||||
d
|
||||
}' \
|
||||
config/policy.xml || \
|
||||
die "Failed to apply hardening of policy.xml"
|
||||
einfo "policy.xml hardened"
|
||||
|
||||
elibtoolize # for Darwin modules
|
||||
|
||||
# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
|
||||
local mesa_cards ati_cards nvidia_cards render_cards
|
||||
shopt -s nullglob
|
||||
ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
|
||||
if test -n "${ati_cards}"; then
|
||||
addpredict "${ati_cards}"
|
||||
fi
|
||||
mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
|
||||
if test -n "${mesa_cards}"; then
|
||||
addpredict "${mesa_cards}"
|
||||
fi
|
||||
nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
|
||||
if test -n "${nvidia_cards}"; then
|
||||
addpredict "${nvidia_cards}"
|
||||
fi
|
||||
render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
|
||||
if test -n "${render_cards}"; then
|
||||
addpredict "${render_cards}"
|
||||
fi
|
||||
shopt -u nullglob
|
||||
addpredict /dev/nvidiactl
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local depth=16
|
||||
use q8 && depth=8
|
||||
use q32 && depth=32
|
||||
|
||||
local openmp=disable
|
||||
use openmp && { tc-has-openmp && openmp=enable; }
|
||||
|
||||
use perl && perl_check_env
|
||||
|
||||
[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
|
||||
|
||||
local myeconfargs=(
|
||||
$(use_enable static-libs static)
|
||||
$(use_enable hdri)
|
||||
$(use_enable opencl)
|
||||
--with-threads
|
||||
--with-modules
|
||||
--with-quantum-depth=${depth}
|
||||
$(use_with cxx magick-plus-plus)
|
||||
$(use_with perl)
|
||||
--with-perl-options='INSTALLDIRS=vendor'
|
||||
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
|
||||
$(use_with bzip2 bzlib)
|
||||
$(use_with X x)
|
||||
$(use_with zlib)
|
||||
--without-autotrace
|
||||
$(use_with postscript dps)
|
||||
$(use_with djvu)
|
||||
--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
|
||||
$(use_with fftw)
|
||||
$(use_with fpx)
|
||||
$(use_with fontconfig)
|
||||
$(use_with truetype freetype)
|
||||
$(use_with postscript gslib)
|
||||
$(use_with graphviz gvc)
|
||||
$(use_with heif heic)
|
||||
$(use_with jbig)
|
||||
$(use_with jpeg)
|
||||
$(use_with jpeg2k openjp2)
|
||||
$(use_with lcms)
|
||||
$(use_with lqr)
|
||||
$(use_with lzma)
|
||||
$(use_with openexr)
|
||||
$(use_with pango)
|
||||
$(use_with png)
|
||||
$(use_with raw)
|
||||
$(use_with svg rsvg)
|
||||
$(use_with tiff)
|
||||
$(use_with webp)
|
||||
$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
|
||||
$(use_with wmf)
|
||||
$(use_with xml)
|
||||
--${openmp}-openmp
|
||||
--with-gcc-arch=no-automagic
|
||||
)
|
||||
CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# Install default (unrestricted) policy in $HOME for test suite #664238
|
||||
local _im_local_config_home="${HOME}/.config/ImageMagick"
|
||||
mkdir -p "${_im_local_config_home}" || \
|
||||
die "Failed to create IM config dir in '${_im_local_config_home}'"
|
||||
cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
|
||||
die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
|
||||
|
||||
local im_command= IM_COMMANDS=()
|
||||
IM_COMMANDS+=( "identify -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
|
||||
IM_COMMANDS+=( "identify -list policy" ) # Verify that policy.xml is used
|
||||
IM_COMMANDS+=( "emake check" ) # Run tests
|
||||
|
||||
for im_command in "${IM_COMMANDS[@]}"; do
|
||||
eval "${S}"/magick.sh \
|
||||
${im_command} || \
|
||||
die "Failed to run \"${im_command}\""
|
||||
done
|
||||
}
|
||||
|
||||
src_install() {
|
||||
# Ensure documentation installation files and paths with each release!
|
||||
emake \
|
||||
DESTDIR="${D}" \
|
||||
DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
|
||||
install
|
||||
|
||||
rm -f "${ED%/}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
|
||||
dodoc {AUTHORS,README}.txt ChangeLog
|
||||
|
||||
if use perl; then
|
||||
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
|
||||
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
|
||||
fi
|
||||
|
||||
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
|
||||
|
||||
if use opencl; then
|
||||
cat <<-EOF > "${T}"/99${PN}
|
||||
SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
|
||||
EOF
|
||||
|
||||
insinto /etc/sandbox.d
|
||||
doins "${T}"/99${PN} #472766
|
||||
fi
|
||||
|
||||
insinto /usr/share/${PN}
|
||||
doins config/*icm
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
local _show_policy_xml_notice=
|
||||
|
||||
if [[ -z "${REPLACING_VERSIONS}" ]]; then
|
||||
# This is a new installation
|
||||
_show_policy_xml_notice=yes
|
||||
else
|
||||
local v
|
||||
for v in ${REPLACING_VERSIONS}; do
|
||||
if ! ver_test "${v}" -gt "6.9.10.10-r2"; then
|
||||
# This is an upgrade
|
||||
_show_policy_xml_notice=yes
|
||||
|
||||
# Show this elog only once
|
||||
break
|
||||
fi
|
||||
done
|
||||
fi
|
||||
|
||||
if [[ -n "${_show_policy_xml_notice}" ]]; then
|
||||
elog "For security reasons, a policy.xml file was installed in /etc/ImageMagick-6"
|
||||
elog "which will prevent the usage of the following coders by default:"
|
||||
elog ""
|
||||
elog " - PS"
|
||||
elog " - PS2"
|
||||
elog " - PS3"
|
||||
elog " - EPS"
|
||||
elog " - PDF"
|
||||
elog " - XPS"
|
||||
fi
|
||||
}
|
||||
262
media-gfx/imagemagick/imagemagick-7.0.9.14.ebuild
Normal file
262
media-gfx/imagemagick/imagemagick-7.0.9.14.ebuild
Normal file
@@ -0,0 +1,262 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="7"
|
||||
|
||||
inherit flag-o-matic libtool perl-functions toolchain-funcs multilib
|
||||
|
||||
if [[ ${PV} == "9999" ]] ; then
|
||||
EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
|
||||
inherit git-r3
|
||||
MY_P="imagemagick-9999"
|
||||
else
|
||||
MY_PV="$(ver_rs 3 '-')"
|
||||
MY_P="ImageMagick-${MY_PV}"
|
||||
SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
|
||||
fi
|
||||
|
||||
DESCRIPTION="A collection of tools and libraries for many image formats"
|
||||
HOMEPAGE="https://www.imagemagick.org/"
|
||||
|
||||
LICENSE="imagemagick"
|
||||
SLOT="0/7.0.9"
|
||||
IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
REQUIRED_USE="corefonts? ( truetype )
|
||||
test? ( corefonts )"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libltdl:0
|
||||
bzip2? ( app-arch/bzip2 )
|
||||
corefonts? ( media-fonts/corefonts )
|
||||
djvu? ( app-text/djvu )
|
||||
fftw? ( sci-libs/fftw:3.0 )
|
||||
fontconfig? ( media-libs/fontconfig )
|
||||
fpx? ( >=media-libs/libfpx-1.3.0-r1 )
|
||||
graphviz? ( media-gfx/graphviz )
|
||||
heif? ( media-libs/libheif:= )
|
||||
jbig? ( >=media-libs/jbigkit-2:= )
|
||||
jpeg? ( virtual/jpeg:0 )
|
||||
jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
|
||||
lcms? ( media-libs/lcms:2= )
|
||||
lqr? ( media-libs/liblqr )
|
||||
opencl? ( virtual/opencl )
|
||||
openexr? ( media-libs/openexr:0= )
|
||||
pango? ( x11-libs/pango )
|
||||
perl? ( >=dev-lang/perl-5.8.8:0= )
|
||||
png? ( media-libs/libpng:0= )
|
||||
postscript? ( app-text/ghostscript-gpl )
|
||||
raw? ( media-libs/libraw:= )
|
||||
svg? ( gnome-base/librsvg )
|
||||
tiff? ( media-libs/tiff:0= )
|
||||
truetype? (
|
||||
media-fonts/urw-fonts
|
||||
>=media-libs/freetype-2
|
||||
)
|
||||
webp? ( media-libs/libwebp:0= )
|
||||
wmf? ( media-libs/libwmf )
|
||||
X? (
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libXext
|
||||
x11-libs/libXt
|
||||
)
|
||||
xml? ( dev-libs/libxml2:= )
|
||||
lzma? ( app-arch/xz-utils )
|
||||
zlib? ( sys-libs/zlib:= )"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
!media-gfx/graphicsmagick[imagemagick]
|
||||
X? ( x11-base/xorg-proto )"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Apply hardening #664236
|
||||
cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
|
||||
sed -i -e '/^<policymap>$/ {
|
||||
r policy-hardening.snippet
|
||||
d
|
||||
}' \
|
||||
config/policy.xml || \
|
||||
die "Failed to apply hardening of policy.xml"
|
||||
einfo "policy.xml hardened"
|
||||
|
||||
elibtoolize # for Darwin modules
|
||||
|
||||
# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
|
||||
local ati_cards mesa_cards nvidia_cards render_cards
|
||||
shopt -s nullglob
|
||||
ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
|
||||
if test -n "${ati_cards}"; then
|
||||
addpredict "${ati_cards}"
|
||||
fi
|
||||
mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
|
||||
if test -n "${mesa_cards}"; then
|
||||
addpredict "${mesa_cards}"
|
||||
fi
|
||||
nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
|
||||
if test -n "${nvidia_cards}"; then
|
||||
addpredict "${nvidia_cards}"
|
||||
fi
|
||||
render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
|
||||
if test -n "${render_cards}"; then
|
||||
addpredict "${render_cards}"
|
||||
fi
|
||||
shopt -u nullglob
|
||||
addpredict /dev/nvidiactl
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local depth=16
|
||||
use q8 && depth=8
|
||||
use q32 && depth=32
|
||||
|
||||
local openmp=disable
|
||||
use openmp && { tc-has-openmp && openmp=enable; }
|
||||
|
||||
use perl && perl_check_env
|
||||
|
||||
[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
|
||||
|
||||
local myeconfargs=(
|
||||
$(use_enable static-libs static)
|
||||
$(use_enable hdri)
|
||||
$(use_enable opencl)
|
||||
--with-threads
|
||||
--with-modules
|
||||
--with-quantum-depth=${depth}
|
||||
$(use_with cxx magick-plus-plus)
|
||||
$(use_with perl)
|
||||
--with-perl-options='INSTALLDIRS=vendor'
|
||||
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
|
||||
$(use_with bzip2 bzlib)
|
||||
$(use_with X x)
|
||||
$(use_with zlib)
|
||||
--without-autotrace
|
||||
$(use_with postscript dps)
|
||||
$(use_with djvu)
|
||||
--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
|
||||
$(use_with fftw)
|
||||
$(use_with fpx)
|
||||
$(use_with fontconfig)
|
||||
$(use_with truetype freetype)
|
||||
$(use_with postscript gslib)
|
||||
$(use_with graphviz gvc)
|
||||
$(use_with heif heic)
|
||||
$(use_with jbig)
|
||||
$(use_with jpeg)
|
||||
$(use_with jpeg2k openjp2)
|
||||
--without-jxl
|
||||
$(use_with lcms)
|
||||
$(use_with lqr)
|
||||
$(use_with lzma)
|
||||
$(use_with openexr)
|
||||
$(use_with pango)
|
||||
$(use_with png)
|
||||
$(use_with raw)
|
||||
$(use_with svg rsvg)
|
||||
$(use_with tiff)
|
||||
$(use_with webp)
|
||||
$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
|
||||
$(use_with wmf)
|
||||
$(use_with xml)
|
||||
--${openmp}-openmp
|
||||
--with-gcc-arch=no-automagic
|
||||
)
|
||||
CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# Install default (unrestricted) policy in $HOME for test suite #664238
|
||||
local _im_local_config_home="${HOME}/.config/ImageMagick"
|
||||
mkdir -p "${_im_local_config_home}" || \
|
||||
die "Failed to create IM config dir in '${_im_local_config_home}'"
|
||||
cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
|
||||
die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
|
||||
|
||||
local im_command= IM_COMMANDS=()
|
||||
if [[ ${PV} == "9999" ]] ; then
|
||||
IM_COMMANDS+=( "magick -version" ) # Show version we are using -- cannot verify because of live ebuild
|
||||
else
|
||||
IM_COMMANDS+=( "magick -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
|
||||
fi
|
||||
IM_COMMANDS+=( "magick -list policy" ) # Verify that policy.xml is used
|
||||
IM_COMMANDS+=( "emake check" ) # Run tests
|
||||
|
||||
for im_command in "${IM_COMMANDS[@]}"; do
|
||||
eval "${S}"/magick.sh \
|
||||
${im_command} || \
|
||||
die "Failed to run \"${im_command}\""
|
||||
done
|
||||
}
|
||||
|
||||
src_install() {
|
||||
# Ensure documentation installation files and paths with each release!
|
||||
emake \
|
||||
DESTDIR="${D}" \
|
||||
DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
|
||||
install
|
||||
|
||||
rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
|
||||
dodoc {AUTHORS,README}.txt ChangeLog
|
||||
|
||||
if use perl; then
|
||||
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
|
||||
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
|
||||
fi
|
||||
|
||||
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
|
||||
|
||||
if use opencl; then
|
||||
cat <<-EOF > "${T}"/99${PN}
|
||||
SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
|
||||
EOF
|
||||
|
||||
insinto /etc/sandbox.d
|
||||
doins "${T}"/99${PN} #472766
|
||||
fi
|
||||
|
||||
insinto /usr/share/${PN}
|
||||
doins config/*icm
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
local _show_policy_xml_notice=
|
||||
|
||||
if [[ -z "${REPLACING_VERSIONS}" ]]; then
|
||||
# This is a new installation
|
||||
_show_policy_xml_notice=yes
|
||||
else
|
||||
local v
|
||||
for v in ${REPLACING_VERSIONS}; do
|
||||
if ! ver_test "${v}" -gt "7.0.8.10-r2"; then
|
||||
# This is an upgrade
|
||||
_show_policy_xml_notice=yes
|
||||
|
||||
# Show this elog only once
|
||||
break
|
||||
fi
|
||||
done
|
||||
fi
|
||||
|
||||
if [[ -n "${_show_policy_xml_notice}" ]]; then
|
||||
elog "For security reasons, a policy.xml file was installed in /etc/ImageMagick-7"
|
||||
elog "which will prevent the usage of the following coders by default:"
|
||||
elog ""
|
||||
elog " - PS"
|
||||
elog " - PS2"
|
||||
elog " - PS3"
|
||||
elog " - EPS"
|
||||
elog " - PDF"
|
||||
elog " - XPS"
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user