dev-db/pgbouncer: add 1.22.1

Signed-off-by: Patrick Lauer <patrick@gentoo.org>

dev-db/pgbouncer/Manifest

@@ -3,3 +3,4 @@ DIST pgbouncer-1.20.0.tar.gz 638020 BLAKE2B 1aa253b4f211e70e882e9b7789bfcdee3436
 DIST pgbouncer-1.20.1.tar.gz 638844 BLAKE2B 9b71b72b9baf3ce49d4b9c6597581d20a2666b5450d89bc716a4df6df0c8a8aaf92735a76033eccf358412934a3af92e1a8ed7e4ca0e863441f2d6bf43eefdc7 SHA512 7669005ac1d46d1cb5b42c853fc0fb5e495c8583c206658bf6c59f797d04eb9170a3d467a48863708ee69034ff71ac6fbbca752b239de644ef6225d46fb98e76
 DIST pgbouncer-1.21.0.tar.gz 668211 BLAKE2B 36dd43d301d1837876806688bc87febb6ae4fd40014e7e7301978026a4866b736c2c174d3b1e19a4e7bf5f8ca85025d2a0cd5711f2e4fa95e455f59ed1dbe381 SHA512 881701deae508e8e664402c0da533b25027259443551cda2974867453ad033ec5cfe8027ca3dac96a5134c57faff385c3c1e5711539e1acd6815761c9e3caee8
 DIST pgbouncer-1.22.0.tar.gz 670589 BLAKE2B feb0138c09eb2e3f865f9c372d1924f9fbe67785a52534f8b99783c0bc2d5a54a6fd8b0554ea8ac7d4e8e108fd2296a3a9ae19cb75d628052c45e4a57fd037cd SHA512 1d8f4b352103e17a3905ec0677362954f4b9f606f6dc00011514c2ec46d8c4e8d17b24e9ca92794ccaf4c86c9c77ac062e6be92be7856192b7c534b5a4911163
+DIST pgbouncer-1.22.1.tar.gz 677351 BLAKE2B c67eba10b51ae74fb77ad61f7c597b687769e75b687ff9682c16d0ac0b32c0e9d20d4c90cd5803331d128f3f388800faa38dd9965b86c5a75688455db1a06d6b SHA512 ac63fe877f68745f1faab096ee9d9e185de9cab97d4fef121c2c551fa0e69ea22342dc8b5ce75cadff755314e5493a5440f0748b5ee9f524f71d871ec1861530

dev-db/pgbouncer/pgbouncer-1.22.1.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://www.pgbouncer.org/"
+SRC_URI="https://www.pgbouncer.org/downloads/files/${PV}/pgbouncer-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+c-ares debug doc pam ssl systemd"
+
+RDEPEND="
+	>=dev-libs/libevent-2.0:=
+	acct-user/pgbouncer
+	c-ares? ( >=net-dns/c-ares-1.10 )
+	ssl? ( >=dev-libs/openssl-1.0.1:=[-bindist(-)] )
+	systemd? ( sys-apps/systemd )
+"
+
+DEPEND="${RDEPEND}"
+
+# Tests require a local database server, wants to fiddle with iptables,
+# and doesn't support overriding.
+RESTRICT="test"
+
+src_prepare() {
+	eapply "${FILESDIR}"/pgbouncer-1.12-dirs.patch
+
+	default
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_with c-ares cares) \
+		$(use_enable debug cassert) \
+		$(use_with pam) \
+		$(use_with ssl openssl) \
+		$(use_with systemd)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+	use doc && dodoc doc/*.md
+
+	newconfd "${FILESDIR}/${PN}.confd-r1" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd-r2" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}